无忧启动论坛

标题: 流畅丝滑 Windows Server 2022使用记录 [打印本页]

作者: liujun2000 时间: 2021-9-23 10:53
标题: 流畅丝滑 Windows Server 2022使用记录
本帖最后由 liujun2000 于 2021-9-23 14:06 编辑

流畅丝滑 Windows Server 2022使用记录

所有东西来自网络，我只是发出来交流。
声明：官方版本我只是按我使用方式安装
背景：呵呵
我开机同时使用的软件比较多，所以对系统反应比较大。
1个excel（excel97）
2个QQ （QQ9.3绿色）
1个游戏
1个浏览器
2个雷电模拟器
1个虚拟机          （内存CPU消耗大户）
5个微信电脑版    （内存CPU消耗大户）
1个酷狗听书
上面的是定数，其他是随机开的软件
很多时候2个雷电同时快速使用有点卡（特殊原因要求反应快），

官方版本（好像是初始版，反正我安装的这个版本）
zh-cn_windows_server_2022_x64_dvd_6c73507d.iso

1、安装
直接用WinNTSetup_x64安装到vhdx或者硬盘
用DrvCeox安装驱动

2、优化
我根据前辈们的优化windows_server_2019的方法优化的，忘记是谁发的。这里就贴出来

将windows server2019打造成个人操作系统 [复制链接]

一、组策略

WIN键+R键，输入gpedit.msc，进入组策略设置。

1、计算机配置，Windows设置，安全设置，帐户策略，密码策略："密码必须符合复杂性要求"，设置为"已禁用"。

解决问题：设置帐号密码，默认必须是字母、数字、特殊字符都必须有，否则会提示不符合条件。
2、计算机配置，Windows设置，安全设置，帐户策略，密码策略："密码最短使用期限"，设置为"0"（无期限）。

解决问题：密码有有效期，快到期会提示修改密码。修改后密码永久有效。

3、计算机配置，Windows设置，安全设置，本地策略，安全选项，"无需按 Ctrl+Alt+Del"，设置为"已启用"。

解决问题：登录系统，需要先按Ctrl+Alt+Del，才能显示登录界面。修改后不再需要。

4、计算机配置，管理模板，系统，显示"关闭事件跟踪程序"，设置为"已禁用"。

解决问题：关机时，需要输入关机原因。设置后不再需要。

5、计算机配置，管理模板，系统，登录时不显示"管理你的服务器"页，设置为"已启用"。

解决问题：Administrators组下的用户每次登录，会自动启动server manager，设置该策略后，会不再自动启动。

二、功能与服务

1、控制面板--->服务器管理器--->本地服务器，IE 增强的安全配置，"管理员"与"用户"的下方，勾选"关闭"。

解决问题：IE默认设置下，上网会有一堆安全提示，设置后不再提示，与个人win10保持一致。

2、控制面板--->程序和功能--->启用或关闭 Windwos 功能--->服务器选择--->功能--->勾选 “Direct Play” 、“无线 LAN 服务”、“优质 Windows 音频视频体验” 确认安装

解决问题：默认如wifi、多媒体、索引服务等是关闭的，添加后可以启用这些功能。

3、设置服务

解决问题：windows server 2016默认没有声音、索引选项无法启用，设置服务后可以解决该问题。

启动两项声音服务，Windows Audio和Windows Audio Endpoint Builder，并设为自动属性。

三、系统属性
1、WIN键+X键，系统，高级系统设置，性能（设置），高级，调整以优化性能，设置为"程序"。
2、WIN键+X键，系统，高级系统设置，性能（设置），数据执行保护，选择"仅为基本Windows程序和服务启用DEP(T)"。
四、删除所有计划任务
1. 仅删除全部任务，不删任务所在文件夹：
   schtasks /delete /tn * /F
2.先删任务，再删文件夹：
   del /s /q C:\Windows\System32\Tasks\Microsoft\Windows
   cd C:\Windows\System32\Tasks\Microsoft\Windows
   rd /s /q C:\Windows\System32\Tasks\Microsoft\Windows
   del /s /q C:\Windows\System32\Tasks\Microsoft\XblGameSave
   rd /s /q C:\Windows\System32\Tasks\Microsoft\XblGameSave
