使用SetupComplete.cmd代替unattend.xml实现无人值守安装系统 - 无忧启动论坛

@echo off
:: 配置用户
set user=baby1277
net user %user% "" /add
:: 激活管理员账户
net localgroup administrators %user% /add
net user %user% /active:yes
if /i not "%user%"=="Administrator" net user Administrator /active:no
:: 配置自动登录
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v AutoAdminLogon /t REG_SZ /d 1 /f
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultUserName /t REG_SZ /d %user% /f
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultPassword /t REG_SZ /d "" /f
:: 跳过OOBE
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\OOBE" /v "SkipMachineOOBE" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\OOBE" /v "SkipUserOOBE" /t REG_DWORD /d 1 /f

复制代码

<?xml version="1.0" encoding="utf-8"?>
<unattend xmlns="urn:schemas-microsoft-com:unattend">
<settings pass="oobeSystem">
<component name="Microsoft-Windows-International-Core" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS">
<InputLocale>zh-CN</InputLocale>
<SystemLocale>zh-CN</SystemLocale>
<UILanguage>zh-CN</UILanguage>
<UserLocale>zh-CN</UserLocale>
</component>
<component name="Microsoft-Windows-Shell-Setup" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS">
<OOBE>
<ProtectYourPC>3</ProtectYourPC>
<HideEULAPage>true</HideEULAPage>
<HideOEMRegistrationScreen>true</HideOEMRegistrationScreen>
<HideWirelessSetupInOOBE>true</HideWirelessSetupInOOBE>
<HideOnlineAccountScreens>true</HideOnlineAccountScreens>
<HideLocalAccountScreen>true</HideLocalAccountScreen>
<SkipMachineOOBE>true</SkipMachineOOBE>
<SkipUserOOBE>true</SkipUserOOBE>
</OOBE>
</component>
</settings>
</unattend>

复制代码

@echo off
setlocal enabledelayedexpansion
title 创建用户，请勿关闭本窗口
for /l %%i in (10, -1, 1) do (
<nul set /p="将于 %%i 秒后自动创建 admin 空密码用户并退出，按任意键创建自定义用户 ..."
powershell.exe -noprofile -command "if ([console]::KeyAvailable) { $host.UI.RawUI.FlushInputBuffer(); exit 1 } else { exit 0 }" >nul 2>nul
if errorlevel 1 (cls & goto :want_uname)
ping 127.0.0.1 -n 1 -w 1000 >nul
cls
)
cls
net user admin /add >nul 2>nul && (
net localgroup administrators admin /add >nul 2>nul && (echo 自动创建 admin 空密码用户成功，即将退出 & timeout /t 2 >nul & exit) || (net user admin /delete >nul 2>nul)
)
echo 自动创建 admin 空密码用户失败，强制创建自定义用户
:want_uname
echo.
set "uname="
set /p uname=请键入用户名:
if "%uname%" == "" goto want_uname
:want_upass
set "upass="
for /f "delims=" %%P in ('powershell.exe -NoProfile -Command "$pwd = Read-Host ''请键入用户的密码'' -AsSecureString; [System.Runtime.InteropServices.Marshal]::PtrToStringAuto([System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pwd))"') do set "upass=%%P"
set "upass2="
for /f "delims=" %%P in ('powershell.exe -NoProfile -Command "$pwd = Read-Host ''请再键入一次密码以便确认'' -AsSecureString; [System.Runtime.InteropServices.Marshal]::PtrToStringAuto([System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pwd))"') do set "upass2=%%P"
if "%upass%" neq "%upass2%" (echo 密码不匹配。 & goto want_upass)
if "%upass%" equ "" (
net user %uname% /add >nul 2>nul && (
net localgroup administrators %uname% /add >nul 2>nul && (echo 创建 %uname% 用户成功，即将退出 & timeout /t 2 >nul & exit) || (echo 加入管理员群组失败 & net user %uname% /delete >nul 2>nul & goto want_uname)
) || (echo 创建 %uname% 用户失败 & goto want_uname)
) else (
net user %uname% %upass% /add >nul 2>nul && (
net localgroup administrators %uname% /add >nul 2>nul && (echo 创建 %uname% 用户成功，即将退出 & timeout /t 2 >nul & exit) || (echo 加入管理员群组失败 & net user %uname% /delete >nul 2>nul & goto want_uname)
) || (echo 创建 %uname% 用户失败 & goto want_uname)
)
exit

复制代码

start /wait "localaccount" "%~dp0localaccount.cmd"

复制代码

reg load HKEY_USERS\uuu z:\Users\Default\ntuser.dat >nul 2>nul
reg.exe add "HKEY_USERS\uuu\SOFTWARE\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport" /v "PDEShown" /t REG_DWORD /d "2" /f >nul 2>nul
reg unload HKEY_USERS\uuu >nul 2>nul

复制代码

@echo off
setlocal enabledelayedexpansion
title 设置计算机名，请勿关闭本窗口
set "cname=WIN-%RANDOM%"
for /l %%i in (10, -1, 1) do (
<nul set /p="将于 %%i 秒后自动设置计算机名为 %cname% 并退出，按任意键手工设置 ..."
powershell.exe -noprofile -command "if ([console]::KeyAvailable) { $host.UI.RawUI.FlushInputBuffer(); exit 1 } else { exit 0 }" >nul 2>nul
if errorlevel 1 (cls & goto :want_name)
ping 127.0.0.1 -n 1 -w 1000 >nul
cls
)
cls
goto set_name
:want_name
echo.
set "cname="
set /p cname=请键入计算机名(字母、连字符和数字的组合):
if "%cname%" == "" goto want_name
:set_name
powershell.exe -noprofile -command "Rename-Computer -NewName '%cname%'" >nul 2>nul
if errorlevel 0 (echo 设置计算机名为 %cname% 成功，即将退出 & timeout /t 2 >nul & exit)
echo 设置计算机名为 %cname% 失败 & goto want_name
exit

复制代码