自娱自乐自用 CMD命令设置或添加PE启动项

享β亻寸木东 · 发表于 5 天前

本帖最后由享β亻寸木东于 2024-11-7 20:08 编辑

@echo off &title _ CMD 设置 PE _
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
PUSHD %~dp0
::获取管理员权限
set mode=2
::改成0 加入启动菜单，每次启动系统时都可以选择
::改成1 一次性启动
::改成2 显示设置页面，两种模式自己选择
if /i "%mode%"=="0" goto:mode0
if /i "%mode%"=="1" goto:mode1
if /i "%mode%"=="2" goto:mode2
echo.&echo mode参数不对，请重新设置。按任意键退出 &pause >nul&exit
:mode0
cls
Call :bcdedit
bcdedit /displayorder %Guid% -addlast >nul 2>&1
::把PE加入启动列表。
bcdedit /timeout 5
::设置等待时间为 5 秒（可更改）
cls &echo.&echo PE启动项添加完成。按任意键退出。&pause >nul&exit
:mode1
cls
Call :bcdedit
bcdedit /bootsequence %Guid% >nul 2>&1
::重启后进入此PE（一次性的）。
cls &echo.&echo 设置完成，按任意键重启，并进入PE。&pause >nul
::删除此行，立即重启进入PE。
shutdown -r -t 0
::立即重启
exit /b
:mode2
ECHO.
ECHO. 按数字 0 把PE加入启动列表
ECHO.
ECHO. 按数字 1 进入一次性PE
ECHO.
ECHO.
choice /C:01 /N /M ">输入你的选择："
if errorlevel 2 goto:mode1
if errorlevel 1 goto:mode0
:bcdedit
cls &echo.&echo 正在处理……
md "C:\PE" >nul 2>&1
::在C盘新建PE文件夹
if not exist boot.sdi (cls &echo.&echo 未找到boot.sdi文件，请把文件和此脚本放一起。按任意键退出。&pause >nul&exit)
xcopy boot.sdi "C:\PE" /Y /Q >nul 2>&1
::复制boot.sdi文件到"C:\PE"文件夹
if not exist boot.wim (cls &echo.&echo 未找到boot.wim镜像，请把镜像和此脚本放一起。按任意键退出。&pause >nul&exit)
xcopy boot.wim "C:\PE" /Y /Q >nul 2>&1
::复制boot.wim镜像到"C:\PE"文件夹（boot.wim自己准备）
bcdedit /set {ramdiskoptions} ramdisksdidevice partition=C: >nul 2>&1
::设置RAM磁盘镜像所在分区为C:盘（可更改）
bcdedit /set {ramdiskoptions} ramdisksdipath \PE\boot.sdi >nul 2>&1
::设置RAM磁盘SDI路径，可以自定义。
for /f "delims={,} tokens=2" %%a in ('bcdedit /create /d "PE" -application osloader') do set Guid={%%a}
::用bdedit创建启动项，导出GUID序列号，赋值给变量Guid
bcdedit /set %Guid% device ramdisk="[C:]\PE\boot.wim,{ramdiskoptions}" >nul 2>&1
::启动设备（可更改）
bcdedit /set %Guid% osdevice ramdisk="[C:]\PE\boot.wim,{ramdiskoptions}" >nul 2>&1
::系统启动设备（设置和启动设备一样就行，可更改）
bcdedit /set %Guid% locale zh-CN >nul 2>&1
::区域设置中国
bcdedit /set %Guid% systemroot \windows >nul 2>&1
::系统根目录
bcdedit /set %Guid% detecthal Yes >nul 2>&1
::检测HAL（硬件抽象层），如Yes（一般用于PE）
bcdedit /set %Guid% winpe Yes >nul 2>&1
::是否windows PE，如Yes（只有是PE时才需要此参数）
exit /b

复制代码

邪恶海盗 · 发表于 5 天前

感觉像是“把PE添加到启动项”？？？

二○二四年十一月七日

享β亻寸木东 · 发表于 5 天前

邪恶海盗发表于 2024-11-7 20:19
感觉像是“把PE添加到启动项”？？？

是滴，是滴，是滴

dna2jm · 发表于 5 天前

努力回贴获积分，争取早日在论坛发布自己DIY的PE，以smine发布的PE为基础，修改增加可以用WIN自带的远程桌面远程PE，PE里面固化一些常用的软件

wn168cn@163.com · 发表于 5 天前

感谢楼主分享

yc2428 · 发表于 5 天前

感谢分享

in9 · 发表于 4 天前

谢谢楼主分享！

zaolaohu · 发表于 4 天前

谢谢分享

wang1126 · 发表于 4 天前

谢谢楼主分享

gsn0421 · 发表于 4 天前

感谢分享！

ttt0001 · 发表于 4 天前

这种小工具好象蛮多的，谢谢楼主分享！

zaolaohu · 发表于 4 天前

谢谢分享

2267981144 · 发表于 4 天前

多谢辛苦提供分享！

孟仁飞 · 发表于 3 天前

学习

cqh · 发表于昨天 18:53

学习

		自动登录	找回密码
密码			注册

[分享] 自娱自乐自用 CMD命令设置或添加PE启动项

评分

点评

点评

评分