新人求助 menu。txt

xingwuzhe

问下这个菜单 怎么解释  最重要是的 想让这个菜单直接进入PE  不用自己点回车

#!ipxe
  #set menu-timeout 8000
   set menu-default win8pe
   set xieyi:string http
   isset ${ip} || dhcp
  #isset ${next-server} || set next-server 192.168.3.3
:start

  menu iPXE Boot Menu --${ip}
  item --gap --             --------------------------------- PE --------------------------------
  
  item win8pe               Boot Win8 PE (wimboot)
  item win81pe              Boot Win8.1 RamOS (wimboot)
   
  item --gap --             -------------------------------- TOOL --------------------------------
  item maxdos               Maxdos Tool
  item menu-disk            DiskTool....
  item menu-other           OtherTool...
  item --gap --             ---------------------------- Advanced options -----------------------

  item --key c config       Configure settings                                   -- c
  item shell                Drop to iPXE shell
  item reboot               Reboot computer
  item --key x exit         Exit iPXE and continue BIOS boot                     -- x
  choose --timeout ${menu-timeout} --default ${menu-default} selected
  goto ${selected}

:shell
  echo Type 'exit' to get the back to the menu
  shell
  goto start

:reboot
  reboot

:exit
  exit

:config
  config
  goto start

:pxelinux
  chain ${xieyi}://${next-server}/pxelinux.0 || goto retry
  
:grub4dos
  chain ${xieyi}://${next-server}/grldr.0 || goto retry

:memtest
  chain ${xieyi}://${next-server}/BOOT/memtest.bin || goto retry
  goto start

:maxdos
  initrd ${xieyi}://${next-server}/BOOT/dostools/max9.3.ima
  chain ${xieyi}://${next-server}/memdisk || goto retry

:menu-disk
menu                    Disk Tool
item diskgen            DiskGen4.5
item mhdd               MHDD

item --key 0x08 back Back to top menu...
choose  selected && goto ${selected} || goto start

:diskgen
  initrd ${xieyi}://${next-server}/boot/DOSTOOLS/DGDOS.IMG
  chain ${xieyi}://${next-server}/memdisk || goto retry

:mhdd
  initrd ${xieyi}://${next-server}/boot/DOSTOOLS/MHDD.ISO
  chain ${xieyi}://${next-server}/memdisk iso raw || goto retry

:menu-other
menu
item memtest         memtest86+
item test    ${xieyi} ----  select change
item --key 0x08 back Back to top menu...
choose  selected && goto ${selected} || goto start

:test
   iseq ${xieyi} ftp && set xieyi http && goto menu-other ||
   iseq ${xieyi} http && set xieyi ftp && goto menu-other ||

:TangoPE
  initrd ${xieyi}://${next-server}/ISO/TangoPE_NET.ISO || goto retry
  chain ${xieyi}://${next-server}/memdisk iso raw

:win8pe
  kernel ${xieyi}://${next-server}/wimboot/wimboot || goto retry
  initrd ${xieyi}://${next-server}/wimboot/bootmgr.exe       bootmgr.exe  || goto retry
  initrd ${xieyi}://${next-server}/wimboot/bcd       BCD  || goto retry
  initrd ${xieyi}://${next-server}/wimboot/boot.sdi   boot.sdi  || goto retry
  initrd ${xieyi}://${next-server}/wimboot/BOOT.WIM   BOOT.WIM  || goto retry
  boot || goto retry
  goto start

:win81pe
  kernel ${xieyi}://${next-server}/wimboot/wimboot || goto retry
  initrd ${xieyi}://${next-server}/wimboot/bootmgr.exe       bootmgr.exe  || goto retry
  initrd ${xieyi}://${next-server}/wimboot/bcd       BCD  || goto retry
  initrd ${xieyi}://${next-server}/wimboot/boot.sdi   boot.sdi  || goto retry
  initrd ${xieyi}://${next-server}/wimboot/DYY8.WIM   BOOT.WIM  || goto retry
  boot || goto retry
  goto start

:retry
  imgfree
  prompt Error! press any key to back menu
  goto start

jjbad

set menu-timeout 8000 删除就好

xingwuzhe

jjbad 发表于 2019-3-14 15:17
set menu-timeout 8000 删除就好

不行啊 还是一直停留在 菜单选择界面

江南一根葱

第二行去掉#号吧

xingwuzhe

嗯嗯 弄好了  但是不是直接进入 是1秒以后  set menu-timeout 1000

邪恶海盗

xingwuzhe 发表于 2019-3-14 18:18
嗯嗯 弄好了  但是不是直接进入 是1秒以后  set menu-timeout 1000

建议搞个倒计时的好一些,否则菜单没存在的意义了

xingwuzhe

邪恶海盗 发表于 2019-3-14 19:46
建议搞个倒计时的好一些,否则菜单没存在的意义了

好的谢谢