无忧启动论坛

标题: 有懂批处理的大佬吗，有个脚本需要键盘输入Y能帮我改下吗 [打印本页]
作者: 黑色de郁金香    时间: 2020-2-12 12:16
标题: 有懂批处理的大佬吗，有个脚本需要键盘输入Y能帮我改下吗
我找到一个卸载onedrive的批处理，里面需要输入以下Y进行确认，我想把这个弄成启动之后就自动执行的，有大佬懂批处理语言吗?
UninstallOneDrive.zip (1.93 KB, 下载次数: 15)
作者: chishingchan    时间: 2020-2-12 12:32
（免下载！）附件的源码：
  1. @rem OneDrive Complete uninstaller batch process for Windows 10.
  2. @rem Run as administrator to completely delete all OneDrive components and files.
  3. @rem Written by TERRA Operative - 2016/08/31. V1.2
  4. @rem Feel free to distribute freely as long as you leave this entire file unchanged and intact,
  5. @rem and if you do make changes and adaptions, don't be a dick about attributing where due.
  6. @rem And most importantly, peace out and keep it real.

  8. @echo OFF

  10. @REM Set variables for coloured text
  11. SETLOCAL EnableDelayedExpansion
  12. for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do     rem"') do (
  13.   set "DEL=%%a"
  14. )

  16.    echo ------Windows 10 OneDrive Uninstaller V1.2------
  17.    echo.
  18.    
  19. @rem This code block detects if the script is being running with admin privileges. If it isn't it pauses and then quits.
  20. NET SESSION >nul 2>&1
  21. IF %ERRORLEVEL% EQU 0 (


  24.    echo        Administrator Privileges Detected!
  25.    echo.
  26. ) ELSE (

  28.    echo.
  29.    call :colorEcho 0C "########### ERROR - ADMINISTRATOR PRIVILEGES REQUIRED #############"
  30.    echo.
  31.    call :colorEcho 0C "#                                                                 #"
  32.    echo.
  33.    call :colorEcho 0C "#"
  34.    call :colorEcho 07 "    This script must be run as administrator to work properly."
  35.    call :colorEcho 0C "    #"
  36.    echo.
  37.    call :colorEcho 0C "#"
  38.    call :colorEcho 07 "    If you're seeing this after clicking on a start menu icon,"
  39.    call :colorEcho 0C "   #"
  40.    echo.
  41.    call :colorEcho 0C "#"
  42.    call :colorEcho 07 "  then right click on the file and select 'Run As Administrator'"
  43.    call :colorEcho 0C " #"
  44.    echo.
  45.    call :colorEcho 0C "#                                                                 #"
  46.    echo.
  47.    call :colorEcho 0C "###################################################################"
  48.    echo.
  49.    echo.

  51.    PAUSE
  52.    EXIT /B 1
  53. )

  55.    echo -----------------------------------------------
  56.    call :colorEcho 0C "                    WARNING"
  57.    echo.
  58.    call :colorEcho 0C "  This script will completely and permanently"
  59.    echo.
  60.    call :colorEcho 0C "      remove OneDrive from your computer."
  61.    echo.
  62.    call :colorEcho 0C "        Make sure all OneDrive documents"   
  63.    echo.
  64.    call :colorEcho 0C "       that are stored locally are fully"
  65.    echo.
  66.    call :colorEcho 0C "          backed up before proceeding."   
  67.    echo.
  68.    echo -----------------------------------------------
  69.    echo.

  71.    SET /P M=  Press 'Y' to continue or any other key to exit.
  72.         if %M% ==Y goto PROCESSKILL
  73.         if %M% ==y goto PROCESSKILL

  75.    EXIT /B 1


  78. @rem The following is based on info from here written by 'LK':
  79. @rem https://techjourney.net/disable-or-uninstall-onedrive-completely-in-windows-10/


  82. @rem Terminate any OneDrive process
  83. :PROCESSKILL
  84.    echo.
  85.    echo Terminating OneDrive process.
  86.    
  87. taskkill /f /im OneDrive.exe


  90. @rem Detect if OS is 32 or 64 bit
  91. reg Query "HKLM\Hardware\Description\System\CentralProcessor\0" | find /i "x86" > NUL && set OS=32BIT || set OS=64BIT

  93. if %OS%==32BIT GOTO 32BIT
  94. if %OS%==64BIT GOTO 64BIT


  97. @rem Uninstall OneDrive app
  98. :32BIT
  99.    echo.
  100.    echo This is a 32-bit operating system.
  101.    echo Removing OneDrive setup files.
  102.    
  103. %SystemRoot%\System32\OneDriveSetup.exe /uninstall
  104. GOTO CLEAN

  106. :64BIT
  107.    echo.
  108.    echo This is a 64-bit operating system.
  109.    echo Removing OneDrive setup files.
  110.    
  111. %SystemRoot%\SysWOW64\OneDriveSetup.exe /uninstall
  112. GOTO CLEAN


  115. @rem Clean and remove OneDrive remnants
  116. :CLEAN
  117.    echo.
  118.    echo Removing remaining OneDrive folders.
  119.    
  120.    rd "%UserProfile%\OneDrive" /Q /S
  121.    rd "%LocalAppData%\Microsoft\OneDrive" /Q /S
  122.    rd "%ProgramData%\Microsoft OneDrive" /Q /S
  123.    rd "C:\OneDriveTemp" /Q /S
  124.    
  125.    echo.
  126.    call :colorEcho 0C "If you see 'access denied' errors here, reboot and run this batch file again."
  127.    echo.



  131. @rem Delete and remove OneDrive in file explorer folder tree registry key
  132.    echo.
  133.    echo Removing OneDrive registry keys.
  134.    
  135.    IF EXIST "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" REG Delete "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f
  136.    IF EXIST "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" REG Delete "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f
  137.    REG ADD "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /v System.IsPinnedToNameSpaceTree /d "0" /t REG_DWORD /f
  138.    
  139.    echo.
  140.    echo OneDrive Uninstall and cleaning completed.
  141.    echo.

  143.    PAUSE
  144.    echo So long and thanks for all the fish...
  145.    PING -n 2 127.0.0.1>nul
  146.    EXIT /B 1

  148.    
  149. @rem Settings for text colour

  151. :colorEcho
  152. echo off
  153. <nul set /p ".=%DEL%" > "%~2"
  154. findstr /v /a:%1 /R "^$" "%~2" nul
  155. del "%~2" > nul 2>&1i
