如何复制txt内容的指定文件到新目录，并且保存目录结构？

2012zhiwen

有一个txt文件，如下如





如何复制txt内容的指定文件到新目录，并且保存目录结构。
例如：
需要复制“C:\Windows\SysWOW64\crypt32.dll”到“D:\newfolder\Windows\SysWOW64\crypt32.dll”


请问用批处理如何写呢？感谢感谢！！！

遗忘ing

XCOPY是COPY的扩展，可以把指定的目录连文件和目录结构一并拷贝

holley2008

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. 
   
4. :: 设置源目录和目标目录
   
5. set "sourceRoot=C:"
   
6. set "targetRoot=D:\newfolder"
   
7. 
   
8. :: 设置包含文件路径的txt文件
   
9. set "listFile=filelist.txt"
   
10. 
    
11. :: 检查txt文件是否存在
    
12. if not exist "%listFile%" (
    
13.     echo 错误：文件列表 %listFile% 不存在。
    
14.     goto :eof
    
15. )
    
16. 
    
17. :: 读取txt文件并复制文件
    
18. for /f "usebackq delims=" %%a in ("%listFile%") do (
    
19.     set "sourcePath=%%a"
    
20.     set "targetPath=!sourcePath:%sourceRoot%=%targetRoot%!"
    
21.    
    
22.     :: 创建目标目录（如果不存在）
    
23.     if not exist "!targetPath:~0,-1!" mkdir "!targetPath:~0,-1!"
    
24.    
    
25.     :: 复制文件
    
26.     echo 正在复制 "!sourcePath!" 到 "!targetPath!"
    
27.     copy "!sourcePath!" "!targetPath!" /Y
    
28. )
    
29. 
    
30. echo 复制完成。
    
31. 
    
32. endlocal
    

复制代码

2012zhiwen

holley2008 发表于 2024-9-4 11:54

感谢，成功了一半，这个批处理把要复制的文件生成了文件夹，如下图

plutoshen

试试这个，一行命令解决

http://bbs.wuyou.net/forum.php?mod=viewthread&tid=442250

plutoshen

人呢？问题解决没有也不吱一声。

holley2008

2012zhiwen 发表于 2024-9-4 14:31
感谢，成功了一半，这个批处理把要复制的文件生成了文件夹，如下图

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. 
   
4. :: 设置源目录和目标目录
   
5. set "sourceRoot=C:"
   
6. set "targetRoot=D:\newfolder"
   
7. 
   
8. :: 设置包含文件路径的txt文件
   
9. set "listFile=filelist.txt"
   
10. 
    
11. :: 检查txt文件是否存在
    
12. if not exist "%listFile%" (
    
13.     echo 错误：文件列表 %listFile% 不存在。
    
14.     goto :eof
    
15. )
    
16. 
    
17. :: 读取txt文件并复制文件
    
18. for /f "usebackq delims=" %%a in ("%listFile%") do (
    
19.     set "sourcePath=%%a"
    
20.     set "targetPath=!sourcePath:%sourceRoot%=%targetRoot%!"
    
21.    
    
22.     :: 创建目标目录（如果不存在）
    
23.     for %%I in ("!targetPath!") do set "targetDir=%%~dpI"
    
24.     if not exist "!targetDir!" mkdir "!targetDir!"
    
25.    
    
26.     :: 复制文件
    
27.     if exist "!sourcePath!" (
    
28.         echo 正在复制 "!sourcePath!" 到 "!targetPath!"
    
29.         copy "!sourcePath!" "!targetPath!" /Y
    
30.     ) else (
    
31.         echo 警告：源文件 "!sourcePath!" 不存在。
    
32.     )
    
33. )
    
34. 
    
35. echo 复制完成。
    
36. 
    
37. endlocal
    

复制代码

szwp

可以先去cmd里练习，先进入目标文件夹
for /f %f in (l.txt) do md %~pf&copy %f %~pf

2012zhiwen

plutoshen 发表于 2024-9-5 08:35
人呢？问题解决没有也不吱一声。

谢谢，我去工地搬砖了。我先看看三楼的用法，你这个还没试，一步一步来。

2012zhiwen

holley2008 发表于 2024-9-5 09:04

谢谢，现在还在工地，晚上试下。

plutoshen

2012zhiwen 发表于 2024-9-5 11:15
谢谢，我去工地搬砖了。我先看看三楼的用法，你这个还没试，一步一步来。

哪个简单直观，你自己看看，没必要舍近求远。

ppll2030

把要复制的名单命名为1.txt
把代码保存为bat文件，跟1.txt放一块，运行即可。

1. @echo off
   
2. set "dest=D:\newfolder"
   
3. for /f "delims=" %%i in (1.txt) do (xcopy "%%i" "%dest%%%~pi")
   
4. echo 文件复制完成。
   
5. pause
   

复制代码

2012zhiwen

szwp 发表于 2024-9-5 09:47
可以先去cmd里练习，先进入目标文件夹
for /f %f in (l.txt) do md %~pf&copy %f %~pf

感谢提供帮助，

2012zhiwen

ppll2030 发表于 2024-9-5 14:23
把要复制的名单命名为1.txt
把代码保存为bat文件，跟1.txt放一块，运行即可。

谢谢，今晚回去试下。

szwp

2012zhiwen 发表于 2024-9-5 15:17
感谢提供帮助，

%~pf前要加路径可以是.

2012zhiwen

holley2008 发表于 2024-9-5 09:04

测试可以。谢谢。

2012zhiwen

ppll2030 发表于 2024-9-5 14:23
把要复制的名单命名为1.txt
把代码保存为bat文件，跟1.txt放一块，运行即可。

测试可以。谢谢

旭东

学习了

xmzhqw

论坛中找到的，我一直在用，还不错。把txt名称更名为RNDIS.txt，然后拖到下面批处理文件（设为：copyfiles.bat）上即可。

@echo off
pushd %~dp0
if not exist RNDIS mkdir RNDIS
(
    for /f "delims=" %%a in (RNDIS.txt) do (
        if exist "%%~fa\" (
            xcopy "%%~fa\*.*" "RNDIS%%~pnxa" /s /y
        ) else (
            xcopy "%%~fa" "RNDIS%%~pa" /s /y
        )
    )
)>RNDIS.log
pause

cqh

学习