无忧启动论坛

标题: 想知道 pe 能不能作为日常的os 使用，将pe作为硬盘上唯一的os [打印本页]

作者: weeew 时间: 2008-8-25 16:01
标题: 想知道 pe 能不能作为日常的os 使用，将pe作为硬盘上唯一的os
说不明白了
单位的机器是赛扬1g的128m 内存跑2000老是蓝屏（有保护卡的，内存不够） xp 又保护卡不支持，我想用pe来作为操作系统使用，但是机房的ip 是需要固定的，总不能每次使用的时候启用网络吧。我想实现的就是开出来就能上网的
就是不知道怎么处理？ ip 地址怎么弄

作者: weeew 时间: 2008-8-25 16:05
目前的pe，安装到硬盘多是 iso格式的，不知道能不能支持那种展开的

作者: yichya 时间: 2008-8-25 16:05
1.很显然PE是不支持还原卡的，因为PE就是基于XP核心的。
2.这个因为PE是一个运行在RAM上的OS，所以只能每次启动PE时启动网络，不过可以通过PENETCFG的配置文件分配IP。
3.展开的因为是PE所以不行，PE启动通过一个选项（/minint）把注册表移动至内存并为PE的磁盘分配盘符（X：），可以适当修改配置文件并去掉/minint选项（仅供参考）

[ 本帖最后由 yichya 于 2008-8-25 16:08 编辑 ]

作者: weeew 时间: 2008-8-25 16:31
谢谢楼上的这样的话保护卡的问题还是不能解决
不知道能不能作为无盘来处理。
明天去试验一下

作者: xubo1971 时间: 2008-8-29 21:47
PE功能不完整，完全用PE作为系统有时还是不方便。
PE也可以解开安装到硬盘，所谓的“非RAM方式”就是。
设固定IP可以很简单的解决，比如用批处理方式。

作者: weeew 时间: 2008-8-29 21:51

原帖由 xubo1971 于 2008-8-29 21:47 发表
PE功能不完整，完全用PE作为系统有时还是不方便。
PE也可以解开安装到硬盘，所谓的“非RAM方式”就是。
设固定IP可以很简单的解决，比如用批处理方式。

兄弟能不能给个例子

作者: caozhi256 时间: 2008-8-29 21:59
盗用下别人的成果，批处理的原因，单网卡机器有效