复制代码
作者: chishingchan    时间: 2020-2-12 12:34
不用思考的将 71行改为：
SET M=Y
作者: hilsonma    时间: 2020-2-12 12:44
也可以把71-75行注释掉(每行前头加上::或rem)如：
::   SET /P M=  Press 'Y' to continue or any other key to exit.
::        if %M% ==Y goto PROCESSKILL
::        if %M% ==y goto PROCESSKILL
::
::   EXIT /B 1
作者: 黑色de郁金香    时间: 2020-2-12 13:46
chishingchan 发表于 2020-2-12 12:34
不用思考的将 71行改为：
SET M=Y

谢谢大神！确实管用！
作者: 黑色de郁金香    时间: 2020-2-12 13:47
hilsonma 发表于 2020-2-12 12:44
也可以把71-75行注释掉(每行前头加上::或rem)如：
::   SET /P M=  Press 'Y' to continue or any other k ...

谢谢大神！刚恢复了一遍系统试了下，这个方法也管用！
作者: ximenzi7    时间: 2020-2-23 00:54
老外的这个没有获取管理权限的代码，差评！
@echo OFF

REM 先判断管理员权限，无则获取

if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0
bcdedit >nul
if '%errorlevel%' NEQ '0' (goto UACPrompt) else (goto UACAdmin)
:UACPrompt
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
exit /B
:UACAdmin

