无忧启动论坛

标题: 64GB内存电脑的一些使用心得，延长了SSD寿命（图文） [打印本页]

作者: D_M_GuYing 时间: 昨天 09:47
标题: 64GB内存电脑的一些使用心得，延长了SSD寿命（图文）
本帖最后由 D_M_GuYing 于 2025-12-8 10:49 编辑

授之以鱼，不如授之以渔。我只是说一些我的心得和思路，使大内存在日常能利用起来，我现在的电脑如此设置后，N天不关机，C盘和D盘的空间基本就没有涨，也是保护SSD，基本上写的东西都让内存盘给承担了，欢迎讨论进步，不喜勿喷！！一次复杂，终身受用，利用了内存，保护延长了SSD寿命，值得！！

我的电脑是m15r6外星人笔记本，硬件如上图，系统是VHD系统，23H2企版本（因为我是11代U，25H2的新功能对我用处不大，还是23H2适合我，但我的使用方法在25H2一样适用），一个500G的SSD用于系统相关，另一个一T的SSD做存储用。直接说正题。

一，虚拟内存，设置为0，如果有些软件一定要开虚拟内存才可以，那就设置200MB

二，安装Primo Ramdisk，创建一个虚拟内存盘，我设置的是R盘，40G，用Primo Ramdisk的实用工具，将TEMP的环境变量R:\temp下

三，创建一个setup.cmd，添加到任务计划，这样做对VHD系统好处多多，我是做的每次启动还原系统到23H2.vhdx状态，有个这个setup.cmd，可以对23H2.vhdx进行小修补，不用整个重备份23H2.vhdx

四，软件安装
尤其是VHD系统，开机自建了C盘，实际文件在"D:\SYS\23H2.vhdx"，尽可能的把桌面，文档等文件夹移到D盘，程序也安装到"D:\Program Files"。Office安装，请看下面实例

五，最核心的部分就是setup.cmd，最核心的应用就是建立MKLINK链接，如果你跟我一样总是要下载电影电视剧，就把下载文件夹MKLINK到R盘，可以把一些软件的缓存链接到内存盘R盘下，有些自定义的预设放到D盘下，这样即不影响每次启动还原系统，也不影响你上次使用时自定义的设置，比如，安装Office，可先MKLINK链接到D盘再安装，写在SETUP.CMD下就可以

::ANSI中文
@echo off
pushd %~dp0 & cd /d "%~dp0"

:open
echo aa>r:\a.txt
if not exist "r:\a.txt" TIMEOUT /T 2 >nul&&goto :open
del /f /q "r:\a.txt" 2>nul

:Office
SET lnkone=C:\Program Files\Microsoft Office
set lnktwo=D:\Program Files\Microsoft Office & call :golink
SET lnkone=C:\Program Files\Microsoft Office 15
set lnktwo=D:\Program Files\Microsoft Office 15 & call :golink

exit

:golink
if not exist "%lnkone%" md "%lnkone%"
rmdir "%lnkone%" /s /q
if not exist "%lnktwo%" md "%lnktwo%"
MKLINK "%lnkone%" "%lnktwo%" /J
goto :eof

比如向日葵远程控制的自定义设置可以在open子脚本的下面加上
SET lnkone=C:\Users\Administrator\AppData\Roaming\Oray
set lnktwo=D:\Program Files\Roaming\Oray & call :golink

比如浏览器相关，选复制C:\Program Files (x86)\Microsoft到D:\Program Files\Microsoft
:Edge
set edgef=User Data
SET lnkone=C:\Program Files (x86)\Microsoft
set lnktwo=D:\Program Files\Microsoft & call :golink
SET lnkone=D:\Program Files\Microsoft\EdgeUpdate\Download
set lnktwo=R:\TEMP\EdgeTemp\Download & call :golink
SET lnkone=D:\Program Files\Microsoft\Edge\Temp
set lnktwo=R:\TEMP\EdgeTemp\Temp & call :golink
SET lnkone=C:\Users\Administrator\AppData\Local\Microsoft\Edge\User Data
set lnktwo=R:\TEMP\EdgeTemp\%edgef% & call :golink
if not exist "R:\TEMP\EdgeTemp\%edgef%\a.txt" xcopy "D:\Program Files\Microsoft\User Data\*.*" "R:\TEMP\EdgeTemp\%edgef%\" /s /e /y

说明：set edgef=User Data是用来调试的，比如先set edgef=U，Edge启动后，把你常去的网站去登录一次，比如你的微软账号，139信箱.....，
设置浏览器关闭时清除

