超级EFI与BIOS双启ISO制作工具 - 无忧启动论坛

@echo off
rem 本程序使用isodir来定义打包的目录，可以拖放打包目录进行打包
rem 如果未指定打包目录，则使用本文件所在位置的上两级作打包目录
rem 打包目录本身及路径均不能带空格，否则可能出现不可预计的结果
rem 生成的ISO与该文件夹位于同一目录下，文件名为打包目录的目录名
rem 启动文件位置的定义约定使用相对于打包目录的相对路径。
set r=-preparer http://bbs.wuyou.net -publisher H3
For /F "tokens=1" %%i In ('DATE /T') do SET d=%%i
color 3f
PUSHD %~dp0
if not "%1"=="" goto Get_isodir
SET TP=%cd%
cd ..\..
set isodir=%cd%
cd %TP%
call :Get_isoname %isodir%
goto start
:Get_isodir
set isodir=%1
set isoname=%~n1%
:start
rem 指定BIOS启动文件
cls
set prog=H3PE EFI与BIOS双引导ISO生成程序
SET LS=====================================================================
SET LD=--------------------------------------------------------------------
title %prog%
Echo.
Echo %LS%
Echo %prog%
Echo %LD%
Echo.
echo 请先选择生成Bios的引导方式：
echo.
echo 　　 [1] Isolinux (LNX)方式
echo 　　 [2] Grub4dos (G4D)方式
echo 　　 [3] EasyBoot (EZB)方式
echo 　　 [4] Grub2 (G2)方式
echo 　　 [5] MS (NT6)方式
echo 　　 [q] 退出程序
echo.
Echo %LD%
echo 注：1.本系统isolinux要求为去掉效验的文件；
echo 　　 2.请查验\WXPE\WINSXS\MANIFESTS下的文件，
echo 　　如果文件名太长，可能造成打包失败！
Echo %LD%
Echo 　　　 Edit by：blithewind、H3　　盗版不究
Echo %LS%
set /p choice=　请选择 (1/2/3/4/5/q) ，然后按回车：
if "%choice%"=="" goto start
if not "%choice%"=="" set choice=%choice:~0,1%
if /i "%choice%"=="1" set bootfile=BOOT\ISOLINUX.BIN &&set bm=LNX
if /i "%choice%"=="2" set bootfile=EZBOOT\H3_GRLDR.BIN &&set bm=G4D
if /i "%choice%"=="3" set bootfile=EZBOOT\LOADER.BIN &&set bm=EZB
if /i "%choice%"=="4" set bootfile=EZBOOT\H3_G2LDR.BIN &&set bm=G2
if /i "%choice%"=="5" set bootfile=EZBOOT\H3_MGRLD.BIN &&set bm=NT6
if /i "%choice%"=="q" exit
rem set isoname=%isoname%-%d%(%bm%)
:EFISTART
rem 指定EFI启动文件
set choice=
Echo.
Echo %LS%
Echo %prog%
Echo %LD%
Echo.
echo 请再选择生成EFI的引导方式：
echo.
echo 　　 [1] MS原生64/32-EFI
echo 　　 [2] Grub2接管的64/32-EFI
echo 　　 [3] rEfind接管的64/32-EFI
echo 　　 [4] xorboot接管的64/32-EFI
echo 　　 [5] Grub4EFI接管的64/32-EFI
echo 　　 [6] shim接管的xorboot 64-EFI
echo 　　 [7] shim接管的Grub2 64-EFI
echo 　　 [8] 卡巴静默过安检再转Grub2（要求/boot/grub/grub.cfg小写）
echo 　　 [b] 返回开始
echo 　　 [q] 退出程序
echo.
Echo %LD%
echo 注：以上6/7可以通过Secure Boot 验证，第一次启动时要选证书
echo 　　第8项要先将/BOOT/GRUB改成小写再打包，此项有可能被MS封杀；
echo 　　如果还不能通过Secure验证，请回复第[1]项；
Echo %LD%
Echo 　　　 Edit by：blithewind、H3　　盗版不究
Echo %LS%
set /p choice=　请选择 (1/2/3/4/5/6/7/8/b/q) ，然后按回车：
if "%choice%"=="" goto EFISTART
if not "%choice%"=="" set choice=%choice:~0,1%
if /i "%choice%"=="1" set efifile=EFI\efisys.bin
if /i "%choice%"=="2" set efifile=EFI\grub2.bin
if /i "%choice%"=="3" set efifile=EFI\refind.bin
if /i "%choice%"=="4" set efifile=EFI\xorboot.bin
if /i "%choice%"=="5" set efifile=EFI\grub4efi.bin
if /i "%choice%"=="6" set efifile=EFI\sxorboot.bin
if /i "%choice%"=="7" set efifile=EFI\sgrub2.bin
if /i "%choice%"=="8" set efifile=EFI\skpgrub2.bin
if /i "%choice%"=="b" goto start
if /i "%choice%"=="q" exit
:ULTRAISO
set efifile=%isodir%\%efifile%
ultraiso.exe -jlong -l -imax -optimize %r% -boot %isodir%\%bootfile% -volu %isoname% -d "%isodir%" -out %isodir%\..\%isoname%.ISO
rem ultraiso -in %1 -rm /* -d "%~dpn1" -jlong -imax -optimize -volu %~n1 -out %1
cls
color 4f
echo 注意：
Echo.
echo 下面进行UltraIso的界面按键操作，请保持程序为当前窗口并等待窗口关闭……
Echo.
start ultraiso.exe %isodir%\..\%isoname%.ISO
nircmd.exe clipboard set %efifile%
echo 开始添加EFI启动文件……
nircmd.exe wait 1500
nircmd.exe sendkeypress ctrl+alt+i
nircmd.exe wait 1000
nircmd.exe sendkeypress ctrl+v enter
echo 开始保存ISO文件……
nircmd.exe wait 100
nircmd.exe sendkeypress ctrl+s
echo 退出UltraISO操作界面……
nircmd.exe wait 1000
nircmd.exe closeprocess ultraiso.exe
goto end
:Get_isoname
set isoname=%~n1%
goto eof
:END
echo 操作全部完成!请按任意键退出……
pause>nul

复制代码