五、windows server2019启用 Flash  （这个我没有执行，好像现在没有必要）
CMD执行
dism /online /add-package /packagepath:"C:\Windows\servicing\Packages\Adobe-Flash-For-Windows-Package~31bf3856ad364e35~amd64~~10.0.17763.1.mum"
六、windows server2019激活
HEU_KMS_Activator_v24.3.0

--------------------------------------------------------------------------------------
@echo off&title ★ 一键停止及禁用会降低系统性能的不常用Windows服务 By Linzeal ★

::Section-全局说明及全局变量设置 ::::::::

::开头的语句为注释。等同于REM语句。注意不要与标记符:相混淆。
setlocal EnableDelayedExpansion
::mode con: cols=80 lines=25
color 2f

If Not "%1"=="" Set a=%1
set welcome=

set DepartLine=----------------------------------------------------------------
::设置分隔线，DepartLine为8×8个“-”
set DepartH0=**********
::设置标题标识符，DepartH0为10个“*”
set DepartH1=========
::设置标题标识符，DepartH1为8个“=”
set DepartH2=====
::设置标题标识符，DepartH2为4个“=”

::SectionEND

::Section-判断系统版本及提取管理员权限运行。 ::::::::
ver | find "5.0." > NUL && @echo 不支持该系统！&& Goto Quit
ver | find "5.1." > NUL && @echo 不支持该系统！&& Goto Quit
ver | find "5.2." > NUL && @echo 不支持该系统！&& Goto Quit
set folder=%~dp0
pushd "%~dp0"
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (goto UAC) else ( goto Administrator )

:UAC
@echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
@echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /b

::UAC-END

:Administrator
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"

::Administrator-END

::SectionEND

::Section-程序界面及操作菜单 ::::::::
:Menu
Cls
@echo.&@echo %DepartH0% DisableUselessServices.bat %DepartH0%
@echo.&@echo          v1.2.0004.03062015 by Linzeal
@echo.&@echo %DepartH2% 本批处理脚本用于停止及禁用会降低系统性能的不常用服务。 %DepartH2%
@echo.&@echo %DepartLine%
@echo.&@echo Y    - 开始进程处理。
@echo.&@echo N OR Q - 什么也不做，退出。或直接点击窗口右上角“ X ”关闭退出。
@echo.

If not "%a%"=="" set welcome=输入" %a% "无效，
Set /p a=%welcome%请输入您的选择（不分大小写，输入“N”或“Q”退出）：
If "%a%"=="y" Goto DisableUselessServices
If "%a%"=="Y" Goto DisableUselessServices
If "%a%"=="n" Goto Quit
If "%a%"=="N" Goto Quit
If "%a%"=="q" Goto Quit
If "%a%"=="Q" Goto Quit
Goto Menu

::Menu-END

::SectionEND

::Section-程序区段 - 关闭不常用服务 ::::::::
:DisableUselessServices
::----- 说明及变量设置 -----::
::在cmd下可有两种方法打开服务开关命令，net和sc。

::net用于打开没有被禁用的服务，语法是：
::net start 服务名       //启动服务
::net stop 服务名       //停止服务

::用sc可打开被禁用的服务，语法是：
::sc config 服务名 start= demand       //手动
::sc condig 服务名 start= auto       //自动
::sc config 服务名 start= disabled       //禁用
::sc start 服务名       //启动服务
::sc stop 服务名       //停止服务

::备注：已启用的服务单单更改为禁用后可能不能立即停止该服务，所以还需加以停止命令。

::下面的服务名集合（SerNameSet）中的各服务就是准备处理的服务，可以进行按自己的需要来增减。注意各服务名称之间的分隔（Tab键或空格）。
::要打开服务管理控制台，在运行（Win+R）中键入services.msc。
::特别注意，下面的服务名集合（SerNameSet）中的各服务名，必须是各服务属性窗口中的“服务名称”，而不能是“显示名称”。（在服务管理控制台窗口中显示的“名称”列显示其实是“显示名称”。）
::可以在服务属性窗口中用鼠标选住“服务名称”进行复制，而不用手动输入，可防输入名称错误。

set SerNameSet=BITS       BDESVC       Browser       DPS       WdiServiceHost       WdiSystemHost       HomeGroupListener       HomeGroupProvider       SharedAccess       CscService       pla       wercplsupport       PcaSvc       SessionEnv       TermService       UmRdpService       RemoteRegistry       RemoteAccess       seclogon       LanmanServer       ShellHWDetection       SysMain       WinDefend       WerSvc       WMPNetworkSvc       WSearch       wuauserv