退出浏览器，复制"R:\TEMP\EdgeTemp\U"到 "D:\Program Files\Microsoft\User Data"，再把set edgef=U改回set edgef=User Data，这个文件夹不到100M，每次启动，SETUP.CMD会复制回R盘，这样弄完了，就不会日子久了C盘下的User Data动不动就几个G，缓存在内存盘下运行也快一些

六，关于VHD系统的安装与设置，例：
1，进入PE或在当前系统下，右键我的电脑--管理--创建23H2,初始化，格式化后，用你自己熟悉的方式安装到这个盘里就可以了，
2，安装，启动，调整到最佳状态，进入PE，创建23H2.vhdx的差分A.vhdx，修改BCD指向A.vhdx
3，如果小修补，可在SETUP.CMD加代码，比如我的之前没设置，现在就加上了

:移除主文件夹图标
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\{f874310e-b6b7-47dc-bc84-b9e6b38f5903}" /f
:移除图库图标
reg add "HKCU\Software\Classes\CLSID\{e88865ea-0e1c-4e20-9aa6-edcd0212c87c}" /f /v "System.IsPinnedToNameSpaceTree" /t REG_DWORD /d 0

echo 正在停止并禁用服务...
sc stop NVDisplay.ContainerLocalSystem >nul 2>&1
sc config NVDisplay.ContainerLocalSystem start= disabled >nul 2>&1
sc stop "igfxCUIService2.0.0.0" >nul 2>&1
sc config "igfxCUIService2.0.0.0" start= disabled >nul 2>&1

七，VHD的更新，比如在A.vhdx下，更新了系统版本
1，进入PE，在磁盘管理下创建一个新的XXX.vhdx,创建后就退出窗口，不要继续操作
2，双击A.vhdx挂载磁盘，在DismGui程序下，磁盘对考，XXX.vhdx会在你选择列表中。
3，对考完成，删除23H2.vhdx和A.vhdx，将XXX.vhdx改成23H2.vhdx重建差分A.vhdx，这样你就得到了一个新的最小体积的原始镜像

八，Hyper-V相关
1，在setup.cmd下添加
:Hyper-V
SET lnkone=C:\ProgramData\Microsoft\Windows\Hyper-V
set lnktwo=D:\Program Files\Hyper-V & call :golink

可保证第次还原重启里，你新增加的虚机机列表还在
2，给虚拟机硬盘文件加个子差分，SETUP.CMD中，每次启动复制这个子差分，虚拟机磁盘文件指向R盘的子差分，我游戏挂机，测试软件都这么做
3，同样的道理，把游戏做成VHDX，读取母VHDX，写和缓存都在R盘

九，每次启动后自动还原，将CMD放在23H2.vhdx同级文件夹下，比如"D:\SYS\更新启动项.cmd"，在SETUP中增加一行

start "" "D:\SYS\更新启动项.cmd"

更新启动项.cmd
--------------------------------------
@echo off
chcp 65001 >nul 2>&1
setlocal enabledelayedexpansion
cls

:: 差分子文件变量
set "VHD1=A.vhdx"
set "VHD2=B.vhdx"
:: 父文件变量
set "BASE_VHD=23h2.vhdx"

:: 强制删除A.vhdx和B.vhdx（无论是否存在）
echo 正在清理旧文件...
if exist "!VHD1!" (
del /f /q "!VHD1!" >nul 2>&1
if not exist "!VHD1!" (echo ✅ 已删除 !VHD1!) else (echo ⚠️ 无法删除 !VHD1!，可能被占用)
)
if exist "!VHD2!" (
del /f /q "!VHD2!" >nul 2>&1
if not exist "!VHD2!" (echo ✅ 已删除 !VHD2!) else (echo ⚠️ 无法删除 !VHD2!，可能被占用)
)
echo.

:: 1. 获取当前目录
pushd %~dp0 & cd /d "%~dp0"
set "CUR_DIR=%cd%"
echo Current folder: %CUR_DIR%
echo VHD files to switch: %VHD1% ↔ %VHD2%

:: 2. 提取盘符和路径
set "DRIVE=%CUR_DIR:~0,2%"
set "REL_PATH=%CUR_DIR:~2%"

:: 3. 自动搜索VHD启动项ID
echo.
echo 正在自动搜索VHD启动项ID...
set "VHDX_ID="
set "in_vhd_entry=0"