@echo off
@cls
@echo .
Rem color a  字体 ** 显示
color a
@echo ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo :::::    ●○克隆后自动改IP-计算机名-IE主页○●    :::::
@echo :::::----------------------------------------------------:::::
@echo :::::    ★☆★☆★☆★☆★☆★☆★☆★☆★☆★    :::::
@echo ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo .
Rem  ########## 延时5秒  ##############
ping -n 5 localhost >nul 2>nul
Rem  ########## #######  ##############
Rem  ------------------------------------------------------------------
Rem 如果存在config.cfg文件，将config.cfg删除
if exist config.cfg  del config.cfg
Rem  ■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■
Rem 收集所有计算机的MAC 地址，按下面的格式设置相关信息好。
Rem 下面■□■□■区域里的内容根据你的实际情况进行填写。
Rem  ■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■
@echo [  计算机名  ]  [ MAC 地址 ]    [客户机 IP]    >>config.cfg
@echo [ComputerName]  [MacAddress]    [IPAddress]    >>config.cfg
@echo XQ-A001 00-0C-29-9C-6D-9A 192.168.0.1    >>config.cfg
@echo XQ-A002 00-14-85-2a-22-12 192.168.0.2    >>config.cfg
@echo XQ-A003 00-14-85-31-3f-7a 192.168.0.3    >>config.cfg
@echo XQ-A004 00-14-85-2b-6e-90 192.168.0.4    >>config.cfg
@echo XQ-A005 00-14-85-17-76-60 192.168.0.5    >>config.cfg
@echo XQ-A006 00-14-85-2f-14-bc 192.168.0.6    >>config.cfg
@echo XQ-A007 00-14-85-2b-75-8c 192.168.0.7    >>config.cfg
@echo XQ-A008 00-14-85-29-1d-37 192.168.0.8    >>config.cfg
@echo XQ-A009 00-14-85-2a-25-14 192.168.0.9    >>config.cfg
@echo XQ-A010 00-14-85-2f-25-ce 192.168.0.10 >>config.cfg
@echo XQ-A011 00-14-85-2f-8e-ba 192.168.0.11 >>config.cfg
@echo XQ-A012 00-14-85-32-1f-07 192.168.0.12 >>config.cfg
Rem  ■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■
Rem  ------------------------------------------------------------------
Rem 如果存在ipconfig.txt文件，将ipconfig.txt删除
if exist ipconfig.txt  del ipconfig.txt
Rem 显示本机TCP/IP配置的详细信息，将结果写入ipconfig.txt文件中
ipconfig /all >ipconfig.txt
Rem  ------------------------------------------------------------------
Rem 如果存在phyaddr.txt文件，将phyaddr.txt删除
if exist phyaddr.txt del phyaddr.txt
Rem 在ipconfig.txt文件中搜索字符串Physical Address
Rem 并将字符串Physical Address所在行的内容写入phyaddr.txt文件中
find  "Physical Address" ipconfig.txt >phyaddr.txt
Rem  ------------------------------------------------------------------
Rem 在phyaddr.txt中忽略前2行，即从第3行开始搜索第12个字符串
Rem 字符串与字符串以空格为分隔，将第12个字符串赋值给变量M
Rem 将变量M的值赋值给变量strMac
for /f "skip=2 tokens=12" %%M in (phyaddr.txt) do set strMac=%%M
@echo 读取MAC地址为：%strMac%
Rem  ------------------------------------------------------------------
Rem 如果存在ComputerCfg.txt文件，将ComputerCfg.txt删除
if exist ComputerCfg.txt del ComputerCfg.txt
Rem 在Config.cfg文件中搜索变量strMac所表示的字符串
Rem 并将变量strMac所表示的字符串(即:MAC地址)所在行的内容写入ComputerCfg.txt文件中
find "%strMac%" Config.cfg >ComputerCfg.txt
Rem  --------------------------------------------------------------------
Rem 在ComputerCfg.txt中忽略前2行，即从第3行开始搜索第1个字符串
Rem 字符串与字符串以空格为分隔，将第1个字符串赋值给变量N
Rem 将变量N的值赋值给变量ComputerName
for /f "skip=2 tokens=1" %%N in (ComputerCfg.txt) do set ComputerName=%%N
@echo 本机计算机名为：%ComputerName%
Rem  --------------------------------------------------------------------
Rem 在ComputerCfg.txt中忽略前2行，即从第3行开始搜索第3个字符串
Rem 字符串与字符串以空格为分隔，将第1个字符串赋值给变量I
Rem 将变量I的值赋值给变量IPAddress
for /f "skip=2 tokens=3" %%I in (ComputerCfg.txt) do set IPAddress=%%I
@echo 本机IP为：%IPAddress%
Rem  --------------------------------------------------------------------
Rem 在ComputerCfg.txt中忽略前2行，即从第3行开始搜索第2个字符串
Rem 字符串与字符串以空格为分隔，将第1个字符串赋值给变量M
Rem 将变量M的值赋值给变量MacAddress
for /f "skip=2 tokens=2" %%M in (ComputerCfg.txt) do set MacAddress=%%M
@echo 设定MAC地址为：%MacAddress%
Rem
Rem  ---------------------------------------------------------------------
@echo ◆◇◆◇◆◇◆◇◆◇◆◇◆◇◆
@echo :::: 开始修改计算机器名称 ::::
@echo ◆◇◆◇◆◇◆◇◆◇◆◇◆◇◆
Rem 把计算机名赋值给变量name
set name=%ComputerName%
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v ComputerName /t reg_sz /d %name% /f
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f
@echo ◆◇◆◇◆◇◆◇◆◇◆◇◆◇◆
@echo :::: 修改计算机器名称完成 ::::
@echo ◆◇◆◇◆◇◆◇◆◇◆◇◆◇◆
Rem  ----------------------------------------------------------------
Rem  ########## 延时5秒  ##############
ping -n 5 localhost >nul 2>nul
Rem  ########## #######  ##############
Rem  ----------------------------------------------------------------
@echo 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
@echo :::::正在修改本机TCP/IP配置，可能需要等待一段时间。:::::
@echo 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
Rem
Rem ■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■
Rem 个性TCP/IP配置修改处：下面是给TCP/IP的各个选项赋值，你可以根据你的实际情况进行修改。
Rem 设置IP地址
set IP=%IPAddress%
Rem 设置子网掩码
set ma=255.255.255.0
Rem 设置网关地址
set ga=192.168.7.1
Rem 设置网关跃点数
set gw=auto
Rem 设置主DNS地址
set DNS01=220.168.128.2
Rem 设置备份DNS地址
set DNS02=202.103.86.3
Rem ■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■□■
Rem
Rem  ==========================================================================================
Rem 设置IP：设置DNS：参数说明:
Rem netsh interface ip set address 设置指定的接口的 IP 地址或默认网关。
Rem netsh interface ip set dns    设置 DNS 服务器模式和地址。
Rem netsh interface ip set wins 设置 WINS 服务器模式和地址。
Rem name：网络连接名称，一般为“本地连接”。你可以在“控制面板”->“网络连接”中看到。
Rem source：  获取IP的途径。动态获取，则为dhcp，手动设置，则为static。
Rem addr：要设置的IP地址。
Rem mask：子网掩码。
Rem gateway：网关地址。
Rem gwmetric：网关跃点数，可以设置为整型数值，也可以设置为“自动”：auto。
Rem  ----------------------
Rem register：
Rem none:    禁用动态 DNS 注册。
Rem primary:  只在主 DNS 后缀下注册。
Rem both:    在主 DNS 后缀下注册，也在特定连接后缀下注册。
Rem index：设置的DNS的顺序号。
Rem  ==========================================================================================
@echo IP地址:%IP% 子网掩码:%ma%
netsh interface ip set address name="本地连接" source=static addr=%IP% mask=%ma%
@echo 网关地址:%ga%  网关跃点数:%gw%
netsh interface ip set address name="本地连接" source=static gateway=%ga% gwmetric=%gw%
Rem  ----------------------
@echo 主DNS地址:%DNS01%
netsh interface ip set dns name="本地连接" source=static addr=%DNS01% register=primary
@echo 备份DNS地址:%DNS02%
netsh interface ip add dns name="本地连接" addr=%DNS02%  index=2
Rem WINS地址:
netsh interface ip set wins name="本地连接" source=static addr=none
Rem  -------------------------------------------------------------------------------------
Rem  ===========================================================================
Rem 如果你是在注册表里面加入名为IP的启动项的话，可以用下面的命令删除，去掉下面命名前的注释命令，即可发生作用。
Rem REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /v IP /f
Rem  ===========================================================================
Rem 删除本批处理程序生成的相关文件
if exist config.cfg  del config.cfg
if exist ipconfig.txt  del ipconfig.txt
if exist phyaddr.txt del phyaddr.txt
if exist ComputerCfg.txt del ComputerCfg.txt
Rem  ===========================================================================
@echo 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
@echo :::::本机TCP/IP配置修改完成间。:::::
@echo 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
Rem  ########## 延时5秒  ##############
ping -n 5 localhost >nul 2>nul
Rem  ########## #######  ##############
Rem  ===========================================================================
@echo  ※※※※※≮≮≮≮≮开始修改IE主页≯≯≯≯≯≯※※※※※
Rem 在下面设置IE主页地址
set IE=http://www.baidu.com
reg add "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main" /v "Start Page" /t reg_sz /d %IE% /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main" /v "Default_Page_URL" /t reg_sz /d %IE% /f
Rem 只要把上面的网址http://www.baidu.com换成你喜欢的就可以了。嘿嘿 ^-^
@echo  ※※※※※    IE主页修改为→ %IE%    ※※※※※
Rem  ===========================================================================
Rem  ########## 延时5秒  ##############
ping -n 5 localhost >nul 2>nul
Rem  ########## #######  ##############
Rem pause
Rem 计算机是重启还是关闭根据自己需要自由修改
Rem 15秒后自动重启计算机
shutdown -r -t 15
Rem 15秒后自动关闭计算机
Rem  shutdown -s -t 15
Rem  ########## 延时5秒  ##############
ping -n 5 localhost >nul 2>nul
Rem  ########## #######  ##############
Rem  ########################
Rem 删除本批处理程序自身
del %0
Rem  ########################

