无忧启动论坛

标题: 怎么获得 磁盘 和 卷 的对应关系 [打印本页]
作者: newswan    时间: 2018-5-25 17:35
标题: 怎么获得 磁盘 和 卷 的对应关系
本帖最后由 newswan 于 2018-6-2 12:13 编辑

wmic DISKDRIVE

Name=\\.\PHYSICALDRIVE1
Partitions=3

wmic LOGICALDISK

Name=M:
VolumeName=U3

那么，怎么得到 磁盘 和 卷 的对应关系，wmic 可以吗？

使用 diskpart 的批处理，最后结果。 diskpartvol.rar (1.64 KB, 下载次数: 4)
作者: plusv    时间: 2018-5-27 05:58
本帖最后由 plusv 于 2018-5-27 06:01 编辑

获得 磁盘 和 卷 的对应关系

http://bbs.c3.wuyou.net/forum.php?mod=attachment&aid=MzcxNzgyfDkxY2M0MDgxMzg3OWI5NzM0N2YyOGQ2MTI3YWUxOWRkfDE3MzMxNzgxMjQ%3D&request=yes&_f=.zip



作者: newswan    时间: 2018-5-29 04:51
本帖最后由 newswan 于 2018-5-29 04:59 编辑

ok，谢谢
但是在我这里报错，win10
用 diskpart 太麻烦了
另外，没有盘符的分区，能显示么？例如 efi msr 或 其他隐藏的分区。

.\Test.ps1 : File C:\Users\admin\Desktop\Test.ps1 cannot be loaded because running scripts is disabled on this system.
For more information, see about_Execution_Policies at http://go.microsoft.com/fwlink/?LinkID=135170.
At line:1 char:1
+ .\Test.ps1
+ ~~~~~~~~~~
    + CategoryInfo          : SecurityError: (:) [], PSSecurityException
    + FullyQualifiedErrorId : UnauthorizedAccess

PS C:\windows\system32> $PSVersionTable

Name                           Value
----                           -----
PSVersion                      5.1.14393.2273
PSEdition                      Desktop
PSCompatibleVersions           {1.0, 2.0, 3.0, 4.0...}
BuildVersion                   10.0.14393.2273
CLRVersion                     4.0.30319.42000
WSManStackVersion              3.0
PSRemotingProtocolVersion      2.3
SerializationVersion           1.1.0.1

作者: nttwqz    时间: 2018-5-29 09:17
wmic volume get caption,deviceid

或者

mountvol
作者: dos时代菜鸟    时间: 2018-5-29 10:17
vbs调用 wimc
作者: dos时代菜鸟    时间: 2018-5-29 13:13
本帖最后由 dos时代菜鸟 于 2018-5-29 14:22 编辑

HD3.1.VBS.7z (855 Bytes, 下载次数: 10)

如果用  select 可能更简便一些，另外 cmd 下也应该可以实现。


vbs


  2. '获取 磁盘以及其分区列表,包括接口信息。
  3. '通过 DiskDrive 获取硬盘 index
  4. '通过 win32_LogicalDiskToPartition 获取分区盘符(C: D: E:...) 和分区位置(disk n#,partition m#)
  5. '通过 win32_LogicalDisk 获取分区盘符 和 分区大小，卷标，格式等
  6. '通过 Diskpartition 做中间索引，可获取 分区所在硬盘的 index 以及分区位置
  7.    
  8. Set wmi=GetObject("winmgmts:\\.\root\cimv2")
  9. Set d_s=wmi.instancesof("win32_diskdrive")
  10. Set p_s1=wmi.instancesof("win32_LogicalDiskToPartition")
  11. Set p_s2=wmi.instancesof("win32_LogicalDisk")
  12. Set p_s3=wmi.instancesof("Win32_DiskPartition")

  14. l="----------------------------------------------------------------------------------"
  15. snx=l
  16. For Each d In d_s
  17.         snx=snx & Chr(10)&  d.deviceId &"  "& d.interfacetype &Right("    "&Int(d.size/1073741824),6) &" Gb" _
  18.                                  & "   "&d.Model
  19.         For Each p3 In p_s3
  20.                 If d.index=p3.diskindex Then
  21.                         For Each p1 In p_s1
  22.                                 p1_1=replace(Split(p1.Antecedent,"=",-1,1)(1),chr(34),"") '获取分区位置,Disk_n#Partition_m#
  23.                                 p1_2=replace(Split(p1.dependent,"=",-1,1)(1),chr(34),"")  '获取盘符
  24.                                 If p1_1=p3.deviceid Then
  25.                                         sn=""
  26.                                         For Each p2 In p_s2
  27.                                                 If p2.deviceid=p1_2 Then
  28.                                                         sn="   "& p2.deviceid & " " _
  29.                                                         & Left(p2.volumename&"         ",11) _
  30.                                                         & Left(p2.filesystem&"   ",6) _
  31.                                                         & Right("    "&Int(p2.size/1073741824),6) &" Gb" _
  32.                                                         & "    ("& d.deviceId&","&p3.index &")"
  33.                                                 End If
  34.                                         Next
  35.                                         snx=snx &Chr(10) & sn
  36.                                 End If
  37.                         Next               
  38.                 End if
  39.         Next
  40. snx=snx&chr(10)&l
  41. Next
  42. WScript.Echo snx