:: 遍历bcdedit输出，提取包含"vhd"的启动项ID
for /f "tokens=1,* delims=:" %%a in ('bcdedit /enum /v 2^>nul') do (
:: 清理行首空格和特殊字符
set "line=%%a%%b"
set "line=!line: =!"

:: 检测到标识符行，提取ID
if "!line:~0,10!"=="identifier" (
      set "current_id=!line:identifier=!"
      set "current_id=!current_id:{=!"  :: 移除左大括号
      set "current_id=!current_id:}=!"  :: 移除右大括号
      set "current_id=!current_id:"=!"  :: 移除引号
      set "in_vhd_entry=0"  :: 重置标记
)

:: 检测到包含"vhd"的行，标记为VHD启动项
echo "!line!" | findstr /i "vhd" >nul 2>&1
if !errorlevel! equ 0 (
      set "in_vhd_entry=1"
)

:: 若在VHD启动项中且已获取ID，则确定为目标ID
if !in_vhd_entry! equ 1 if defined current_id (
      set "VHDX_ID={!current_id!}"
      goto :found_vhd_id  :: 找到后退出循环
)
)
:found_vhd_id

:: 验证ID是否存在
if "!VHDX_ID!"=="" (
echo ❌ 错误：未找到VHD类型的启动项，请检查系统配置
pause
exit /b 1
)
echo ✅ 找到VHD启动项ID：!VHDX_ID!

:: 4. 构建路径
set "SUFFIX_DEVICE=,locate=custom:12000002"
set "SUFFIX_OSDEVICE=,locate=custom:22000002"
set "VHD1_DEV=vhd=[%DRIVE%]%REL_PATH%\%VHD1%%SUFFIX_DEVICE%"
set "VHD1_OS=vhd=[%DRIVE%]%REL_PATH%\%VHD1%%SUFFIX_OSDEVICE%"
set "VHD2_DEV=vhd=[%DRIVE%]%REL_PATH%\%VHD2%%SUFFIX_DEVICE%"
set "VHD2_OS=vhd=[%DRIVE%]%REL_PATH%\%VHD2%%SUFFIX_OSDEVICE%"

:: 5. 检测文件存在性（清理后应该都不存在）
set "VHD1_EXIST=0"
set "VHD2_EXIST=0"
if exist "%CUR_DIR%\%VHD1%" set "VHD1_EXIST=1"
if exist "%CUR_DIR%\%VHD2%" set "VHD2_EXIST=1"

:: 6. 显示检测结果
echo.
echo ==============================================
echo  File Detection:
if %VHD1_EXIST% equ 1 (echo ✅ %VHD1% exists) else (echo ❌ %VHD1% not found)
if %VHD2_EXIST% equ 1 (echo ✅ %VHD2% exists) else (echo ❌ %VHD2% not found)
echo ==============================================

:: 7. 确定目标差分文件
set "TARGET="
set "NEW_DEV="
set "NEW_OS="

if %VHD1_EXIST% equ 1 (
set "TARGET=%VHD2%"
set "NEW_DEV=%VHD2_DEV%"
set "NEW_OS=%VHD2_OS%"
) else if %VHD2_EXIST% equ 1 (
set "TARGET=%VHD1%"
set "NEW_DEV=%VHD1_DEV%"
set "NEW_OS=%VHD1_OS%"
) else (
:: 当A和B都不存在时，默认使用A.vhdx
set "TARGET=%VHD1%"
set "NEW_DEV=%VHD1_DEV%"
set "NEW_OS=%VHD1_OS%"
echo 提示：所有文件均不存在，默认切换目标为 %TARGET%
)

:: 8. 先执行差分文件创建任务
echo.
echo ==============================================
echo 子文件创建任务：
echo  母文件：%BASE_VHD%
echo  子文件：%TARGET%（与启动目标一致）
echo  目标路径：%CUR_DIR%
echo ==============================================

set "CREATE_SUCCESS=0"
:: 检查母文件是否存在
if not exist "%CUR_DIR%\%BASE_VHD%" (
echo ❌ 错误：母文件 %BASE_VHD% 未在 %CUR_DIR% 找到，无法创建子文件
) else (
echo ⚠️  正在创建差分文件（需管理员权限）...
(
      echo create vdisk file="%CUR_DIR%\%TARGET%" parent="%CUR_DIR%\%BASE_VHD%"
      echo exit
) | diskpart

:: 验证差分文件创建结果
if exist "%CUR_DIR%\%TARGET%" (
      echo ✅ 成功：差分文件 %TARGET% 已创建 → %CUR_DIR%\%TARGET%
      set "CREATE_SUCCESS=1"
) else (
      echo ❌ 失败：差分文件未创建，请检查权限和母文件完整性
)
)
echo ==============================================