::=       服务名称       _显示名称       _描述
::=       BITS       _Background Intelligent Transfer Service       _使用空闲网络带宽在后台传送文件。
::=       BDESVC       _BitLocker Drive Encryption Service       _BDESVC 承载 BitLocker 驱动器加密服务。
::=       Browser       _Computer Browser       _维护网络上计算机的更新列表，并将列表提供给计算机指定浏览。
::=       DPS       _Diagnostic Policy Service       _诊断策略服务启用了 Windows 组件的问题检测、疑难解答和解决方案。
::=       WdiServiceHost       _Diagnostic Service Host       _诊断服务主机被诊断策略服务用来承载需要在本地服务上下文中运行的诊断。
::=       WdiSystemHost       _Diagnostic System Host       _诊断系统主机被诊断策略服务用来承载需要在本地系统上下文中运行的诊断。
::=       HomeGroupListener       _HomeGroup Listener       _使本地计算机更改与加入家庭组的计算机的配置和维护相关联。
::=       HomeGroupProvider       _HomeGroup Provider       _执行与家庭组的配置和维护相关的网络任务。
::=       SharedAccess       _Internet Connection Sharing (ICS)       _为家庭和小型办公网络提供网络地址转换、寻址、名称解析和/或入侵保护服务。
::=       CscService       _Offline Files       _脱机文件服务在脱机文件缓存中执行维护活动。
::=       pla       _Performance Logs & Alerts       _性能日志和警报根据预配置的计划参数从本地或远程计算机收集性能数据，然后将该数据写入日志或触发警报。
::=       wercplsupport       _Problem Reports and Solutions Control Panel Support       _“问题报告和解决方案”控制面板的系统级问题报告提供支持。
::=       PcaSvc       _Program Compatibility Assistant Service       _此服务为程序兼容性助手(PCA)提供支持。
::=       SessionEnv       _Remote Desktop Configuration       _远程桌面配置服务(RDCS)负责需要 SYSTEM 上下文的所有远程桌面服务和远程桌面相关的配置和会话维护活动。
::=       TermService       _Remote Desktop Services       _允许用户以交互方式连接到远程计算机。远程桌面和远程桌面会话主机服务器依赖此服务。
::=       UmRdpService       _Remote Desktop Services UserMode Port Redirector       _允许为 RDP 连接重定向打印机/驱动程序/端口。
::=       RemoteRegistry       _Remote Registry       _使远程用户能修改此计算机上的注册表设置。
::=       RemoteAccess       _Routing and Remote Access       _在局域网以及广域网环境中为企业提供路由服务。
::=       seclogon       _Secondary Logon       _在不同凭据下启用启动过程。
::=       LanmanServer       _Server       _支持此计算机通过网络的文件、打印、和命名管道共享。
::=       ShellHWDetection       _Shell Hardware Detection       _为自动播放硬件事件提供通知。
::=       SysMain       _Superfetch       _维护和提高一段时间内的系统性能。
::=       WinDefend       _Windows Defender Service       _帮助用户防止恶意软件及其他潜在的垃圾软件。
::=       WerSvc       _Windows Error Reporting Service       _允许在程序停止运行或停止响应时报告错误，并允许提供现有解决方案。还允许为诊断和修复服务生成日志。
::=       WMPNetworkSvc       _Windows Media Player Network Sharing Service       _使用通用即插即用设备与其他网络播放机和媒体设备共享Windows Media Player 媒体库
::=       WSearch       _Windows Search       _为文件、电子邮件和其他内容提供内容索引、属性缓存和搜索结果。
::=       wuauserv       _Windows Update       _启用检测、下载和安装 Windows 和其他程序的更新。

::----- 进程代码 -----::
@echo.&@echo %DepartLine%
@echo 指令正确。进程开始：
set /a SUM=0
for %%i in (%SerNameSet%) do (
set /a SUM+=1
@echo.&@echo ┎─ START FOR !SUM!：%%i ─┒
sc config %%i start= disabled
@echo.&@echo 状态：
net stop %%i
@echo ┖─  END FOR !SUM!：%%i  ─┚
)
@echo.&@echo %DepartH1% 共处理%SUM%个服务。进程结束并返回。 %DepartH1%
@echo.&@echo %DepartLine%