复制代码




作者: dos时代菜鸟    时间: 2018-5-29 15:36
dos时代菜鸟 发表于 2018-5-29 13:13
如果用  select 可能更简便一些，另外 cmd 下也应该可以实现。

wimc 中 没有 Win32_DiskPartition 的别名定义，不知道怎么创建。
作者: plusv    时间: 2018-5-29 18:21
To:newswan

Q:>但是在我这里报错，win10
A:PowerShell Set-ExecutionPolicy UnRestricted

>用 diskpart 太麻烦了
A:这不是 DiskPart

>另外，没有盘符的分区，能显示么？例如 efi msr 或 其他隐藏的分区。
A:如附图,改一列.


作者: newswan    时间: 2018-5-30 11:10
本帖最后由 newswan 于 2018-5-30 11:24 编辑

用了一个vhd磁盘测试，
分区是这样的：


Test.ps1


HD3.1.VBS


都没有显示出没有盘符的卷
作者: dos时代菜鸟    时间: 2018-5-30 18:41
本帖最后由 dos时代菜鸟 于 2018-5-30 20:56 编辑

看脚本内容就知道了，我那个本来就是只显示分配盘符的分区。

稍微修改 是可以显示 没有盘符的 分区的，但是也 仅仅能够知道 该分区 所在的硬盘 位置，其他的什么大小，卷标，格式类型也都 无法获取。


用 diskpart 也不麻烦 可以看 http://wuyou.net/forum.php?mod=v ... 93&fromuid=1198
作者: plusv    时间: 2018-5-30 21:03
我也觉的用 DiskPart 才是好方法.
作者: newswan    时间: 2018-5-30 22:52
dos时代菜鸟 发表于 2018-5-30 18:41
看脚本内容就知道了，我那个本来就是只显示分配盘符的分区。

稍微修改 是可以显示 没有盘符的 分区的， ...

谢谢
作者: dos时代菜鸟    时间: 2018-5-30 23:15
本帖最后由 dos时代菜鸟 于 2018-5-30 23:47 编辑

唉，记得以前弄过 类似的脚本 ，再 弄一次吧。
利用 diskpart 实现的。
英文diskpart 也应该适用。因为 没有 用到 中文关键字作为 文本流 参照标记。否则 脚本 编辑会更 简洁。

hd3.2.cmd.7z (780 Bytes, 下载次数: 4)



  1. @echo off
  2. setlocal ENABLEDELAYEDEXPANSION
  3. color 1f
  4. mode con:  cols=130 LINES=20
  5. title 获取硬盘分区序列.....

  7.   CLS
  8.   echo ....正在生成硬盘和各卷信息列表.....
  9.   set l0=
  10.   >%temp%\part_0.txt echo.
  11.   >%temp%\temp.txt echo list disk
  12. for /f "tokens=1,2,3" %%c in ('diskpart /s %temp%\temp.txt') do (
  13.         set disk=%%d
  14.         if "%%c"=="*" set disk=%%e
  15.         if "!disk:~0,1!"=="-" set l0=ok
  16.         if not "!disk:~0,1!"=="-" (if /i "!l0!"=="ok" (
  17.                 echo 正在分析 HD #!disk!
  18.           (echo select disk !disk!  
  19.                  echo detail disk)>%temp%\temp.txt
  20.                 set l1=
  21.                 for /f "tokens=2,*"  %%f in ('diskpart /s %temp%\temp.txt') do (
  22.                         set part=%%g
  23.                         if "!part:~0,1!"=="-" set l1=ok
  24.                         if not "!part:~0,1!"=="-" (if /i "!l1!"=="ok" (
  25.         if not "!part:~1,1!"==" " set "part=*                       !part!"
  26.         echo .找到 Vol#%%f
  27.         (echo select disk !disk!  
  28.                      echo select vol %%f
  29.                      echo list part)>%temp%\temp.txt
  30.                     set "sp=*"
  31.                     for /f "tokens=1,3" %%i in ('diskpart /s %temp%\temp.txt') do (if "%%i"=="*" set sp=%%j)
  32.         echo %%f    !disk!:!sp!   !part! >>%temp%\part_0.txt
  33.                         ))
  34.                 )
  35.         ))
  36. )

  38.   cls
  39.   echo --------------------------------------------
  40.   echo  VOL  HD:P  LTR  格式  大小      标签
  41.   echo ----- ----- ---  ----- --------  -----------
  42.   for /f "tokens=1,2,*" %%o in (%temp%\part_0.txt) do (
  43.     set vol=%%o
  44.     set hdp=%%p
  45.     set l2=%%q
  46.     set ltr=!l2:~0,1!
  47.     set fmt=!l2:~17,5!
  48.     set size=!l2:~36,8!
  49.     set lable=!l2:~4,12!
  50.     echo   !vol!    !hdp!   !ltr!   !fmt!  !size! !lable!
  51.   )
  52.   echo -----------------------------------------------------
  53. pause
