开源，基于分区助手命令行的UD三分区一键无损制作脚本，uft8，支持win10!20190504 - 无忧启动论坛

UD三分区因具有超强的bios/uefi双启兼容性、一键制作的超强方便性、PE全隐藏的超强安全性、方法标准通用的超强可移植性、fbinst和grub4dos全开源的超强开放性、数据区可存放大于4G文件的超大文件存储性，越来越受到电脑公司和PE爱好者的喜爱，成为后bios时代主流PE部署方法之一。
但因传统的UD三分区编程技术比较复杂，制作UD区和efi区会相应的破坏对方，所以UD三分区一键制作编程并没有普及起来。为实现无损数据区制作，主要还是为了大大简化UD三分区编程制作，让人人都能编出UD三分区制作主程序，不才特请傲梅分区助手作者disktool，开发出无损分区的相应命令行，用于简化UD三分区编程制作，实现无损数据区制作UD三分区。现在已经开发出一个cmd脚本，自己测试是成功的。基本上是模拟手工制作教程。编程高手可以对照手工教程及分区助手命令行，来编程实现。

关于无损数据区制作UD三分区大致的流程
基于ntfs格式的U盘，很容易无损的分出左端区和右端区，而左端未分配空间区用fbinst命令行非强格式就成UD区。所以，思路如下：
1获取U盘编号和盘符，并判断U盘格式，ntfs格式磁盘不动，fat16和fat32用convert无损转换为ntfs格式；exfat强格为ntfs，这个数据丢失，不能无损。
2用分区助手清空U盘当前盘左端和右端所有分区，合并空间到ntfs数据区。这样子可以解决二次制作问题，解决复杂U盘制作失败的问题。
3用分区助手调整出右端的efi区，并格式为fat,不激活，不设置隐藏属性
4用分区助手调整出左端的区，并用fbinst非强格成UD区。（非强格，未分配空间就无损数据区变成了UD区）
5用分区助手把iso数据写入efi区。
6用fbinst把fba文件写入UD区。