::DisableUselessServices-END
::SectionEND

::Section-程序完成及退出 ::::::::
:Quit
@echo.&@echo %DepartH0% 全部程序完成，请按任意键退出！ %DepartH0%
pause>nul
for /l %%a in (25 -3 1) do (
      @echo %DepartH0% BYE！ %DepartH0%
      set /a "cols=30+%%a*2"
      call mode con:cols=%%cols%% lines=%%a
)
exit

::QuitEND

::SectionEND
—————————————————————————————————————————————

优化软件
DWS
OOSU10
PCMaster.6.2.1
dism++
BOOTICE
都是常用的，请百度！
建议用vhdx方式安装，可以安装过程中随时备份！

很多朋友在网络上问vhd和硬盘系统怎么转换。
其实很简单，只要在
[HKEY_LOCAL_MACHINE\SYSTEM\MountedDevices]
"\\DosDevices\\C:"=hex:c0,9d,c0,9d,00,20,25,40,01,00,00,00
"\\DosDevices\\D:"=hex:c0,9d,c0,9d,00,00,e0,1f,00,00,00,00
"\\DosDevices\\E:"=hex:c0,9d,c0,9d,00,00,10,00,00,00,00,00
中改成你要安装系统分区（这个分区可以是硬盘，u盘，vhdx等）的hex:
比如你要把c盘系统换到d盘启动
你d盘要是主分区（是否激活无所谓，只要你原来的c盘激活了的就行）
用dism++备份c盘为xxx.wim然后释放到d盘（只释放，wimboot，compact，Windowstogo方式都行）然后改
"\\DosDevices\\D:"=hex:c0,9d,c0,9d,00,20,25,40,01,00,00,00 --原来的c
"\\DosDevices\\C:"=hex:c0,9d,c0,9d,00,00,e0,1f,00,00,00,00 --原来的d
"\\DosDevices\\E:"=hex:c0,9d,c0,9d,00,00,10,00,00,00,00,00
重启引导
首页微软Win11下载正文
Windows Server 2022下载
N软 2021-08-2219:28:37 1  19,407
Windows Server 2022下载

微软服务器版操作系统Windows Server 2022千呼万唤始出来！时光飞逝，老铁们期待的Windows Server 2022官方正式版发布，该操作系统在三个关键主题上引入了许多创新：安全性、Azure 混合集成和管理以及应用程序平台。此外，可借助 “Windows Server 2022 Datacenter：Azure版本”，利用云的优势使 VM保持最新状态，同时最大限度地减少停机时间。微软官方已经正式向VLSC和MSDN发布了Windows Server 2022正式版，最新系统版本及命名简称21H2，OS内部版本为20348.169。

新版变化

Windows Server 版本信息
docs.microsoft.com/zh-cn/windows/release-health/windows-server-release-info

Windows Server 2022 新增功能
docs.microsoft.com/zh-cn/windows-server/get-started/whats-new-in-windows-server-2022

下载地址

Windows Server 2022 简体中文正式版微软官方ISO镜像下载（2021年8月更新）
ISO镜像包含以下版本（根据需要选择安装）：
Windows Server 2022 Standard、Windows Server 2022 Standard (Desktop Experience)、Windows Server 2022 Datacenter、Windows Server 2022 Datacenter (Desktop Experience)

MVS(MSDN)渠道消费者版（即零售版）
Windows Server 2022 (Updated Aug 2021) (x64) - DVD (Chinese-Simplified)
文件名称：zh-cn_windows_server_2022_x64_dvd_6c73507d.iso
SHA1：0DF46441DD01F99459FB75BDB732E7904900A0D7
文件大小：5.41GB
发布时间：2021-08-18
下载地址：zh-cn_windows_server_2022_x64_dvd_6c73507d.iso (5.41 GB)
磁力链接：magnet:?xt=urn:btih:0A63B2E08D5D154A79D408040BE4994917C223D3&dn=zh-cn_windows_server_2022_x64_dvd_6c73507d.iso&xl=5805221888

QQ图片20210923131421.png (89.42 KB, 下载次数: 195)

QQ图片20210923131348.png (63.98 KB, 下载次数: 197)