:: 9. 只有差分文件创建成功后，才执行引导切换
if %CREATE_SUCCESS% equ 1 (
echo.
echo Auto-switching to %TARGET%...
bcdedit /enum %VHDX_ID% >nul 2>&1
timeout /t 1 /nobreak >nul

bcdedit /set %VHDX_ID% device "%NEW_DEV%" >nul
bcdedit /set %VHDX_ID% osdevice "%NEW_OS%" >nul
bcdedit /enum %VHDX_ID% >nul 2>&1
timeout /t 1 /nobreak >nul

:: 验证引导切换结果
set "FINAL_DEV="
for /f "tokens=2,*" %%a in ('bcdedit /enum %VHDX_ID% /v ^| findstr /i "device "') do set "FINAL_DEV=%%b"

echo.
echo ==============================================
echo Switch Completed! Target: %CUR_DIR%\%TARGET%
echo Final Path: %FINAL_DEV%
echo ==============================================
if "%FINAL_DEV%"=="%NEW_DEV%" (
      echo ✅ Success: Path is correct
) else (
      echo ⚠️  Success: Actual path set to %NEW_DEV%
)
) else (
echo.
echo ⚠️  差分文件创建失败，未修改启动引导配置
echo.
echo 按任意键退出...
set /p=
)

endlocal
exit

作者: win82 时间: 昨天 09:50
感谢分享

作者: wsdyleon 时间: 昨天 09:50
是ramos吗？我一般用冰点还原。不过可能会损失一点性能

作者: smile_z 时间: 昨天 09:56
学习一下

作者: D_M_GuYing 时间: 昨天 09:57

wsdyleon 发表于 2025-12-8 09:50
是ramos吗？我一般用冰点还原。不过可能会损失一点性能

是Primo Ramdisk，在咱们坛里有PJ的，用服务器版最好，

作者: lixiangliuyi 时间: 昨天 10:02
不更新系统，微信聊天记录不存在C盘，没啥乱七八糟的后台流氓软件，c盘基本不会涨。

很多人C盘满了，基本就是微信聊天记录塞满了。你还不能说，
你说了。张小龙就会皮笑肉不笑的回一句：每天都有几亿人在教我如何做产品

作者: 小龙飞 时间: 昨天 10:04
感谢您的分享！

作者: dysunb 时间: 昨天 10:05
奢侈啊，64G

作者: a66 时间: 昨天 10:09
越折腾越快乐

作者: 剑转流云 时间: 昨天 10:10
现在内存贵了，玩不起。

作者: D_M_GuYing 时间: 昨天 10:10

lixiangliuyi 发表于 2025-12-8 10:02
不更新系统，微信聊天记录不存在C盘，没啥乱七八糟的后台流氓软件，c盘基本不会涨。

很多人C盘满了，基 ...

那你看下，你现在"C:\Users\Administrator\AppData\Local\Microsoft\Edge"文件夹有多大了？
我这样设置，也是保护SSD，基本上写的东西都让内存盘给承担了

我的微信基本不用留聊天记录之类的，因为手机里有，所以我下SETUP.CMD下加了
:WeChat
SET lnkone=E:\文档\xwechat_files
set lnktwo=D:\Program Files\Tencent\xwechat_files & call :golink
SET lnkone=D:\Program Files\Roaming\Tencent\xwechat\xplugin
set lnktwo=R:\TEMP\WeChat Files\xwechat\xplugin & call :golink
SET lnkone=D:\Program Files\Roaming\Tencent\xwechat\update
set lnktwo=R:\TEMP\WeChat Files\xwechat\update & call :golink
SET lnkone=D:\Program Files\Roaming\Tencent\xwechat\radium\cache
set lnktwo=R:\TEMP\WeChat Files\xwechat\radium\cache & call :golink
SET lnkone=D:\Program Files\Roaming\Tencent\xwechat\radium\WmpfCache
set lnktwo=R:\TEMP\WeChat Files\xwechat\radium\WmpfCache & call :golink
SET lnkone=D:\Program Files\Roaming\Tencent\xwechat\radium\xworker
set lnktwo=R:\TEMP\WeChat Files\xwechat\radium\xworker & call :golink

