请教有关autoexec.bat问题

infoprint

我想刻录个自动恢复ghost镜像文件的启动光盘（ghost.exe和镜像文件都在光盘上），
但是在编辑autoexe.bat碰到一个问题：
因为不同电脑的光驱的盘符可能不同，怎么样在autoexe.bat里实现自动执行光盘上的ghost了？
谢谢

cq-bbcyb

抄一段给你参考：
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
cls
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL
copy readme.txt %RAMD%:\ > NUL
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
%CDROM%:
CD\GHOST
Ghost -clone,mode=pload,src=system.gho:1,dst=1:1 -sure -rb

locust1980

我是新手
有同样问题
请问：编辑好上面这个批处理文件后，如何加入启动所必须得文件呢？

Climbing

Config.sys:
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
;devicehigh=ramdrive.sys /E 8192
dos=high,umb
files=30
buffers=20
Autoexec.bat:
set td=Q:\testdrv.bat
>  %td% echo @echo off
>> %td% echo dready %%1
>> %td% echo if errorlevel 1 goto _quit
>> %td% echo set CDOK=%%CDOK%% %%1
>> %td% echo :_quit
:: 调用mscdex为所有光驱分配盘符
LH MSCDEX.EXE /D:mscd001
set CDROM=
findcd /s > nul
:: 调用testdrv.bat检测哪些光驱中有盘并将准备好的光驱保存到cdok变量中
SET CDOK=
for %%I in (%cdrom1% %cdrom2% %cdrom3%) DO call %td% %%I
::检测哪些准备好的光驱中存在需要的GHO文件，并将结果保存到bootcd变量中
set bootcd=
for %%I in (%cdok%) DO if exist %%I\XPSP2\XP-SP2.GHO set BOOTCD=%%I
:: 检测是否存在需要的启动光盘
IF %BOOTCD%*==* goto _nobootcd
set CDROM=%bootcd%
echo bootcd=%bootcd%
goto _findbootcdok
:: 找不到所需启动光盘的错误提示
:_nobootcd
echo.
echo Error: I cannot find your CDROM where we boot from!
echo Please make sure you insert the boot disc in it!
pause
goto _quit
:: 如果存在gho文件，则执行ghost过程并重新启动
:_findbootcdok
%CDROM%\XPSP2\ghost.exe -clone,mode=pload,src=%CDROM%\XPSP2\XP-SP2.gho:1,dst=1:1 -sure -fx
f.com
wboot.com
goto _quit
:: 没有成功建立内存虚拟磁盘的错误提示
:_errramd
echo.
echo Error: I cannot access your RAM Disk at Q:!
echo Check if xmsdsk can create RAM Disk.
pause
goto _quit
:: 退出，清理环境变量
:_quit
for %%I in (cdrom1 cdrom2 cdrom3 cdok) do set %%I=

xiaoyuan0417

[这个贴子最后由xiaoyuan0417在 2005/03/14 11:23am 第 1 次编辑]

对于 DOS “二把刀”的人来说，楼上的贴子实在精彩，掌声鼓励！估计是看到问这个问题的人太多，有点烦了，一古脑说清楚算啦！哈哈哈哈......

infoprint

  Climbing   
你说的不行啊?提示:
echo Error: I cannot find your CDROM where we boot from!
echo Please make sure you insert the boot disc in it!
明明可以进入dos,为什么说还没有启动盘了

弄潮儿-NET

你要把这个改一改:
if exist %%I\XPSP2\XP-SP2.GHO set BOOTCD=%%I
改成你自己的文件名...

pandatown

最简单的办法：
1、网上下载一个findcd.exe文件，用于判断光驱盘符，并自动赋值给变量cdrom，
   即调用findcd命令后，会显示cdrom=你的光盘盘符，后面就可以直接用%cdrom%
   代替你的光盘盘符使用了。
2、找一个98启动镜像（已带用启动光驱支持功能），在镜像中加入findcd.exe文件
3、假设你的ghost.exe和ghost文件*.gho在光盘system目录下，则在autoexec.bat中
   加入以下几行，就可以实现自动恢复ghost镜像
   findcd
   %cdrom%
   cd system
   Ghost -clone,mode=pload,src=*.gho:1,dst=1:1 -sure -rb
  *.gho中的星号代表你的ghost文件名
   

infoprint

下面引用由弄潮儿-NET在 2005/03/15 08:34pm 发表的内容：
你要把这个改一改:
if exist %%I\XPSP2\XP-SP2.GHO set BOOTCD=%%I
改成你自己的文件名...

晕，我当然改了啊。

infoprint

下面引用由pandatown在 2005/03/16 00:45am 发表的内容：
最简单的办法：
1、网上下载一个findcd.exe文件，用于判断光驱盘符，并自动赋值给变量cdrom，
   即调用findcd命令后，会显示cdrom=你的光盘盘符，后面就可以直接用%cdrom%
   代替你的光盘盘符使用了。
...

我试试。。。。