QQ图片20210923131312.png (87.62 KB, 下载次数: 209)

作者: liujun2000 时间: 2021-9-23 10:58
说到题目的流畅丝滑
是因为我电脑中安装了很多系统
这个系统给我一个感觉就是，，，，，

作者: glzd 时间: 2021-9-23 11:18
放地址出来让大家体验才是真的！

作者: yyjpcx 时间: 2021-9-23 11:25

glzd 发表于 2021-9-23 11:18
放地址出来让大家体验才是真的！

他应该说的官方系统加上他的优化才流畅丝滑

作者: wondaol 时间: 2021-9-23 11:30
Server 版的一个麻烦就是有些如杀软不支持

作者: liujun2000 时间: 2021-9-23 11:37

wondaol 发表于 2021-9-23 11:30
Server 版的一个麻烦就是有些如杀软不支持

长期裸奔不知道杀软是什么呵呵

作者: liujun2000 时间: 2021-9-23 11:39

glzd 发表于 2021-9-23 11:18
放地址出来让大家体验才是真的！

是官方版本直接百度就是了

作者: godsend 时间: 2021-9-23 12:56
真是不聪明,空口说白话,没图没意思,我还在用美国的深蓝电脑呢

作者: liujun2000 时间: 2021-9-23 13:01

godsend 发表于 2021-9-23 12:56
真是不聪明,空口说白话,没图没意思,我还在用美国的深蓝电脑呢

你相信和我有1毛钱关系么呵呵

作者: godsend 时间: 2021-9-23 13:07
哎,可怜的家伙,连截图还没学会,只能打字吸睛拉人

作者: liujun2000 时间: 2021-9-23 13:24

godsend 发表于 2021-9-23 13:07
哎,可怜的家伙,连截图还没学会,只能打字吸睛拉人

QQ图片20210923131312.png (87.62 KB, 下载次数: 209)

作者: 黑中见白 时间: 2021-9-23 13:39
@echo off

rem script: @rgadguard and abbodi406

setlocal EnableExtensions
setlocal EnableDelayedExpansion
set "params=%*"
cd /d "%~dp0" && ( if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs" ) && fsutil dirty query %systemdrive% 1>nul 2>nul || ( echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k cd ""%~sdp0"" && %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs" && "%temp%\getadmin.vbs" && exit /B )

if not exist "%cd%\bin\wimlib-imagex.exe" goto :ConvertLite

:Info
for /f "tokens=3 delims=: " %%b in ('dism /english /online /Get-Intl ^| find /i "System locale"') do (
call bin\lang-uup.cmd -en
if /i %%b==ru-RU call bin\lang-uup.cmd -ru
)
set "file_main=%~n0"
set "aria2=bin\aria2c.exe"
set "rand=%random%"
set "down_temp=%rand%\down"
set "aria2Script=%rand%\aria2_script.txt"
set "BuildInfo=20348.230"
set "lang_def=zh-cn"
set "destDir=uup/!BuildInfo!/!lang_def!/amd64"
set "updateId=2fb8402f-90cb-4516-8758-0f5e38497d60"
mkdir %rand%

%aria2% -x16 -s16 -d"%rand%" -o"aria2_script.txt" "https://uup.rg-adguard.net/api/GetFiles?id=!updateId!&lang=!lang_def!&edition=ServerStandard&txt=yes"
if %ERRORLEVEL% GTR 0 goto DOWNERR
for %%i in ("%aria2Script%") do (if /i %%~zi LEQ 10 goto ERRAPI)

:Tools
set update_en=OFF
set update_num=0
for /f "tokens=1 skip=2" %%a in ('find /N "Windows10.0-KB" "%aria2Script%"') do (
set /a update_num+=1
)
for /f "tokens=6 delims=[]. " %%G in ('ver') do (
if %%G LEQ 9599 set update_num=0
)
if /i %update_num% neq 0 (set update_en=ON)

:DownFiles
title %lang_titke_download%...
if not exist "%destDir%\good" (
%aria2% -x16 -s16 -j5 -c -R -d"%destDir%" -i"%aria2Script%"
if %ERRORLEVEL% GTR 0 goto DOWNERR
echo.>%destDir%\good
)
erase /q /s "%aria2Script%" >NUL 2>&1

