批处理利用Windows防火墙阻止程序和服务联网！ - 无忧启动论坛

@echo off
setlocal ENABLEDELAYEDEXPANSION
mode con: cols=65 lines=25
color 0a
rem 批处理获取管理员权限
:-------------------------------------
%1 mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&&exit /b
CD /D "%~dp0"
:-------------------------------------
::添加阻止程序出站规则
(
echo "Office_OfficeClickToRun","%ProgramFiles%\Common Files\microsoft shared\ClickToRun\OfficeClickToRun.exe"
echo "Office_msoia","%ProgramFiles%\Microsoft Office\root\Office16\msoia.exe"
echo "Office_WINWORD","%ProgramFiles%\Microsoft Office\root\Office16\WINWORD.EXE"
echo "Office_EXCEL","%ProgramFiles%\Microsoft Office\root\Office16\EXCEL.EXE"
echo "Office_POWERPNT","%ProgramFiles%\Microsoft Office\root\Office16\POWERPNT.EXE"
echo "Office_VISIO","%ProgramFiles%\Microsoft Office\root\Office16\VISIO.EXE"
echo "Office_WINPROJ","%ProgramFiles%\Microsoft Office\root\Office16\WINPROJ.EXE"
echo "Office_MSPUB","%ProgramFiles%\Microsoft Office\root\Office16\MSPUB.EXE"
echo "Office_MSACCESS","%ProgramFiles%\Microsoft Office\root\Office16\MSACCESS.EXE"
echo "AutoCAD_LMU","%ProgramFiles%\Common Files\Autodesk Shared\AdLM\R11\LMU.exe"
echo "AutoCAD_DADispatcherService","C:\Program Files\Autodesk\AutoCAD 2016\DADispatcherService.exe"
echo "AutoCAD_acad","C:\Program Files\Autodesk\AutoCAD 2016\acad.exe"
)>list.txt
FOR /F "usebackq tokens=1,2 delims=," %%i in ( list.txt ) do (
netsh advfirewall firewall del rule name="%%i">nul 2>nul
netsh advfirewall firewall add rule name="%%i" program=%%j action=block dir=out>nul
echo 阻止%%i程序出站规则已添加
)
del list.txt
::添加阻止服务出站规则
(
echo "Windows Update","wuauserv"
)>list.txt
set svchost_exe="%%systemroot%%\system32\svchost.exe"
FOR /F "usebackq tokens=1,2 delims=," %%i in ( list.txt ) do (
netsh advfirewall firewall del rule name=%%i>nul 2>nul
netsh advfirewall firewall add rule name=%%i service=%%j action=block dir=out program="%svchost_exe%">nul
echo 阻止%%i服务出站规则已添加
)
del list.txt
pause

复制代码

@ECHO OFF
set name="Kugou"
set exePath="D:\Program Files\KuGou\KGMusic\KuGou.exe"
netsh advfirewall firewall del rule name=%name%>nul 2>nul
netsh advfirewall firewall add rule name=%name% program=%exePath% action=block dir=out>nul
set serviceNameShow="KuGou Service"
set serviceName="KugouService"
set svchost="%%systemroot%%\system32\svchost.exe"
netsh advfirewall firewall del rule name=%serviceNameShow%>nul 2>nul
netsh advfirewall firewall add rule name=%serviceNameShow% service=%serviceName% action=block dir=out program="%svchost%">nul

复制代码