无忧启动论坛

标题: 谁有"1999年10月"转化成"一九九九年十月"这样功能的批处理？ [打印本页]
作者: wjh6088    时间: 2007-6-5 15:40
标题: 谁有"1999年10月"转化成"一九九九年十月"这样功能的批处理？
如题，别人急要的先谢了
网上的都是阿拉伯数字转为大写金额的

[ 本帖最后由 wjh6088 于 2007-6-5 03:41 PM 编辑 ]
作者: namejm    时间: 2007-6-5 22:30
　　你要的是这样的代码吧？

  2. @echo off
  3. setlocal enabledelayedexpansion
  4. set str=零一二三四五六七八九
  5. for /f "tokens=1-3 delims=-:/" %%i in ("%date%") do set str1=%%i%%j%%k
  6. for /l %%i in (0,1,7) do (
  7.     set var=!str1:~%%i,1!
  8.     call set day=!day!%%str:~!var!,1%%
  9.     set /a num+=1
  10.     if !num! equ 4 set day=!day!年
  11.     if !num! equ 6 set day=!day!月
  12. )
  13. set day=%day:年零=年%
  14. echo      系统当前日期是：%day:月零=月%日
  15. pause>nul
复制代码
作者: wjh6088    时间: 2007-6-5 23:07
差不多是这个，是拿来处理文本文件的，还能改一改吗
最好以零开头的自动去除零．
谢谢了
作者: namejm    时间: 2007-6-5 23:49
　　月份和日期前面的零都已经去掉了啊，你还想要做成什么样的？要不然把你要处理的文本选择有代表性的内容发出来看看吧，顺便把你的要求完整地描述一遍。
作者: lianjiang    时间: 2007-6-6 06:49
支持楼上的，要求尽可能一次提清楚。
作者: namejm    时间: 2007-6-6 07:31
　　2楼的代码大写格式不统一，并且不能正确处理10、20，修改一下：
  1. @echo off
  2. :: 把系统日期转换成大写
  3. setlocal enabledelayedexpansion
  4. set str=〇一二三四五六七八九

  6. :main
  7. cls
  8. set day=
  9. for /f "tokens=1-3 delims=-:/" %%i in ("%date%") do set str1=%%i%%j%%k
  10. for /l %%i in (0,1,7) do (
  11.     set var=!str1:~%%i,1!
  12.     call set day=!day!%%str:~!var!,1%%
  13. )

  15. set str1=%day:~0,4%年%day:~4,1%十%day:~5,1%月%day:~6,1%十%day:~7,1%日
  16. set str1=%str1:〇十=%
  17. set str1=%str1:一十=十%
  18. set str1=%str1:十〇=十%

  20. echo      系统当前日期是：%str1%
  21. pause>nul
  22. goto main
复制代码

[ 本帖最后由 namejm 于 2007-6-6 01:17 PM 编辑 ]
作者: wjh6088    时间: 2007-6-6 17:55
对不起，昨天没时间来回复了，感谢楼上的热情解答
待处理的文本内容如下
1999.12.3
1958.2.12
1987.5.24
1988.12.5

不过已经通过excel转换好了，算是交差了，不过还是批处理比较简洁吧
楼上的代码我自己修改看看，3q
作者: namejm    时间: 2007-6-7 19:31
　　把6楼的代码稍做改动就可以了。

  2. @echo off
  3. setlocal enabledelayedexpansion
  4. set str=〇一二三四五六七八九
  5. for /f "tokens=1-3 delims=." %%i in (test.txt) do (
  6.     set /a y=%%i,m=10%%j,d=10%%k
  7.     call :change
  8. )
  9. pause
  10. exit

  12. :change
  13. set day=
  14. set str1=%y%%m:~-2%%d:~-2%
  15. for /l %%i in (0,1,7) do (
  16.     set var=!str1:~%%i,1!
  17.     call set day=!day!%%str:~!var!,1%%
  18. )
  19. set str1=%day:~0,4%年%day:~4,1%十%day:~5,1%月%day:~6,1%十%day:~7,1%日
  20. set str1=%str1:〇十=%
  21. set str1=%str1:一十=十%
  22. set str1=%str1:十〇=十%
  23. echo %str1%
  24. goto :eof
复制代码




欢迎光临 无忧启动论坛 (http://bbs.c3.wuyou.net/) Powered by Discuz! X3.3