SET lnkone=D:\Program Files\Tencent\xwechat_files\wxid_a8q9ggqek08521_76fc\cache
set lnktwo=R:\TEMP\WeChat Files\\xwechat_files\wxid_a8q9ggqek08521_76fc\cache & call :golink
SET lnkone=D:\Program Files\Tencent\xwechat_files\wxid_a8q9ggqek08521_76fc\temp
set lnktwo=R:\TEMP\WeChat Files\\xwechat_files\wxid_a8q9ggqek08521_76fc\temp & call :golink
SET lnkone=D:\Program Files\Tencent\xwechat_files\wxid_a8q9ggqek08521_76fc\db_storage
set lnktwo=R:\TEMP\WeChat Files\\xwechat_files\wxid_a8q9ggqek08521_76fc\db_storage & call :golink
SET lnkone=D:\Program Files\Tencent\xwechat_files\wxid_a8q9ggqek08521_76fc\msg
set lnktwo=R:\TEMP\WeChat Files\xwechat_files\wxid_a8q9ggqek08521_76fc\msg & call :golink
SET lnkone=D:\Program Files\Tencent\xwechat_files\WMPF
set lnktwo=R:\TEMP\WeChat Files\\xwechat_files\WMPF & call :golink
SET lnkone=D:\Program Files\Tencent\xwechat_files\Backup
set lnktwo=R:\TEMP\WeChat Files\xwechat_files\Backup & call :golink

作者: Climbing 时间: 昨天 10:11
看打了这么多字，怪不容易的，有必要搞得这么复杂吗？

作者: srj001 时间: 昨天 10:14
64G不是随便造吗

作者: yyz2191958 时间: 昨天 10:16
技术贴谢谢

作者: kanon｜ 时间: 昨天 10:18
感谢分享，学习了

作者: liuyang2025 时间: 昨天 10:24
感谢分享，很实用，楼主辛苦了

作者: D_M_GuYing 时间: 昨天 10:25

Climbing 发表于 2025-12-8 10:11
看打了这么多字，怪不容易的，有必要搞得这么复杂吗？

有必要，一次复杂，终身受用，利用了内存，保护延长了SSD寿命，值得！！

作者: anyscai 时间: 昨天 10:26
需要有这样配置的电脑才能用？

作者: mwolf 时间: 昨天 10:33
16G内存，虚拟4G，常用绿软及windows写操作都通过powershell同步到R:，关机回写，ps1放入startup快捷方式，日常刷视频小游戏延迟无感，固态写入减少20-50%

作者: yzszh64 时间: 昨天 10:36
学习，谢谢分享。

作者: D_M_GuYing 时间: 昨天 10:37

mwolf 发表于 2025-12-8 10:33
16G内存，虚拟4G，常用绿软及windows写操作都通过powershell同步到R:，关机回写，ps1放入startup快捷方式， ...

powershell同步到R:？？这一步怎么做到哇

作者: fulibo 时间: 昨天 10:38
不错哦!我的浏览器需要这种设置

作者: wn168cn@163.com 时间: 昨天 10:40
感谢分享

作者: ge 时间: 昨天 10:43
本帖最后由 ge 于 2025-12-8 17:56 编辑

有道理！但是我選擇了linux，也沒有分配swap

作者: wondaol 时间: 昨天 10:55
64G内存，够大

作者: 1999 时间: 昨天 10:55

ge 发表于 2025-12-8 10:43
有道理！但是我選擇了linux，也沒有分配swap。還有64太小了

作者: 好好学些 时间: 昨天 11:03
支持楼主

作者: hmaaaa 时间: 昨天 11:07
謝謝您的分享 ^^ 有您真好。辛苦了！^^

作者: erdos47 时间: 昨天 11:10
感谢您的分享！

作者: 单田芳 时间: 昨天 11:14
太好了，谢谢楼主的建议。

作者: 单田芳 时间: 昨天 11:16
太好了，不用再花钱冲了

作者: valen21 时间: 昨天 11:17
感谢分享

作者: xiao878 时间: 昨天 11:23
教程很受用，谢谢

作者: tcl123 时间: 昨天 11:23
学习一下，好方法

作者: 董大 时间: 昨天 11:23
辛苦了！谢谢楼主热心分享!

作者: guong 时间: 昨天 11:28
64G内存够豪华的