color 0a
call bin\convert-UUP.cmd %cd%\uup\!BuildInfo!\!lang_def!\amd64 %update_en%
goto EOF

:ConvertLite
for /f "tokens=3 delims=:. " %%f in ('bitsadmin.exe /CREATE /DOWNLOAD "Download convert_lite" ^| findstr "Created job"') do set GUID=%%f
title Download convert_lite...
bitsadmin /transfer %GUID% /download /priority foreground https://uup.rg-adguard.net/dl/convert_lite.cab "%cd%\convert_lite.cab"
if NOT EXIST convert_lite.cab goto DOWNERR
expand convert_lite.cab -f:* %cd% >nul
del /f /q convert_lite.cab >nul 2>&1
goto :Info

:DOWNERR
color 0c
echo We have encountered an error while downloading files.
erase /q /s "%aria2Script%" >NUL 2>&1
pause
goto EOF

:ERRAPI
color 0c
echo Error getting links to download UUP files.
echo Try again a few minutes later.
erase /q /s "%aria2Script%" >NUL 2>&1
pause
goto EOF

:EOF
exit

作者: wyjhby 时间: 2021-9-23 13:50
很是羡慕呀，有时间也下载安装试用一下

作者: 002 时间: 2021-9-23 14:18
硬件也兼容性牌子好的就可以有些三在机器啥系统也会有毛病

作者: 2011miyahanni 时间: 2021-9-23 14:39
server系统真的能日用吗？

作者: liujun2000 时间: 2021-9-23 14:52

2011miyahanni 发表于 2021-9-23 14:39
server系统真的能日用吗？

长期日用中

作者: wondaol 时间: 2021-9-24 11:29

liujun2000 发表于 2021-9-23 11:37
长期裸奔不知道杀软是什么呵呵

你牛，裸奔。我是装了免费红伞

作者: zchyjsdcy 时间: 2021-9-24 14:30
为什么要用excel97？？

作者: liujun2000 时间: 2021-9-24 14:53

zchyjsdcy 发表于 2021-9-24 14:30
为什么要用excel97？？

小资源占用少而且我就是记账够用了

作者: syj163 时间: 2021-9-24 15:41
感谢楼主分享经验，服务器系统有机会也尝试一下，据说很稳定

作者: manbuzhe719 时间: 2021-9-24 16:22
我也想试用server，但是有些专门软件不知道会不会兼容性有问题

作者: abbatybz 时间: 2021-9-25 12:20
有蓝牙么?

作者: lgkun8 时间: 2021-9-25 14:26
我单位的服务器就只用来共享资料，做无盘服务器，运行一个铃声系统。旧机用的是win2003，现在要换新机，无法安装2003。试过2008r2，2012r2，对旧软件都不太兼用。2022没试过，等买了新机器再测试吧。
前面提的优化几点有帮助，学习了，感谢。

作者: dadadxf 时间: 2021-9-25 16:13
老早就知道这些优化

作者: ysource 时间: 2021-10-23 21:30
批处理怎么使用

作者: legou 时间: 2021-10-24 03:13
真不觉得有啥差别

作者: f111 时间: 2022-1-1 20:41
同文蓝牙能用么？

作者: freeuser 时间: 2022-5-16 20:36
抄作业谢谢楼主提供

作者: hbymyzw 时间: 2022-5-16 20:54
感觉很厉害！

作者: bbst191 时间: 2023-3-6 14:38
流畅丝滑 Windows Server 2022使用记录

作者: 1227cn 时间: 2025-3-20 19:16
谢谢分享

作者: 12956 时间: 2025-5-12 22:43
谢谢楼主提供

作者: aoyabing 时间: 2025-5-13 07:16

黑中见白发表于 2021-9-23 13:39
@echo off

rem script: @rgadguard and abbodi406

请求指导一下——会清除部分桌面图标，请要去掉代码的哪部分才不会清理？？？

作者: bilvnet 时间: 2025-5-13 08:19

aoyabing 发表于 2025-5-13 07:16
请求指导一下——会清除部分桌面图标，请要去掉代码的哪部分才不会清理？？？

好像没有单独的代码

作者: bilvnet 时间: 2025-5-13 08:19
装 Server 标准版好，还是数据中心好？？

欢迎光临无忧启动论坛 (http://bbs.c3.wuyou.net/)