@REM 设置彩色文本的变量
SETLOCAL EnableDelayedExpansion
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do     rem"') do (
  set "DEL=%%a"
)
   echo ------Windows 10 OneDrive 卸载工具 V1.2------
   echo.
   echo -----------------------------------------------
   call :colorEcho 0C "               警告！          "
   echo.
   call :colorEcho 0C "      这个脚本将完全和永久     "
   echo.
   call :colorEcho 0C "   从你的计算机中删除OneDrive。"
   echo.
   call :colorEcho 0C "  请确认您所有的OneDrive文件   "   
   echo.
   call :colorEcho 0C "        已经全部保存在本地     "
   echo.
   call :colorEcho 0C "  请确保在操作之前已经作好备份."   
   echo.
   echo -----------------------------------------------
   echo.


echo; "取消请在3秒内按c"
CHOICE /t 3 /C YC /D Y >nul 2>nul
if %errorlevel% equ 1 goto PROCESSKILL
if %errorlevel% equ 2 exit /b 1

@rem 以下是根据来自这里的信息写的 by:'LK'
@rem https://techjourney.net/disable-or-uninstall-onedrive-completely-in-windows-10/


@rem 终止OneDrive的所有进程
:PROCESSKILL
   echo.
   echo Terminating OneDrive process.
   
taskkill /f /im OneDrive.exe


@rem 检测操作系统是32位还是64位
reg Query "HKLM\Hardware\Description\System\CentralProcessor\0" | find /i "x86" > NUL && set OS=32BIT || set OS=64BIT

if %OS%==32BIT GOTO 32BIT
if %OS%==64BIT GOTO 64BIT


@rem 卸载OneDrive应用程序
:32BIT
   echo.
   echo 这是32位的操作系统
   echo 删除OneDrive安装文件。
   
%SystemRoot%\System32\OneDriveSetup.exe /uninstall
GOTO CLEAN

:64BIT
   echo.
   echo 这是64位的操作系统
   echo 删除OneDrive安装文件。
   
%SystemRoot%\SysWOW64\OneDriveSetup.exe /uninstall
GOTO CLEAN


@rem 清理删OneDrive的残留文件
:CLEAN
   echo.
   echo 正在处理残留的OneDrive文件夹。
   
   rd "%UserProfile%\OneDrive" /Q /S
   rd "%LocalAppData%\Microsoft\OneDrive" /Q /S
   rd "%ProgramData%\Microsoft OneDrive" /Q /S
   rd "C:\OneDriveTemp" /Q /S
   
   echo.
   call :colorEcho 0C "如果你看到"拒绝访问"错误,重启计算机并再次运行该批处理文件。"
   echo.



@rem 删除资源管理器中的OneDrive文件夹和注册表键值
   echo.
   echo 删除OneDrive注册表项。
   
   IF EXIST "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" REG Delete "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f
   IF EXIST "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" REG Delete "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f
   REG ADD "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /v System.IsPinnedToNameSpaceTree /d "0" /t REG_DWORD /f
   
   echo.
   echo OneDrive卸载清理完成
   echo.

   PAUSE
   echo 再见,感谢您的使用！
   timeout /3 >nul
   EXIT /B 1

   
@rem 设置文本颜色

:colorEcho
echo off
<nul set /p ".=%DEL%" > "%~2"
findstr /v /a:%1 /R "^$" "%~2" nul
del "%~2" > nul 2>&1i
作者: 黑色de郁金香    时间: 2020-2-23 02:36
ximenzi7 发表于 2020-2-23 00:54
老外的这个没有获取管理权限的代码，差评！
@echo OFF

无忧真是卧虎藏龙！这个功能太方便了，连右键以管理员身份这一步都省了！谢谢大神！



欢迎光临 无忧启动论坛 (http://bbs.c3.wuyou.net/) Powered by Discuz! X3.3