作者: hudaluoshen 时间: 昨天 11:29
个人认为：没必要，目前大部分固态是TLC，撑个七八年可以啦，到时电脑升级直接换。保护SSD对我来说实在有些滑稽。
真有数据存储就固态+机械（或网盘）
我的习惯是，装系统后第一时间关WD，改几个默认文件夹存放位置。
系统和软件全装C盘，系统随便格式化重装，重装完实际体验和原系统基本一样

作者: kimleee 时间: 昨天 11:31
非常棒的技术贴！

作者: yuzmb 时间: 昨天 11:31
感谢分享，学习了

作者: 2011564267265 时间: 昨天 11:32
大容量内存当下是赢家

作者: aker 时间: 昨天 11:37
本帖最后由 aker 于 2025-12-8 11:39 编辑

我没搞那么复杂的，就用Primo Ramdisk就分了8G内存，把临时文件，下载都丢里面。这样用了好多年了。其实SSD也没那么脆弱，当然能减少点损耗也是好的。

作者: imslc 时间: 昨天 11:40
操作好复杂，谢谢分享

作者: cncecpcy 时间: 昨天 11:44
好。。。。。。。。。。。

作者: john138 时间: 昨天 11:57
感謝分享

作者: john138 时间: 昨天 12:04
64G，可以使用RAMOS了，除了開機費時點，其他沒有缺點。

作者: 地球守护者 时间: 昨天 12:04
楼层主人，其实，我想象需要说明一个事情，现在很多都是固态硬盘+机械硬盘，纯净固态硬盘，不是存在，真正存在纯净固态硬盘，非常很少，原因就是，固态硬盘，除了运行速度很快，任何优点，没有多少优点，机械硬盘，完全可以纯净机械硬盘使用，不会出现固态硬盘，依赖靠拢机械硬盘，放心存储内容，机械硬盘优点，大型于是固态硬盘优点

作者: zlq_hysy 时间: 昨天 12:16
羡慕64G内存。我主用机才12G，副用机最小的2G

作者: D_M_GuYing 时间: 昨天 12:19
本帖最后由 D_M_GuYing 于 2025-12-8 12:21 编辑

hudaluoshen 发表于 2025-12-8 11:29
个人认为：没必要，目前大部分固态是TLC，撑个七八年可以啦，到时电脑升级直接换。保护SSD对我来说实在有些 ...

我是安装之前就删除了WD，浏览器，N个APPs，就算直接装C盘，那也是安装后，运行一下SETUP.CMD，用过的绿软，拿来就用。需要安装的，安装后，不用第二次设置，自定义设置和以前的一样一样比如向日葵远程控制，程序是最新的，登录信息，设置的密码等自定义的东西还在，也是拿来就能用。

作者: ge 时间: 昨天 12:21

1999 发表于 2025-12-8 10:55
NB

沒有什麼吧？我也是剛開始學，像剛開始用Windows一樣，關鍵是走出第一步

作者: ge 时间: 昨天 12:24
我看錯了，我先以為64G是硬碟呢

作者: laozhao 时间: 昨天 12:25
环境变量temp和tmp改到内存盘r:\temp，再把pagefile改小一点和浏览器cache改到r盘，基本就可以了，没必要这么复杂

作者: D_M_GuYing 时间: 昨天 12:26

ge 发表于 2025-12-8 12:21
沒有什麼吧？我也是剛開始學，像剛開始用Windows一樣，關鍵是走出第一步

第一步好走，以下的路可是长着呢，入门易，进阶难呀

作者: ge 时间: 昨天 12:30

D_M_GuYing 发表于 2025-12-8 12:26
第一步好走，以下的路可是长着呢，入门易，进阶难呀

不怕，當年用Windows時不是依然一無所知？至少現在能有一些知識是公用的

作者: D_M_GuYing 时间: 昨天 12:37

aker 发表于 2025-12-8 11:37
我没搞那么复杂的，就用Primo Ramdisk就分了8G内存，把临时文件，下载都丢里面。这样用了好多年了。其实SSD ...

其实咱俩一样，我长篇大论的，只是多一些实例，中心思想就是建内存盘，用SETUP.CMD把写盘操作都尽可能的链接到内存盘，

作者: hudaluoshen 时间: 昨天 12:45

D_M_GuYing 发表于 2025-12-8 12:19
我是安装之前就删除了WD，浏览器，N个APPs，就算直接装C盘，那也是安装后，运行一下SETUP.CMD，用过的绿 ...

绿软我都是用Claunch启动，放在C盘以外的盘中，系统再怎么重装都是直接用。
至于需要安装的软件，因为本人是追新，重装后PJ下即可，如office PS CAD CDR，设置几乎都默认。

