无忧启动论坛

标题: diskpart 一次性装入全部未挂载的卷 [打印本页]

作者: dos时代菜鸟 时间: 2018-3-12 19:59
标题: diskpart 一次性装入全部未挂载的卷
本帖最后由 dos时代菜鸟于 2018-3-12 23:10 编辑

auto_drv.zip (708 Bytes, 下载次数: 45)

@echo off
setlocal ENABLEDELAYEDEXPANSION
color 0a
mode con: lines=40 cols=120
echo 正在探测未挂载的卷......
>%temp%\lp.txt echo list vol
diskpart /s %temp%\lp.txt >%temp%\dl.txt
type %temp%\dl.txt
set t0=
set n=0
>%temp%\lp.txt echo.
for /f "tokens=1,*" %%c in (%temp%\dl.txt) do (
set l0=%%c
set l1=%%d
if "!l0:~0,1!"=="-" set "t0=ok"
if "!t0!"=="ok" (if not "!l0:~0,1!"=="-" ( rem 确认当前行为数据行
if "!l1:~6,1!"==" " ( rem 判断当前卷没有被挂载盘符
set /a n=!n!+1
for /f "tokens=1" %%e in ("%%~d") do ( rem 获取卷号并将挂载指令传递给脚本
>>%temp%\lp.txt echo select vol %%e
>>%temp%\lp.txt echo assign
)
)
))
)
if !n! GTR 0 (
>>%temp%\lp.txt echo list vol
echo 发现 !n! 个未挂载卷,挂载脚本已生成：
echo -------------------------
type %temp%\lp.txt
echo -------------------------
echo 按任意键开始挂载...
pause>nul
diskpart /s %temp%\lp.txt
) else (echo 未发现没有被挂载的卷)
pause

复制代码

作者: 窄口牛 时间: 2018-3-13 07:09
写一个照着旧注册表文件修改盘符吧，多系统的人有这个需求。

作者: dos时代菜鸟 时间: 2018-3-13 08:11
本帖最后由 dos时代菜鸟于 2018-3-13 08:12 编辑

窄口牛发表于 2018-3-13 07:09
写一个照着旧注册表文件修改盘符吧，多系统的人有这个需求。

这个
http://bbs.wuyou.net/forum.php?m ... &extra=page%3D1

就可以改盘符，直接选 L
再选择要该盘符的卷，在输入要改成啥盘符，就可以了。要是盘符已经被占用了，可以先把占位卷卸载了，装成别的盘符。

作者: 窄口牛 时间: 2018-3-13 08:20
描述不对，应该是按照卷标修改盘符。

作者: dos时代菜鸟 时间: 2018-3-13 14:14

窄口牛发表于 2018-3-13 08:20
描述不对，应该是按照卷标修改盘符。

卷标？
以前的定义，卷标就是现在列表中的卷标签。使用 lable 命令给分区定义的名字。

作者: 窄口牛 时间: 2018-3-13 14:52
按照卷标名字分配盘符

作者: dos时代菜鸟 时间: 2018-3-13 18:26

窄口牛发表于 2018-3-13 14:52
按照卷标名字分配盘符

这个可以有，就是事先把卷标和盘符编入文本，脚本读取文本和分区序列，进行排序，还有一些细节要考虑，比如虚拟内存位置，文本没记录的分区怎么处理，gpt.mbr的差别还有别的杂七杂八的都嘚考虑。

欢迎光临无忧启动论坛 (http://bbs.c3.wuyou.net/)

Powered by Discuz! X3.3