作者: weeew 时间: 2008-8-29 22:58
这个要收集机房里面所有的mac的数据了呀

作者: xubo1971 时间: 2008-8-30 08:08
给个简单的例子：
@echo on
echo 设置IP地址......
echo -----------------------
@rem 关闭动态IP服务
net stop dhcp
rundll32 netshell.dll HrRenameConnection
@rem 使用接口IP上下文
netsh add helper ifmon.dll
@rem -----------------------
@rem 设置静态IP,网关，默认DNS服务器，可自行修改。
netsh interface ip set address "本地连接" static addr=10.156.31.202 mask=255.255.255.0 gateway=10.156.31.254 auto
netsh interface ip set dns "本地连接" static 172.168.1.2
netsh interface ip add dns "本地连接" 211.91.33.193
@rem 重复一次
netsh interface ip set address "本地连接" static addr=10.156.31.202 mask=255.255.255.0 gateway=10.156.31.254 auto
netsh interface ip set dns "本地连接" static 172.168.1.2
netsh interface ip add dns "本地连接" 211.91.33.193
net start dhcp
注意：必须要有netsh.exe、netshell.dll、ifmon.dll三个文件。

作者: weeew 时间: 2008-8-30 09:42
谢谢楼上的， netsh 知道但是没用过

欢迎光临无忧启动论坛 (http://bbs.c3.wuyou.net/)