作者: lhsum 时间: 昨天 12:49
感谢分享，16G的能搞吗

作者: 燕飞龙 时间: 昨天 12:50

感谢分享

作者: lhsum 时间: 昨天 12:51

mwolf 发表于 2025-12-8 10:33
16G内存，虚拟4G，常用绿软及windows写操作都通过powershell同步到R:，关机回写，ps1放入startup快捷方式， ...

这个具体怎么搞？分享下，谢谢

作者: xuxiaojie120 时间: 昨天 13:07
感谢分享！！！

作者: fegr 时间: 昨天 13:16
多谢分享

作者: yy666888 时间: 昨天 13:18
太专业了，感谢分享

作者: wjqok 时间: 昨天 13:20
我搞了个40G的内存盘用，日常都里面搞七搞八，包括虚拟机测试系统，硬盘都设置在内存盘里面

作者: liuyaosheng 时间: 昨天 13:21
谢谢分享

作者: a583091790 时间: 昨天 13:21
年初的64G没下手，然后一月一月的涨到买不起了，太贵了，当时买下就好了捶胸口吐血

作者: ootdyao 时间: 昨天 13:35
感谢分享

作者: D_M_GuYing 时间: 昨天 13:41

hudaluoshen 发表于 2025-12-8 12:45
绿软我都是用Claunch启动，放在C盘以外的盘中，系统再怎么重装都是直接用。
至于需要安装的软件，因为本 ...

把PE安装到ESP下也是一样的，有兴趣，看我的帖子，有PE
http://bbs.wuyou.net/forum.php?m ... p;extra=#pid4685035

作者: D_M_GuYing 时间: 昨天 13:50

a583091790 发表于 2025-12-8 13:21
年初的64G没下手，然后一月一月的涨到买不起了，太贵了，当时买下就好了捶胸口吐血

我是2022年买的三星内存，3200的32G,一个750，两条64G，现在的价，1500元，再过一阵可能一条32都买不下来了

作者: zhang2025 时间: 昨天 13:53
感谢您的分享！赞一个！

作者: hudaluoshen 时间: 昨天 13:58

D_M_GuYing 发表于 2025-12-8 13:41
把PE安装到ESP下也是一样的，有兴趣，看我的帖子，有PE
http://bbs.wuyou.net/forum.php?mod=viewthread ...

PE我只当系统维护工具而已，用的少，就装系统或者禁用WD用用。
平时收集几个常用纯净版PE放Ventoy的ISO分区中，用ventoy启动即可，安装PE有点奢侈了。
况且我是Ventoy+OpenCore集成在一个盘，万能系统安装，格式化是万万不可，重做太废时间。

作者: xianglang 时间: 昨天 14:03
开启 UWF 效果是一样的吧？

作者: zp1688 时间: 昨天 14:03
感谢分享

作者: 709601484 时间: 昨天 14:06
學習一下

作者: 小灰猪 时间: 昨天 14:13
感谢分享

作者: 709601484 时间: 昨天 14:30
感谢分享

作者: wang1126 时间: 昨天 14:42
谢谢楼主分享

作者: 左岸麦田 时间: 昨天 14:43
感谢楼主分享

作者: D_M_GuYing 时间: 昨天 14:50

xianglang 发表于 2025-12-8 14:03
开启 UWF 效果是一样的吧？

UWF 等什么时候要是能自动释放内存就完美了，必竟是微软家自带的

作者: D_M_GuYing 时间: 昨天 14:52

xianglang 发表于 2025-12-8 14:03
开启 UWF 效果是一样的吧？

也就是说，能像Primo Ramdisk那样的，动态内存管理，

作者: it323 时间: 昨天 14:57
感谢分享！

作者: 445112826 时间: 昨天 14:58
技术帖，谢谢分享。

作者: nining376 时间: 昨天 14:59
大差不差，我32G的内存划了10G出来做临时盘，不过我用的是QSoft RAMDisk Enterprise，已经用了十来年也习惯了，我主要是把下载文件放临时盘里，还有把temp也放这里就差不多了

作者: wwwlhp 时间: 昨天 15:05
多谢分享！！！

作者: D_M_GuYing 时间: 昨天 15:13

nining376 发表于 2025-12-8 14:59
大差不差，我32G的内存划了10G出来做临时盘，不过我用的是QSoft RAMDisk Enterprise，已经用了十来年也习惯 ...

慢慢研究着来吧，加了SETUP.CMD，把迅雷，看片，听歌，股票这些有缓存和临时文件夹的，都链到内存盘，尤其是同花顺，

