留个纪念：用批获取Microsoft Office的版本号

七仙花

1. @echo off
   
2. 
   
3. echo 获取 Microsoft Office 安装路径
   
4. Setlocal Enabledelayedexpansion
   
5. for /f "delims=\ tokens=5,*" %%a in ('reg query HKLM\SOFTWARE\Microsoft\Office /f "." /k 2^>nul') do (
   
6.     for /f "skip=1 tokens=2,* delims= " %%b in ('reg query HKLM\SOFTWARE\Microsoft\Office\%%~a\Word\InstallRoot /v Path 2^>nul') do (
   
7.         set "WordPath=%%~c"
   
8.     )
   
9. )
   
10. if defined WordPath (set "WordPath=%WordPath:root\Office16=Office16%") else (
    
11. echo 未检测到当前系统安装有 Microsoft Office 软件，请直接关闭或按任意键退出 ......
    
12. pause >nul
    
13. goto :eof
    
14. )
    
15. echo.
    
16. echo Microsoft Office 安装路径是:
    
17. echo %WordPath%
    
18. echo.
    
19. echo 获取 Microsoft Office 文件的版本号
    
20. echo.
    
21. for /f "delims=\ tokens=1-4" %%i in ("%WordPath%") do set "WordPath=%%i\\%%j\\%%k\\%%l\\"
    
22. 
    
23. ::显示misc.exe的版本号
    
24. wmic datafile where Name="%WordPath%misc.exe" get Version
    
25. 
    
26. ::使用wmic获取misc.exe的版本号并赋值给变量
    
27. 
    
28. for /F "skip=1 delims= " %%i in ('wmic datafile where "Name='%WordPath%misc.exe'" get Version') do (
    
29.           set "V=%%i"
    
30.           goto Ver
    
31. )
    
32. :Ver
    
33. echo Microsoft office 的版本号是%V%
    
34. echo.
    
35. pause
    

复制代码

稍做修改，也可以获取其它文件的版本号。

七仙花

奇怪，明明编辑的时候，代码是正确的，但保存后第21行代码少了一个反斜杠“\"，直接复制帖子里的代码，也是少了一个反斜杠。

编辑时是这样的


保存后是这样的


重新编辑，在最后加多一个反斜杠”\"，变成3个反斜杠。


保存后才能显示正确的代码

七仙花

是论坛的问题，还是我的电脑中毒了，明明回复的时候字是正确的，重新编辑就会有几个字变成乱码了，不做改动直接保存，也是显示乱码。

yc2428

谢谢分享

nathan6498

谢谢分享

shidongzhi

感谢分享

nttwqz

七仙花 发表于 2024-2-12 16:28
是论坛的问题，还是我的电脑中毒了，明明回复的时候字是正确的，重新编辑就会有几个字变成乱码了，不做改动 ...

本坛帖子编辑有不少问题，特别是代码编辑。

AcidBurn

谢谢分享

风之暇想

传附件吧

in9

谢谢分享，新年快乐！

chenbingwen

谢谢分享

fjjowhs

感谢分享！

窄口牛

最多能检测到office16，应该重新考虑。

likeyouli

七仙花 发表于 2024-2-12 16:28
是论坛的问题，还是我的电脑中毒了，明明回复的时候字是正确的，重新编辑就会有几个字变成乱码了，不做改动 ...

放心吧， 绝不是你的问题，，我也发现了，http://bbs.wuyou.net/forum.php?m ... p;page=2#pid5129985

ceshi后边少了\

wyjhby

很实用的代码，谢谢分享

窄口牛

dyc086

谢谢分享

guong

感谢分享

iyg429

如何盘点 office是否被激活 ，我遇到了一个这样的问题，一个人买了一个笔记本 试用了几天 ，然后抹除系统 ，看起来和新的一样 请问我如何判断这个笔记本是否被别人激活了？

yanglinman

感谢分享！

htmlc4

窄口牛 发表于 2024-2-13 09:18
最多能检测到office16，应该重新考虑。

严格来说应该是不支持C2R版本，2016版是最后一版有msi版本的office，之后的office，无论是买断制的2019、2021，抑或是订阅制的365，都只有C2R版本

htmlc4

iyg429 发表于 2024-2-13 14:32
如何盘点 office是否被激活 ，我遇到了一个这样的问题，一个人买了一个笔记本 试用了几天 ，然后抹除系统  ...

预装的office激活是绑定到微软账号上的，而不是绑定到主板

htmlc4

这个批处理有严重缺陷，不支持检测C2R版本的office，2016版是最后一版有msi版本的office，之后的office都是C2R版本的

oh312

赞，谢谢分享。

iyg429

htmlc4 发表于 2024-2-14 04:19
预装的office激活是绑定到微软账号上的，而不是绑定到主板

假如说 别人买了我的笔记本 是全新未激活的 别人进到里面用自己的账号绑定office 然后再回复出厂设置 然后告诉我说 笔记本7天无条件退货 我岂不是无法防止？

htmlc4

iyg429 发表于 2024-2-14 15:27
假如说 别人买了我的笔记本 是全新未激活的 别人进到里面用自己的账号绑定office 然后再回复出厂设置 然 ...

一般来说只要联网激活了就不能7天无理由

610644034

@echo off
::CMD窗口字体绿色
title %~n0
color 0a
setlocal EnableDelayedExpansion
set "m_Office版本号="
set "m_Office系统位数="
set "m_Office安装目录="