复制代码


作者: newswan    时间: 2018-5-31 11:47
本帖最后由 newswan 于 2018-5-31 11:50 编辑

搞了几天，我想要的这样的，bat 弄起来太累了，语法不熟，又不好调试。。。。


  2. @echo off
  3. setlocal EnableDelayedExpansion

  5. :C_listDiskVolume

  7. echo,
  8. (set diskID=)
  9. (set cmdline=cmd /c "(set <nul /p=list disk)")
  10. for /f "usebackq skip=7 tokens=*" %%i in (`%cmdline% ^| diskpart`) do (echo %%i)
  11. echo,
  12. for /f "usebackq skip=9 tokens=2" %%i in (`%cmdline% ^| diskpart`) do (
  13.     (set diskID=%%i)
  14.     if "!diskID!" NEQ "" (
  15.         (set begin2=)
  16.         (set cmdline=cmd /c "echo sel disk !diskID! & (set <nul /p=detail disk)")
  17.         (set /a count1=0)
  18.         for /f "usebackq tokens=* skip=10 delims=" %%i in (`!cmdline! ^| diskpart`) do (
  19.             (set /a count1+=1)
  20.             if "!count1!"=="1" echo %%i
  21.         )
  22.         (set count1=)
  23.         (set cmdline=cmd /c "echo sel disk !diskID! & (set <nul /p=list part)")
  24.         for /f "usebackq tokens=* delims=" %%i in (`!cmdline! ^| diskpart`) do (
  25.             (echo "%%i" | find /i "###" >nul) && (set begin2=T) && (set /a count2=0)
  26.             if defined begin2 (
  27.                 (set /a count2+=1)
  28.                 if !count2!==1 (set line2=.%%i ) else (set line2=.%%i)
  29.                 if !count2! LEQ 3 (
  30.                     (set cmdline=cmd /c "echo sel disk 0 & echo sel part 1 & (set <nul /p=detail part)")
  31.                     for /f "usebackq tokens=* delims=" %%i in (`!cmdline! ^| diskpart`) do (
  32.                         (echo "%%i" | find /i "###" >nul) && (set begin3=T) && (set /a count3=0)
  33.                         if defined begin3 (
  34.                             (set /a count3+=1)
  35.                             if !count2!==!count3! (set line3=%%i)
  36.                         )
  37.                     )
  38.                 )
  39.                 (set begin3=)
  40.                 (set count3=)
  41.                 if !count2! GTR 2 (
  42.                     for /f "tokens=3" %%i in ("!line2!") do set partID=%%i
  43.                     (set cmdline=cmd /c "echo sel disk !diskID! & echo sel part !partID! & (set <nul /p=detail part)")
  44.                     for /f "usebackq tokens=* delims=" %%i in (`!cmdline! ^| diskpart`) do (
  45.                         (echo "%%i" | find /i "###" >nul) && (set begin3=T) && (set /a count3=0)
  46.                         if defined begin3 (
  47.                             (set /a count3+=1)
  48.                             if !count3!==3 (set line3=%%i)
  49.                         )
  50.                     )
  51.                 )
  52.                 set <nul /p=!line2! & if defined line3 (echo !line3:~,38!!line3:~50!) else (echo,)
  53.                 (set begin3=)
  54.                 (set count3=)
  55.                 (set line3=)
  56.             )
  57.             (set line2=)
  58.         )
  59.         (set begin2=)
  60.         (set count2=)
  61.         echo,
  62.     )
  63. )
  64. (set diskID=)
  65. (set cmdline=)
  66. (set rowcount=)
  67. goto :eof