作者: zw18621862 时间: 昨天 15:25
多谢!楼主此帖对我有极大帮助!收藏备用!!!

作者: mwolf 时间: 昨天 15:27

D_M_GuYing 发表于 2025-12-8 10:37
powershell同步到R:？？这一步怎么做到哇

http://bbs.wuyou.net/forum.php?m ... d=448845&extra=

作者: mwolf 时间: 昨天 15:27

lhsum 发表于 2025-12-8 12:51
这个具体怎么搞？分享下，谢谢

http://bbs.wuyou.net/forum.php?m ... d=448845&extra=

作者: ewq11111 时间: 昨天 15:50

谢谢分享

作者: zx2024 时间: 昨天 16:04
看你写了很多，学习了，感觉你缺一个机械硬盘做虚拟内存，我单独划了机械硬盘60G做E盘，虚拟内存，TEMP等都放E盘，我的文档等放D盘，没你弄的这么复杂。

作者: handsome_xiang 时间: 昨天 16:17
感谢分享！

作者: lbw2007 时间: 昨天 16:17
围观一下。我也是64G内存，本打算看看有没有什么帮助，最后只能说：对于能控制住SSD写入、不需要保护硬盘的人来说，你的操作不会延长多少SSD的寿命；对于需要保护SSD的人，即使按照你这样操作了，他也会装一些神奇的软件自己毁掉SSD。内存盘有内存盘的好处，不必纠结SSD。

作者: D_M_GuYing 时间: 昨天 17:02

zx2024 发表于 2025-12-8 16:04
看你写了很多，学习了，感觉你缺一个机械硬盘做虚拟内存，我单独划了机械硬盘60G做E盘，虚拟内存，TEMP等都 ...

64G的内存，无特殊要求，虚拟内存已经是用不到了，可以关闭了。

机械硬盘做虚拟内存，那意义不大呀，要是实在有虚拟内存要求，加个小一些的SSD做都要比机械硬盘要好

作者: 2012fengxi 时间: 昨天 17:17
等我买得起64G再保护sdd硬盘，现在买个20块钱的小容量固态盘承受大量的读写

作者: 易广白 时间: 昨天 17:23
首先感谢分享，确实有很多不错的地方，
仅个人认为过于复杂，可能更适合专业的人，或者爱折腾的人，对于大多普通用户，有64G的内存，只要安装Primo Cache(用内存保护硬盘的缓写工具)，系统盘什么都不用改，只要设个40G大小的容量保护系统盘即可，
它不仅可以保护系统盘，还可以保护其他分区，甚至还可以用于u盘移动系统的改造(较复杂)。
对于下载删除频繁的用户，可以安装Primo Cache，再加上Primo Ramdisk(内存磁盘创建工具)，Primo Cache如上专门保护系统盘，Primo Ramdisk创建内存盘用于存放下载文件，一旦下载完成，便剪切到存储盘存放，可以大幅降低下载过程的硬盘损耗。

作者: D_M_GuYing 时间: 昨天 17:42

易广白发表于 2025-12-8 17:23
首先感谢分享，确实有很多不错的地方，
仅个人认为过于复杂，可能更适合专业的人，或者爱折腾的人，对于大 ...

Primo Cache中，主要是用来改善机械硬盘读写，64内存和SSD用不到的，主要用Primo Cache做系统的零写入，但万一系统意外，比如内存耗尽黑屏，硬件问题蓝屏，程序及问题死机，对你的硬盘和数据是灾难性的，一定要慎用

作者: ynkm169 时间: 昨天 17:49
我也在用Primo Cache保护系统盘，Primo Ramdisk创建内存盘用于系统与浏览器临时文件，存放下载文件。

作者: Paudy 时间: 昨天 17:55
就羡慕64G的内存，现在这内存价格疯了

作者: ge 时间: 昨天 17:58

zlq_hysy 发表于 2025-12-8 12:16
羡慕64G内存。我主用机才12G，副用机最小的2G

2G的怎麼用呢？

作者: womwom 时间: 昨天 18:33
学习学习

作者: zlq_hysy 时间: 昨天 19:06

ge 发表于 2025-12-8 17:58
2G的怎麼用呢？

7x24小时开机，做共享资料主机使用

作者: dreamhouse0130 时间: 昨天 19:14
好，坐等内存条降价

欢迎光临无忧启动论坛 (http://bbs.c3.wuyou.net/)