set "m_Office系统位数=64"
call :扫描注册表一级子目录并回调 "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Office" ":检查激活Office"

set "m_Office系统位数=32"
call :扫描注册表一级子目录并回调 "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Office" ":检查激活Office"
echo.
pause
goto :eof



:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:检查激活Office
set "m_Office版本号="
set "m_Office安装目录="
set "m_ospp文件目录="

call :查询注册表一个数值 "m_Office安装目录" "%~1\Common\InstallRoot" "Path"
if "" EQU "!m_Office安装目录!" call :查询注册表一个数值 "m_Office安装目录" "%~1\Excel\InstallRoot" "Path"
if "" EQU "!m_Office安装目录!" call :查询注册表一个数值 "m_Office安装目录" "%~1\Word\InstallRoot" "Path"
if "" NEQ "!m_Office安装目录!" if exist "!m_Office安装目录!" (
        for %%a in ( "%~1" ) do set "m_Office版本号=%%~na"
        if "\" EQU "!m_Office安装目录:~-1!" set "m_Office安装目录=!m_Office安装目录:~0,-1!"
        set "m_ospp文件目录=!m_Office安装目录!"

        cd /d "!m_Office安装目录!"
        if not exist "!m_Office安装目录!\ospp.vbs" (
                set "m_ospp文件目录="
                cd /d "..\..\Office!m_Office版本号!"
                if exist "ospp.vbs" for /f "delims=*" %%a in ( 'cd' ) do set "m_ospp文件目录=%%a"
        )

        echo.
        echo --------------------------------------------------------
        echo 准备激活:!m_Office系统位数!位 Office 20!m_Office版本号!
        echo 系统位数:!m_Office系统位数!
        echo 安装版本:!m_Office版本号!
        echo 安装路径:!m_Office安装目录!
        echo ospp文件目录:!m_ospp文件目录!

        if not exist "!m_ospp文件目录!\ospp.vbs" (
                echo 无法找到激活文件:ospp.vbs 在目录:!m_ospp文件目录!
                echo 激活失败!
                goto :eof
        )

        if "16" EQU "!m_Office版本号!" (
                call :安装2016证书
                call :安装2019证书
                call :安装2021证书
        )>nul 2>nul
        if "19" EQU "!m_Office版本号!" ( call :安装2019证书 )>nul 2>nul
        if "21" EQU "!m_Office版本号!" ( call :安装2021证书 )>nul 2>nul

        call :设置KMS服务器并激活
)
goto :eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:扫描注册表一级子目录并回调
rem :扫描注册表一级子目录并回调 "in"       "in"
rem :参数列表                   注册表路径 回调标签

( Reg Query "%~1" )>nul 2>nul || (
    goto :eof
)

rem if 0 NEQ %errorlevel% (
rem     goto :eof
rem )

if "" EQU "%~2" for /f "delims=*" %%a in ( 'Reg Query "%~1" ' ) do if "" NEQ "%%a" call :扫描注册表一级子目录并回调_001 "%%a" "%~1"
if "" NEQ "%~2" for /f "delims=*" %%a in ( 'Reg Query "%~1" ' ) do if "" NEQ "%%a" call :扫描注册表一级子目录并回调_002 "%%a" "%~1" "%~2"
goto :eof

:扫描注册表一级子目录并回调_001
echo x%~1 | findstr /i "%~2" >nul 2>nul && echo %~1
goto :eof
:扫描注册表一级子目录并回调_002
echo x%~1 | findstr /i "%~2" >nul 2>nul && call %~3 "%~1"
goto :eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:查询注册表一个数值
rem :查询注册表一个数值 "inout_ptr"       "in"       "in"   
rem :参数列表            输出的数值变量名 注册表路径 [注册表数值名,如果空则查询默认值]

( Reg Query "%~2" )>nul 2>nul || (
    goto :eof
)

if "" NEQ "%~1" set "%~1="
if "" NEQ "%~3" (
    for /f "delims=*" %%a in ( 'Reg Query "%~2" /v "%~3" ' ) do if "" NEQ "%%a" if "" NEQ "%~1" (
        set "查询注册表一个数值_临时变量=%%a"
        set "查询注册表一个数值_临时变量=!查询注册表一个数值_临时变量:    %~3    =!"
        for /f "tokens=1,* delims= " %%b in ( "!查询注册表一个数值_临时变量!" ) do set "查询注册表一个数值_输出数值=%%c"
        set "%~1=!查询注册表一个数值_输出数值!"
    )
    goto :eof
)>nul 2>nul

for /f "delims=*" %%a in ( 'Reg Query "%~2" /ve ' ) do if "" NEQ "%%a" if "" NEQ "%~1" (
        set "查询注册表一个数值_临时变量=%%a"
        set "查询注册表一个数值_临时变量=!查询注册表一个数值_临时变量:    %~3    =!"
        for /f "tokens=1,* delims= " %%b in ( "!查询注册表一个数值_临时变量!" ) do set "查询注册表一个数值_输出数值=%%c"
        set "%~1=!查询注册表一个数值_输出数值!"
)>nul 2>nul
goto :eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

shinykers

谢谢分享~批处理还是很强大的存在啊~

dos时代菜鸟

如果是 64为系统 安装了 32位的office 注册表位置就会不一样了。HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Office 了解下


OFFICE_信息.7z (1.27 KB, 下载次数: 7)

2024-2-15 20:02 上传

点击文件名下载附件
下载积分: 无忧币 -2

享β亻寸木东

能获取品牌机自带office家庭学生版序列号吗？