复制代码

t3.rar (1.46 KB, 下载次数: 7)
作者: dos时代菜鸟    时间: 2018-5-31 21:59
本帖最后由 dos时代菜鸟 于 2018-5-31 22:28 编辑
newswan 发表于 2018-5-31 11:47
搞了几天，我想要的这样的，bat 弄起来太累了，语法不熟，又不好调试。。。。

我基本上明白你的意思了

看这个吧 hd3y2.zip (960 Bytes, 下载次数: 2) ,运行效率 有点儿低，因为要频繁调用 diskpart 对每一个分区进行 探测。

hd3y2.cmd
  1. @echo off
  2. setlocal ENABLEDELAYEDEXPANSION
  3. color 1f
  4. mode con:  cols=150 LINES=30
  5. title 获取硬盘分区序列.....

  7. set "s1=磁盘"
  8. set "s2=分区"
  9. set "s3=卷"

  11.   CLS
  12.   echo.

  14. >%temp%\part_0.txt echo.
  15. >%temp%\diskpart.s echo list disk
  16. set /a No=0
  17. echo                           硬盘分区序列
  18. echo --------------------------------------------------------------------------------------------------
  19. echo  No.  Vol  HD:P   LTR  格式   大小      标签          类型_状态_信息_偏移

  21. for /f "tokens=1,2,3,4,5" %%a in ('diskpart /s %temp%\diskpart.s') do (
  22.   if "%%a"=="!s1!" (if not "%%b"=="###" (
  23.     set "disk=%%b"
  24.     (
  25.       echo select disk !disk!
  26.       echo detail disk
  27.       echo list part
  28.     )>%temp%\diskpart.s
  29.     set /a Nod=0
  30.     for /f "delims=" %%u in ('diskpart /s %temp%\diskpart.s') do (
  31.       set /a Nod+=1
  32.       if !Nod! equ 5  (
  33.         echo  ---  ---  -----  ---  -----  --------  ------------  ------------------------ Disk#%%b %%d%%e %%c（%%~u）
  34.       )
  35.       for /f "tokens=1,2,3,4,5,6,7" %%e in ("%%~u") do (
  36.         set "size=      %%h %%i"
  37.         if "%%e"=="!s2!" (if not "%%f"=="###" (
  38.           (
  39.             echo select disk !disk!
  40.             echo select part %%f
  41.             echo list vol
  42.           )>%temp%\diskpart.s
  43.           set "lv0="
  44.           for /f "tokens=1,2,*" %%l in ('diskpart /s %temp%\diskpart.s') do (
  45.             if "%%l"=="*" ( if "%%m"=="!s3!"  set "lv0=%%n" )
  46.           )
  47.           set /a No+=1
  48.           set "No1=  !No!"
  49.           set hdp=!disk!:%%f
  50.           set size=!size:~-8!
  51.           if not "!lv0!"==""  (
  52.             for /f "tokens=1" %%r in ("!lv0!") do (set "vol=  %%r")
  53.             set ltr=!lv0:~6,1!
  54.             if "!ltr!"==" " set ltr=*
  55.             set fmt=!lv0:~23,5!
  56.             set lable=!lv0:~10,12!
  57.             for /f "tokens=1,2" %%r in ("!lv0:~51!") do (set other=%%r_%%s)
  58.             echo  !No1:~-3!  !vol:~-3!   !hdp!    !ltr!   !fmt!  !size!  !lable!  %%g_!other! %%j%%k
  59.           ) else (
  60.             echo  !No1:~-3!    *   !hdp!               !size!                %%g_ %%j%%k
  61.           )
  62.         ))
  63.       )
  64.      )
  65.   ))
  66. )
  67. echo --------------------------------------------------------------------------------------------------
  68. pause
复制代码


1,获取硬盘列表
2，获取每个硬盘分区列表
3，获取分区对应的 卷信息，卷标，格式，信息，状态。。。。
4，将掌握的 各个分区信息 显示出来。

本来windows 不支持的 分区，也要把信息 弄一下，这样就影响效率了。
作者: newswan    时间: 2018-5-31 23:30
dos时代菜鸟 发表于 2018-5-31 21:59
我基本上明白你的意思了

看这个吧 ,运行效率 有点儿低，因为要频繁调用 diskpart 对每一个分区进行 探 ...

差不多，就是这样了。
字符串截取太麻烦了



欢迎光临 无忧启动论坛 (http://bbs.c3.wuyou.net/) Powered by Discuz! X3.3