哪位高手写个vbs或者批处理查看浏览器插件信息（找到替代方案） - 无忧启动论坛

!include "MUI2.nsh"
!include "LogicLib.nsh"
!include "FileFunc.nsh"
!define PRODUCT_NAME "获取Chrome已安装插件信息"
Name "${PRODUCT_NAME}"
Caption "${PRODUCT_NAME}"
OutFile "${PRODUCT_NAME}.exe"
BrandingText " "
ManifestDPIAware true
XPStyle on
ShowInstDetails show
SetFont "Microsoft YaHei" 9
RequestExecutionLevel user
; InstallDir "D:\Chrome109\UserData\Default"
SpaceTexts 'none' 'none'
InstallButtonText "查找"
; 程序图标
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\info.ico"
!define MUI_PAGE_CUSTOMFUNCTION_SHOW "func_hide"
!define MUI_DIRECTORYPAGE_TEXT_TOP " "
!define MUI_DIRECTORYPAGE_TEXT_DESTINATION "选择 Default 路径："
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "SimpChinese"
Var out
Section
SetDetailsPrint none
SetOutPath "$INSTDIR\Extensions"
FileOpen $out "$EXEDIR\已安装插件信息.txt" w
FileWrite $out "目录：$INSTDIR$\r$\n$\r$\n"
FileWrite $out "版本$\t$\t名称$\t$\t路径$\r$\n"
${Locate} "$OUTDIR" "/M=manifest.json" "func_findjson"
FileClose $out
SetDetailsPrint both
DetailPrint "文件已保存到程序所在目录：已安装插件信息.txt"
SectionEnd
Function func_findjson
; $R9 "path\name"
; $R8 "path"
; $R7 "name"
; $R6 "size" ($R6="" 如果是文件夹，$R6="0" 如果是文件 (带 /S= 参数时))
; $R0-$R5 未使用，可用于保存数据
; ...
; Push $var ; 如果 $var="StopLocate" 则退出函数
nsJSON::Set /file "$R9"
nsJSON::Get "name" /end
Pop $R0
nsJSON::Get "version" /end
Pop $R1
${GetParent} "$R8" $R5
FileWrite $out "$R1$\t$\t$R0$\t$\t$R5$\r$\n"
Push $1
FunctionEnd
Function func_hide
; 隐藏一些界面元素
GetDlgItem $0 $HWNDPARENT 1034
ShowWindow $0 0
GetDlgItem $0 $HWNDPARENT 1036
ShowWindow $0 0
GetDlgItem $0 $HWNDPARENT 1037
ShowWindow $0 0
GetDlgItem $0 $HWNDPARENT 1038
ShowWindow $0 0
GetDlgItem $0 $HWNDPARENT 1039
ShowWindow $0 0
GetDlgItem $0 $HWNDPARENT 1006
ShowWindow $0 0
FunctionEnd

复制代码

# python 3.*
import os
import json
from tkinter.filedialog import askdirectory
opendir = askdirectory(title='选择 Default 目录', mustexist=True)
list = []
for root,dirs,files in os.walk(opendir, r'manifest.json'):
for i in files:
list.append(os.path.join(root, i))
with open(os.path.join(root, i), 'r', encoding='utf-8') as f:
dict = json.load(f)
if 'short_name' in dict.keys():
name = dict['short_name']
else:
name = dict['name']
print(os.path.abspath(os.path.dirname(root)), ' {: <10}'.format(dict['version']), name)
del name
print('\n\n')
os.system('pause')

复制代码