ipxe菜单内嵌实现自动判断服务器，外网内网全协议自动判断启动 - 无忧启动论坛

#!ipxe
:code_begin # Note 2021 by zulinfi
prompt --key 0x02 --timeout 100 Press Ctrl-B for the iPXE shell...${filename} && shell ||
# 全变量设置 web site: ddns aaa.vicp.net bbb.vicp.net ccc.eicp.net and port map web: 80>88 ftp: 21>2121
set pxeFileName ipxe/bootstrap/default
isset ${default_webServerPort} || set default_webServerPort 80
isset ${default_ftpServerpath} || set default_ftpServerpath 21
isset ${default_nfsServerpath} || set default_nfsServerpath /volume2/pxe
isset ${diyWebServerPort} || set diyWebServerPort 88
isset ${diyFtpServerPort} || set diyFtpServerPort 2121
isset ${diyNfsServerpath} || set diyNfsServerpath /volume1/pxe
set totalWanSvr:int32 1 #外网服务器个数
set web_pxe_server0${totalWanSvr} aaa.vicp.net && inc totalWanSvr ||
set web_pxe_server0${totalWanSvr} bbb.vicp.net && inc totalWanSvr ||
set web_pxe_server0${totalWanSvr} ccc.eicp.net #&& inc totalWanSvr ||
isset ${diy_lanPxeServer} || set diy_lanPxeServer 192.168.1.8 #备选服务器ip
# set 66:ipv4 192.168.1.8
set lanSvr_idx:int32 1
set wanSvr_idx:int32 1
# set keep-san 1
:retry_dhcp
ifopen
isset ${ip} || dhcp ||
# buildarch: i386 = bios , x86_64 efi = 64-bit
# platform: pcbios, efi
# iseq ${buildarch} x86_64 && set arch x86_64 || set arch i386 ||
iseq ${platform} efi && set platformStart efi_start || set platformStart pcbios_start ||
cpuid --ext 29 && set arch x86_64 || set arch i386 ||
cpuid 6 && set pae yes ||
cpuid --ecx 5 && set vmx yes ||
cpuid --ext --ecx 2 && set svm yes ||
isset ${vmx} || isset ${svm} && set hw_virt yes ||
:set_Escape_char
set _:hex 2d && set _ ${_:string} # ANSI "-" screen sequence - 2d
set colon:hex 3a && set colon ${colon:string} # ANSI ":" screen sequence - 3a
set mark:hex 23 && set mark ${mark:string} # ANSI "#" screen sequence - 23
set space:hex 20:20 && set space ${space:string} # ANSI " " screen sequence - 20
set lf:hex 0a && set lf ${lf:string} # ANSI "lf:" screen sequence - 0a
set cr:hex 0d && set cr ${cr:string} # ANSI "cr:" screen sequence - 0d
set cls:hex 1b:5b:4a && set cls ${cls:string} # ANSI clear screen sequence - "^[[J"
# 显示常用变量开关
# clear debug_timeout || # isset ${debug_timeout} || set debug_timeout 9000 #调试开关
isset ${menu-timeout} || set menu-timeout 3000
isset ${visableSystemVal} || set visableSystemVal:int32 0
# Note 确定网络启动服务器，并设置网络启动传输协议,本着先内网dhcp服务器->自定服务器->外网服务器, 协议本着先http协议->nfs->ftp->tftp
isset ${debug_timeout} && prompt --key 0x02 --timeout ${debug_timeout} filename: ${filename} ready get next-server and boot protocol. ||
isset ${boot_url} && goto pxeServer_defaultMenu ||
isset ${boot_server} && goto setBootURL ||
prompt --key 0x17 --timeout 500 Press Ctrl-W from WWW boot... && goto tryWanBootProtocol ||
isset ${next-server} && initrd --name default --timeout 1000 tftp://${next-server}/${pxeFileName} && goto setLanBootProtocol ||
isset ${netX/gateway} && initrd --name default --timeout 1000 tftp://${netX/gateway}/${pxeFileName} && set next-server ${netX/gateway} && goto setLanBootProtocol ||
isset ${diy_lanPxeServer} && initrd --name default --timeout 1000 tftp://${diy_lanPxeServer}/${pxeFileName} && set next-server ${diy_lanPxeServer} && goto setLanBootProtocol ||
isset ${next-server} || goto tryWanBootProtocol ||
:setLanBootProtocol
initrd --name default --timeout 2000 http://${next-server}${colon}${default_webServerPort}/${pxeFileName} && set boot_protocol http && set server_port ${colon}${default_webServerPort} && goto setBootURL ||
initrd --name default --timeout 2000 nfs://${next-server}${default_nfsServerpath}/${pxeFileName} && set boot_protocol nfs && set server_port ${default_nfsServerpath} && goto setBootURL ||
initrd --name default --timeout 2000 ftp://${next-server}${colon}${default_ftpServerpath}/${pxeFileName} && set boot_protocol ftp && set server_port ${colon}${default_ftpServerpath} && goto setBootURL ||
initrd --name default --timeout 1000 tftp://${next-server}/${pxeFileName} && set boot_protocol tftp && clear server_port && goto setBootURL ||
iseq ${lanSvr_idx} 2 && goto tryWanBootProtocol || inc lanSvr_idx || # 如果以上全部失败则变更默认端口重试一次
iseq ${default_webServerPort} 80 && set default_webServerPort ${diyWebServerPort} || set default_webServerPort 80 ||
iseq ${default_ftpServerpath} 21 && set default_ftpServerpath ${diyFtpServerPort} || set default_ftpServerpath 21 ||
iseq ${default_nfsServerpath} /volume2/pxe && set default_nfsServerpath ${diyNfsServerpath} || set default_nfsServerpath /volume2/pxe ||
goto setLanBootProtocol ||
:tryWanBootProtocol
set default_webServerPort 80 ||
set default_ftpServerpath 21 ||
set default_nfsServerpath /volume2/pxe ||
:setWanBootProtocol #本地无启动文件则远程尝试Web启动，网络传输协议 http>ftp>nfs
isset ${wanSvr_idx} || set wanSvr_idx:int32 1 ||
initrd --timeout 2000 http://${web_pxe_server0${wanSvr_idx}}${colon}${default_webServerPort}/${pxeFileName} && set boot_server ${web_pxe_server0${wanSvr_idx}} && set wanBoot y && set boot_protocol http && set server_port ${colon}${default_webServerPort} && goto setBootURL ||
initrd --timeout 2000 ftp://${web_pxe_server0${wanSvr_idx}}${colon}${default_ftpServerpath}/${pxeFileName} && set boot_server ${web_pxe_server0${wanSvr_idx}} && set wanBoot y && set boot_protocol ftp && set server_port ${colon}${default_ftpServerpath} && goto setBootURL ||
initrd --timeout 2000 nfs://${web_pxe_server0${wanSvr_idx}}${default_nfsServerpath}/${pxeFileName} && set boot_server ${web_pxe_server0${wanSvr_idx}} && set wanBoot y && set boot_protocol ftp && set server_port ${default_nfsServerpath} && goto setBootURL ||
iseq ${wanSvr_idx} ${totalWanSvr} && goto diyServerPort ||
isset ${debug_timeout} && prompt --timeout ${debug_timeout} wanSvr_idx: ${wanSvr_idx} ${space} totalWanSvr: ${totalWanSvr} ||
inc wanSvr_idx 1 && goto setWanBootProtocol ||
:diyServerPort
iseq ${diyPortTryed} y && goto noAnyServer || set diyPortTryed y ||
clear wanSvr_idx
iseq ${default_webServerPort} 80 && set default_webServerPort ${diyWebServerPort} || set default_webServerPort 80 ||
iseq ${default_ftpServerpath} 21 && set default_ftpServerpath ${diyFtpServerPort} || set default_ftpServerpath 21 ||
iseq ${default_nfsServerpath} /volume2/pxe && set default_nfsServerpath ${diyNfsServerpath} || set default_nfsServerpath /volume2/pxe ||
goto setWanBootProtocol ||
:noAnyServer
isset ${debug_timeout} && prompt --key 0x02 --timeout ${debug_timeout} Error! No Cloud server Online. Server use gateway. Press Ctrl-B for the iPXE shell. && shell ||
set boot_protocol tftp && clear server_port ||
set next-server ${netX/gateway} ||
set boot_server ${netX/gateway} ||
:setBootURL #确定设置网络启动传输协议
iseq ${wanBoot} y && set prefixHostname wanPC || set prefixHostname lanPC ||
iseq ${wanBoot} y || set boot_server ${next-server} ||
set boot_url ${boot_protocol}://${boot_server}${server_port} ||
:code_end
:code_begin # Note 取本机iP地址未位数关赋值本地名称
:start
set hostIP ${netX/ip} ||
set returnMenuPoint getLastIpend && goto Function_getLastIp ||
:getLastIpend
set hostname ${prefixHostname}${Function_getLastIp} ||
:code_end
:code_begin # Note 启动后自动取服务器上的如下菜单顺序尝试加载启动
isset ${debug_timeout} && prompt --timeout ${debug_timeout} filename: ${filename} begin loading order .ipxe by hostname\uuid\mac\bus\default ||
##############ipxe/bootstrap/文件夹下依次先后:###############
# 1.->hostname-${hostname}.ipxe #
# 2.->uuid-${uuid}.ipxe #
# 3.->mac-${mac:hexhyp}.ipxe #
# 4.->bus-${busid:hexhyp}.ipxe #
# 5.->default #
#################default文件为最后通用菜单###################
set boot_ipxe_url ${boot_url}/ipxe # set basedir
set bootstrap_url ${boot_ipxe_url}/bootstrap
set defaultMenuFile ${bootstrap_url}/default
isset ${ServerMenuLoaded} && goto pxeServer_defaultMenu || #如果加载过服务器上的default菜单文件，则跳过再次加载机器特征ipxe与default菜单
set ServerMenuLoaded y ||
# if hostname DHCP variable is set and script is present
chain --autofree --timeout 2000 ${bootstrap_url}/hostname/${hostname}.ipxe ||
# if uuid SMBIOS variable is set and script is present
chain --autofree --timeout 2000 ${bootstrap_url}/uuid/${uuid}.ipxe ||
# Boot <bootstrap_url>/mac/01-02-03-04-05-06.ipxe if script is present 这儿可以设置静态ip地址mac绑定
chain --autofree --timeout 2000 ${bootstrap_url}/mac/${mac:hexhyp}.ipxe ||
# Boot <bootstrap_url>/bus/01-80-86-10-0e.ipxe if PCI Intel adapter is present and script is present
chain --autofree --timeout 2000 ${bootstrap_url}/bus/${busid:hexhyp}.ipxe ||
# Boot ${bootstrap_url}/pci/8086100e.ipxe if one type PCI Intel adapter is present and script is present
# chain --autofree --name default --timeout 2000 ${bootstrap_url}/pci/${pci/${busloc}.0.2}${pci/${busloc}.2.2}.ipxe ||
# Boot ${bootstrap_url}/chip/82541pi.ipxe if one type of PCI Intel adapter is present and script is present
# chain --autofree --name default --timeout 2000 ${bootstrap_url}/chip/${chip}.ipxe ||
imgfree
chain --replace --timeout 2000 ${bootstrap_url}/default && imgstat && prompt begin to exit svrDefault && exit || goto serverNotReady ||
# --replace chain加载的映像/脚本即为最终映像，完成后退出系统。不加此选项类似call命令，结束chain调用后从此映像/脚本断点后面继续执行。
:serverNotReady
isset ${debug_timeout} && prompt --timeout ${debug_timeout} Not found bootfile or server Not Ready ! Press any key enter system menu. ||
clear ServerMenuLoaded && goto Function_topMenuShow || #设置已尝试机器特征菜单失败后只显示本地相关功能菜单
# 内建菜单结束外置菜单default开始
:pxeServer_defaultMenu
isset ${debug_timeout} && prompt --timeout ${debug_timeout} Ready ! Press any key enter system. ||
isset ${debug_timeout} && prompt --key 0x02 --timeout ${debug_timeout} Begin load bootServer ipxemenu and set var Press Ctrl-B for the iPXE shell. && shell ||
:code_end
#chain --autofree ${bootstrap_url}/default && exit || 以下代码略
#chain --autofree ${bootstrap_url}/init.ipxe && exit ||

复制代码