@Echo Off
rem cd /d "%~dp0"
COLOR 2F
echo 检查管理员权限...
%1 mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&& exit
pushd "%CD%"&& CD /D "%~dp0"
Set TT=独剑制作的无损UD三分区脚本
TITLE %TT%
CLS
Echo.
Echo.
Echo 　　　　　　　╭══════════════════╮
Echo 　　　　　　　║　　　　　　　　　　　　　　　　　　║
Echo 　　　╭═══┤ %TT%! ├═══╮
Echo 　　　║　　　║　　　　　　　　　　　　　　　　　　║　　　║
Echo 　　　║　　　╰══════════════════╯　　　║
Echo.
rem 变量说明： %uid%—U盘磁盘编号 %udri%—U盘盘符 %drid%—U盘磁盘格式
rem 变量说明： %padel%—要删除的非数据分区 %padel%—显示无损制作成功
rem 中间文件说明 Usee0.txt-U盘磁盘编号查看文件，用于判断U盘磁盘编号
rem 中间文件说明 Usee.txt-U盘磁盘格式查看文件，用于判断U盘盘符和格式
echo 列出指定电脑上所有移动磁盘
.\bin\partassist.exe /list /usb
.\bin\partassist.exe /list /usb /out:.\bin\Usee0.txt
Set uid=
Echo.
echo 智能查找U盘磁盘编号，多个U盘时候选择最后一个。
Set uid=
for %%j in (1 2 3 4 5 6 7 8 9 10 11 12) DO (find /i "%%j |" .\bin\Usee0.txt>nul&&SET uid=%%j)
if not defined uid echo 找不到U盘，无法制作自动退出!!!!&&pause&&del .\bin\Usee0.txt /q&&goto EX
echo 你的U盘磁盘编号为%uid%
del ".\bin\Usee0.txt" /q
Echo.
echo 列出U盘上的所有分区
.\bin\partassist.exe /list:%uid%
.\bin\partassist.exe /list:%uid% /out:.\bin\Usee.txt
Echo.
echo 智能查找U盘所在盘符，移动硬盘自动选择最左端分区
Set udri=
for %%i in (Z Y X W U T S R Q P O N M L K J I H G F E D C) DO (
find /i "%%i:" .\bin\Usee.txt>nul&&SET udri=%%i)
if not defined udri echo 找不到U盘盘符，无法制作自动退出&&pause&&del .\bin\Usee.txt /q&&goto EX
echo 你的U盘所在盘符为%udri%盘
Echo.
echo 制作UD三分区启动盘，无损数据区制作，请保持不间断电源！
echo 继续请按任意键，退出请关闭窗口！&&pause
Echo.
echo 判断磁盘格式，fat16、fat32转换为ntfs，可无损制作；exfat格式不能无损制作，只能全新制作
Echo.
set drid=exfat
find /c /i "fat16" .\bin\Usee.txt>nul&&set drid=fat16
find /c /i "fat32" .\bin\Usee.txt>nul&&set drid=fat32
find /c /i "ntfs" .\bin\Usee.txt>nul&&set drid=ntfs
find /c /i "exfat" .\bin\Usee.txt>nul&&set drid=exfat
rem del .\bin\Usee.txt /q
echo 你的U盘格式为%drid%
rem 强制卸载并修复磁盘错误，解决U盘占用，以增强无损制作的可靠性
rem if not %drid%==exfat echo.&&echo 强制卸载并修复磁盘错误，以增强无损制作的可靠性&&chkdsk %udri%: /x /f
echo.&&echo 强制修复U盘磁盘错误，以增强无损制作的可靠性&&chkdsk %udri%: /x /f
if %drid%==exfat echo 你的U盘格式为exfat，只能格式化为ntfs，所有数据丢失，请备份数据！&&pause&& .\bin\partassist.exe /fmt:%udri% /fs:ntfs /label:data
if %drid%==fat16 echo.&&echo 你的U盘格式为fat16，先无损转换为ntfs！&&CONVERT %udri%: /FS:NTFS /V /NoSecurity
if %drid%==fat32 echo.&&echo 你的U盘格式为fat32，先无损转换为ntfs！&&CONVERT %udri%: /FS:NTFS /V /NoSecurity
if %drid%==ntfs echo.&&echo 你的U盘格式为ntfs，无损制作效果刚刚的！
echo.
echo 下面自动清空data区左端和右端分区恢复单一分区，以免二次制作时候受影响而导致制作失败
rem 带*的为PE区而非数据区，智能判断出分区ID并清空
set padel=
find /c /i "0 | *:" .\bin\Usee.txt>nul&&set padel=0
find /c /i "1 | *:" .\bin\Usee.txt>nul&&set padel=1
if defined padel .\bin\partassist.exe /hd:%uid% /del:%padel%
rem 强制把数据区左右两端的未分配空间扩展到数据区，恢复到单一分区，4k对齐
.\bin\partassist.exe /hd:%uid% /resize:%udri% /extend:auto /align
rem if %padel%==0 .\bin\partassist.exe /hd:%uid% /resize:%udri% /extend:right /align
rem if %padel%==1 .\bin\partassist.exe /hd:%uid% /resize:%udri% /extend:left /align
del .\bin\Usee.txt /q
Echo.
echo 从U盘右边无损分出300M未分配空间用于EFI区
.\bin\partassist.exe /resize:%udri% /reduce-right:300
Echo.
echo 创建并格式化右端的efi区，fat16,4k对齐，不激活，不设置隐藏属性，设置卷标为efi
rem .\bin\partassist.exe /hd:%uid% /cre /pri /size:auto /end /fs:fat16 /act /hide /align /label:EFI
.\bin\partassist.exe /hd:%uid% /cre /pri /size:auto /end /fs:fat16 /align /label:EFI
Echo.
echo 从U盘左边无损分出680M未分配空间用于UD区,4k对齐
.\bin\partassist.exe /resize:%udri% /reduce-left:680 /align
Echo.
echo 把左边分出的680M空间非强格成UD区，指定UD主分区为8M，剩下的空间全部变为UD扩展空间，故UD扩展空间不用指定
rem .\bin\fbinst.exe (hd%uid%) format --fat32 --zip --chs --primary 8M --align
echo on
.\bin\fbinst.exe %udri%: format --fat32 --primary 8M --align
@echo off
rem 写入fba文件时候，自动建立了fb主菜单，以下语句关闭；文件fb.cfg可以删除
rem .\bin\fbinst.exe %udri%: add-menu "fb.cfg" "fb.cfg
rem U+低端隐藏盘和高端隐藏盘制作时，会出现无激活区情况，这里强制激活data区；0为data区，1为efi区
echo.&&echo 设置数据区卷标为data,并强制激活data区&&label %udri%: data&&.\bin\partassist.exe /setact:0 /hd:%uid%
Echo.
echo 这个时候，三分区已经形成，UD区已经格式化成功，UD主引导也形成！
Echo.
echo 正在把efi.iso文件写入EFI区，请稍候……
if exist %temp%\uefi\ rd "%temp%\uefi" /s /q
.\bin\7z.exe x .\pediy\efi.iso -y -aos -o"%temp%\uefi"
if exist %temp%\uefi\[boot] rd "%temp%\uefi\[boot]" /s /q
.\bin\partassist.exe /hd:%uid% /whide:1 /src:%temp%\uefi
rd "%temp%\uefi" /s /q
Echo.
echo 正在把ud.fba写入UD区，请稍候……
rem .\bin\fbinst.exe %uid%: load .\pediy\ud.fba
.\bin\fbinst.exe %udri%: load .\pediy\ud.fba
rem 通过移除高端区的盘符来隐藏高端efi分区
Echo.
echo 隐藏高端efi分区
.\bin\partassist.exe /hd:%uid% /setletter:1 /letter:*
set exdata=
if not %drid%==exfat set exdata=检查一下你数据区数据还在不在吧，
Echo.
echo 已经成功把PE写入UD区和EFI区！%exdata%用佛大的qemu虚拟机测试一下bios/uefi双启吧。
pause
goto EX
:EX
@echo on

复制代码