[原创]我研究的XP SP2及之后的补丁集成法（后续更新请见老毛桃的帖子）

bshun · 发表于 2006-10-18 12:52:31

KBArticleNumber /integrate:path

复制代码

按我们的路径，命令类似

E:\WXPSP2_HotFix\SP2_Hotfix2\WindowsXP-KBXXYYZZ-x86-CHS.exe /integrate:D:\XP\Retail.SP2\

复制代码

这个/s或者/integrate有个前提条件，要求补丁为使用 Update.exe 5.4.15.0 版或更高版本作为安装程序的软件更新
目前大部分的补丁都满足条件
如果有谁不会把SP2集成到原版光盘，也可以用类似这个命令的办法实现
我们来试着运行一下会发现，补丁先自动解开，然后过了一阵提示已经集成完毕，并且需要按确定。
补丁还有一个开关命令/passive，加上这个开关命令后，命令将以无人参与方式运行，无须确认。

2、对需要特别处理集成的小补丁进行集成
为什么要特别处理，根据微软的知识库描述，其实这个是这几个小补丁的一个bug
在集成完SP2的XP光盘文件夹\i386路径下有个HIVESYS.inf，这个文件中有一行为

INSTALL_LANGUAGE="0804"

复制代码

而这2个小补丁不认"0804"，将其改为"804"则能认
因此，我们需要进行修改
修改完毕后，可用这几条命令将它们进行集成

E:\WXPSP2_HotFix\SP2_Hotfix1\WindowsXP-KBXXYYZZ-x86-CHS.exe /integrate:D:\XP\Retail.SP2_HotFix\

复制代码

然后为了防止今后出什么意外的错，再把改过的内容改回来

3、现在我们来看如何将40个（将来可能更多）补丁用一条命令完成集成
先来看这条命令

dir E:\WXPSP2_HotFix\SP2_Hotfix2\*.exe /b

复制代码

这条命令将返回在E:\WXPSP2_HotFix\SP2_Hotfix2\下面所有的.exe文件的文件名，注意，仅仅是文件名，没有修改日期、时间和大小等等。
接着，再来看这条命令

FOR /F usebackq %i IN (`dir E:\WXPSP2_HotFix\SP2_Hotfix\*.exe /b`) DO start /wait E:\WXPSP2_HotFix\SP2_Hotfix2\%i /integrate:D:\XP\Retail.SP2\ /passive

复制代码

依次来解释具体的含义
FOR.......DO——对一组文件中的每一个文件执行某个特定命令。
/F—— 表示处理对象是一组以回车作为分隔符的文件
usebackq——处理一对``里面的命令
%i——就是参数了
IN——包含在...之中的
dir *.exe /b——得到目录下全部exe的文件名，每行一个
连起来就是，对（FOR）目录下全部的exe文件（/F usebackq %i IN (`dir *.exe /b`)），执行无人参与方式集成（E:\WXPSP2_HotFix\SP2_Hotfix\%i /integrate:D:\XP\Retail.SP2\ /passive）
其中，start /wait是用于启动一条命令，并且等待其结束再执行后续的命令，如果不加，则会出现n个补丁试图同时集成的情况，会造成集成失败的。
可以把这么复杂的命令，放到一个.bat文件中，但要注意，需要把%i修改为%%i，原因是.bat中的%i是另有含义的。
即

FOR /F usebackq %%i IN (`dir E:\WXPSP2_HotFix\SP2_HotFix2\*.exe /b`) DO start /wait E:\WXPSP2_HotFix\SP2_HotFix2\%%i /integrate:D:\XP\Retail.SP2\ /passive

复制代码

这样，运行这个.bat，就能把n个补丁一口气集成到目标路径。

讲完了分解动作，来讲一下我的想法，我认为准备好的XP集成了SP2的目录不要直接把补丁打进去，而是复制一份后再打
原因是，如果直接打了，那么一旦以后出现某补丁A把某补丁B替换了、而补丁B已经被集成了的情况，则需要手工把集成了的补丁B的相关垃圾文件和垃圾信息删去，比较麻烦。
而不直接打，则只需要每次删除前次的集成目录后重新集成一次即可
基于这个想法，我给出一份全自动的补丁集成批处理文件，内容如下：

SETLOCAL
SET SP2CD=D:\XP\Retail.SP2
SET SP2_HotFixCD=D:\XP\Retail.SP2_HotFix
SET SP2Dir=E:\WXPSP2_HotFix\SP2
SET SP2HotFix1=E:\WXPSP2_HotFix\SP2_HotFix1
SET SP2HotFix2=E:\WXPSP2_HotFix\SP2_HotFix2
IF EXIST %SP2_HotFixCD% RD /S /Q %SP2_HotFixCD%
XCOPY /E /I %SP2CD% %SP2_HotFixCD%
REN %SP2_HotFixCD%\i386\HIVESYS.INF HIVESYS.bak
COPY %SP2HotFix1%\HIVESYS.INF %SP2_HotFixCD%\i386\HIVESYS.INF
FOR /F usebackq %%i IN (`dir %SP2HotFix1%\*.exe /b`) DO START /wait %SP2HotFix1%\%%i /s:%SP2_HotFixCD%\ /passive
DEL %SP2_HotFixCD%\i386\HIVESYS.INF
REN %SP2_HotFixCD%\i386\HIVESYS.bak HIVESYS.INF
FOR /F usebackq %%i IN (`dir %SP2HotFix2%\*.exe /b`) DO START /wait %SP2HotFix2%\%%i /s:%SP2_HotFixCD%\ /passive
ENDLOCAL

复制代码

如果你连集成了SP2的XP的光盘这点空间也想省掉，那么
假设放XP光盘的光驱为G:
SP2的补丁下载在E:\WXPSP2_HotFix\SP2\WindowsXP-KB835935-SP2-CHS.exe
那么.bat文件相应改为

SETLOCAL
SET XPCD=G:
SET SP2CD=D:\XP\Retail.SP2
SET SP2_HotFixCD=D:\XP\Retail.SP2_HotFix
SET SP2Dir=E:\WXPSP2_HotFix\SP2
SET SP2HotFix1=E:\WXPSP2_HotFix\SP2_HotFix1
SET SP2HotFix2=E:\WXPSP2_HotFix\SP2_HotFix2
IF EXIST %SP2_HotFixCD% RD /S /Q %SP2_HotFixCD%
XCOPY /E /I /V %XPCD% %SP2_HotFixCD%
START /wait %SP2Dir%\WindowsXP-KB835935-SP2-CHS.exe -s:D:\XP\Retail.SP2_HotFix /passive
REN %SP2_HotFixCD%\i386\HIVESYS.INF HIVESYS.bak
COPY %SP2HotFix1%\HIVESYS.INF %SP2_HotFixCD%\i386\HIVESYS.INF
FOR /F usebackq %%i IN (`dir %SP2HotFix1%\*.exe /b`) DO START /wait %SP2HotFix1%\%%i /s:%SP2_HotFixCD%\ /passive
DEL %SP2_HotFixCD%\i386\HIVESYS.INF
REN %SP2_HotFixCD%\i386\HIVESYS.bak HIVESYS.INF
FOR /F usebackq %%i IN (`dir %SP2HotFix2%\*.exe /b`) DO start /wait %SP2HotFix2%\%%i /s:%SP2_HotFixCD%\ /passive
ECHO HotFix集成完毕！正在删除无用的文件...
FOR %%i IN (898461,885836,908531,920213,900485,920872,922760) DO REN %SP2_HotFixCD%\i386\SVCPACK\KB%%i.EXE KB%%i.BAK
DEL %SP2_HotFixCD%\i386\SVCPACK\*.EXE
REN %SP2_HotFixCD%\i386\SVCPACK\*.BAK *.EXE
RD /S /Q %SP2_HotFixCD%\i386\update
ENDLOCAL

复制代码

这样做节省了空间，但每次操作的时间会多很多

当然，不管你用了上面2个里面的哪个，前面分解动作里面提到的批处理文件都不需要了，而且需要把修改过的HIVESYS.INF复制一份到E:\WXPSP2_HotFix\SP2_HotFix1
而批处理里面的环境参数，你可以修改为自己需要的（就是前面的那些SET XXX=YYYYY啦），光盘也可以换成VOL/OEM，不见得非用零售版（本人偏好零售版啦）
注意，不要使用+/&等在DOS下有特殊用途的字符

最后讲一下刻盘和补丁维护
先用UltraISO之类的将原版XP的光盘做一个.ISO光盘镜像文件，这个镜像应该是可以从光盘启动的
然后打开，把里面的东西全砍掉，再把D:\XP\Retail.SP2_HotFix\里面的东西扔进去，保存，刻盘即可
将来有了新补丁，可以在WSUS里面查看到，请先根据WSUS给出的链接，把这些补丁下载下来，单独保存（没有WSUS？那就去看MS的安全公告，比如http://www.microsoft.com/china/technet/security/bulletin/ms06-063.mspx，与此安全更新相关的常见问题解答 (FAQ) 中提到“此安全更新替代以前的一个安全更新。下表列出了相应的安全公告 ID 和受影响的操作系统”，具体看那个表）
单独运行集成命令（不要加/passive），测试这些补丁是否能集成到D:\XP\Retail.SP2_HotFix
如果提示集成完毕，就把它移动到E:\WXPSP2_HotFix\SP2_HotFix2\，如不能集成，则把这个补丁删除掉或者通过别的办法集成
然后看剩下这些补丁是否有替代了我们先前下载的补丁，如果有那么删除掉原先的那些

PS：老毛桃斑竹已经发布了使用起来更方便的工具，我这边的补丁列表就偷懒不再更新了

[ 本帖最后由 bshun 于 2006-12-18 03:47 PM 编辑 ]

老毛桃 · 发表于 2006-10-18 15:23:25

楼主这个帖子不错，不过不明白为什么要禁止 URL 自动识别和 Discuz! 代码，为了大家打开链接方便，我先私自修改了。如果楼主认为不妥，可以告诉我或者改回！

wuyou1752818 · 发表于 2006-10-18 15:43:10

写的很好,怎么没人顶
楼主的批处理写的很好, 最近的脚本可以跟新下吗?
微软的补丁太麻烦了,有时候还会来个累积补丁,烦

bshun · 发表于 2006-10-18 15:45:23

原帖由 老毛桃 于 2006-10-18 03:23 PM 发表
楼主这个帖子不错，不过不明白为什么要禁止 URL 自动识别和 Discuz! 代码，为了大家打开链接方便，我先私自修改了。如果楼主认为不妥，可以告诉我或者改回！

我怕出现混乱而已，呵呵
有些论坛的自动识别功能不好，识别出来的链接是错的，还不如不识别，DISCUZ!我不太清楚，保险起见就禁了

原帖由 wuyou1752818 于 2006-10-18 03:43 PM 发表
楼主的批处理写的很好, 最近的脚本可以跟新下吗?
微软的补丁太麻烦了,有时候还会来个累积补丁,烦

我写的就是可以更新最新的

原帖由 bshun 发表
截至2006年10月16日，需要准备的小补丁有
....

[ 本帖最后由 bshun 于 2006-10-18 03:52 PM 编辑 ]

流年转换 · 发表于 2006-10-18 19:00:25

看不懂,晚上回来再细细回放

zhfzl2006 · 发表于 2006-10-18 22:04:16

谢谢楼主，微软的补丁太麻烦了，希望楼主能及时更新！

johnjames · 发表于 2006-10-18 22:29:22

好帖，学习了，收藏了。

wangbo_cq · 发表于 2006-10-18 23:18:04

只能潜水学习！

kxcbb · 发表于 2006-10-18 23:28:57

是个好贴，该顶起来

yinbin · 发表于 2006-10-19 09:45:06

好帖，收藏了，谢谢。
想问问楼主，这种方法对目前所有MS关键更新都是有效的吗？

老毛桃 · 发表于 2006-10-19 09:55:14

发现集成后个别文件还需要处理一下，比如在 Windows 环境下安装，选择将所有文件从 CD 复制到硬盘安装时，会出现 imekr61.ime 无法被读取的错误，点击忽略可以继续安装，但难保不会有问题。解决方法：打开 DOSNET.INF，找到 d1,imekr61.ime 字样的一行，修改成 d1,LANG\imekr61.ime 即可。

皖－辉 · 发表于 2006-10-19 11:15:07

好帖，学习了，收藏了。

bshun · 发表于 2006-10-19 12:23:23

原帖由 yinbin 于 2006-10-19 09:45 AM 发表
好帖，收藏了，谢谢。
想问问楼主，这种方法对目前所有MS关键更新都是有效的吗？

不能肯定，但你可以把补丁下载下来用/integrate试试看
做这个光盘的目的是为了重装完毕第一次启动后，相对比较安全
只是相对而已，大部分的关键更新补丁都打上了，再到网上去升级一把时，中招的可能性会小很多
想象一下，如果是XP的RTM装完要去网上升级，会怎样......

原帖由 老毛桃 于 2006-10-19 09:55 AM 发表
发现集成后个别文件还需要处理一下，比如在 Windows 环境下安装，选择将所有文件从 CD 复制到硬盘安装时，会出现 imekr61.ime 无法被读取的错误，点击忽略可以继续安装，但难保不会有问题。解决方法：打开 DOSNET ...

还有这样的事？？
我从来都是用光盘引导装的，倒是没碰到过，受教了

[ 本帖最后由 bshun 于 2006-10-19 12:29 PM 编辑 ]

雪风 · 发表于 2006-10-19 14:53:08

继续潜水吧，呵呵。。。。

老毛桃 · 发表于 2006-10-19 15:25:59

mkhang · 发表于 2006-10-19 16:19:02

谢谢，学到不少

ayyllll · 发表于 2006-10-19 18:12:15

好文章

mcdragon · 发表于 2006-10-19 18:55:04

每天学习一点点,总有一天也会出个精华帖的......加油!!!

tylz · 发表于 2006-10-19 21:37:25

bshun and 老毛桃:

首先非常感谢贴出这么精华的帖子，其次想问的是
如果全部集成上去这些补丁，估计光盘快装不下了吧？（正在下补丁，还没动手集成）对于普通用户来说,没有WSUS，如何知道哪些补丁被重新替代过呢?难道非得一个个的去MICROSOFT上查看吗?系统更新到最新以后，我的控制面板内“安装与添加程序”中所显示出来的补丁更新会不会既出现A更新，也出现后来替代A的B补丁更新呢？
谢谢！

[ 本帖最后由 tylz 于 2006-10-19 09:41 PM 编辑 ]

icespringxp · 发表于 2006-10-20 13:44:29

楼主真是为大家造福啦。
以后有更新的补丁的话，批处理文件是否还要进行修改？

ymzsc · 发表于 2006-10-20 14:17:39

真是好东西！！！顶你没商量！！！！

ayyllll · 发表于 2006-10-20 14:59:08

请楼主和毛桃：

整合后，I386\svcpack下的KB*.EXE可以删除吗？？安装时还要用吗？

[ 本帖最后由 ayyllll 于 2006-10-20 05:10 PM 编辑 ]

yjstone · 发表于 2006-10-20 16:33:15

高手！顶！

secowu · 发表于 2006-10-20 16:49:30

果然是好東西，讚一個

secowu · 发表于 2006-10-20 16:50:53

原帖由 老毛桃 于 2006-10-19 09:55 AM 发表
发现集成后个别文件还需要处理一下，比如在 Windows 环境下安装，选择将所有文件从 CD 复制到硬盘安装时，会出现 imekr61.ime 无法被读取的错误，点击忽略可以继续安装，但难保不会有问题。解决方法：打开 DOSNET ...

這個高啊，老毛就是老毛嘛，跟隨你有飯吃的說。。。

cq-bbcyb · 发表于 2006-10-20 19:28:07

quote]原帖由 ayyllll 于 2006-10-20 02:59 PM 发表
请楼主和毛桃：
整合后，I386\svcpack下的KB*.EXE可以删除吗？？安装时还要用吗？ [/quote]

那是必须用的。其实就是把微软的方法的整合方式用批处理来进行。

偶比较赖，一直用那些牛人做的整合包。

ayyllll · 发表于 2006-10-20 19:50:43

原帖由 cq-bbcyb 于 2006-10-20 07:28 PM 发表
quote]原帖由 ayyllll 于 2006-10-20 02:59 PM 发表
请楼主和毛桃：
整合后，I386\svcpack下的KB*.EXE可以删除吗？？安装时还要用吗？

那是必须用的。其实就是把微软的方法的整合方式用批处理来进行。

偶 ...

真的吗？至少要有整合SP2的效果，用不着安装过程再装SP2。

要真这样，还还得花时间去安装补丁，楼主整了半天有什么用？还不如用XPlode挂着装。

[ 本帖最后由 ayyllll 于 2006-10-20 07:54 PM 编辑 ]

zjl6634 · 发表于 2006-10-20 20:56:08

好帖,认真学学.

tylz · 发表于 2006-10-20 21:33:34

WindowsMessenger-KB887472-PreXPSP2-CHS.exe
MP10Setup.exe
Windows-KB890830-V1.21.exe
Windows-KB913433-x86-CHS.exe

以上几个文件无法整合进去？请问有什么办法呢？

tylz · 发表于 2006-10-20 21:38:34

1、集成Windows Media Player10到 XP SP2。
把XPSP2光盘下的I386目录以及WIN51、WIN51IP、WIN51IP.SP2复制到E盘(其他盘也可以);
把下载好的Windows Media Player10文件改名为:MP10Setup.exe
再把下面附件里的WMP10_Slipstreamer_V11_CN_Fix.cmd 和MP10Setup.exe复制到D盘根目录
双击运行WMP10_Slipstreamer_V11_CN_Fix.cmd.一路回车。最后将在D盘根目录生成一个wmp10文件夹。
把D:\wmp10 文件夹中的文件复制到E:\i386 目录中. 提示是否要覆盖时, 请按确定。
现在你就要编辑 I386\HIVEDEF.INF 文件了:
请在节 [AddReg] 下添加以下行:
HKCU,"SOFTWARE\Microsoft\MediaPlayer\Preferences","AcceptedPrivacyStatement",0x00010003,1

完成! Windows Media Player 10 现在已被完全整合了

bat files(把下面内容复制到记事本另存为bat文件,名字为:WMP10_Slipstreamer_V11_CN_Fix):

CODE:
TITLE 将Windows Media Player 10集成到WinXP安装文件 By bd540
@ECHO OFF
SET P=d:\WMP10TMP
SET OUT=d:\WMP10
SET C=MAKECAB /D CompressionType=LZX /D CompressionMemory=21 /L %OUT% %P%\
SET TotalSteps=3
IF EXIST %P% RD %P%
IF EXIST %OUT% RD %OUT%
COLOR 1C

CLS
ECHO.
ECHO.
ECHO 这个批处理文件将会帮助你整合 Windows Media Player 10!
ECHO.
ECHO.
ECHO.
ECHO.
PAUSE

IF NOT EXIST MP10Setup.exe GOTO ERR

CLS
TITLE 1/%TotalSteps% 正在将 MP10Setup.exe 提取到 %P% 中...
ECHO.
ECHO.
ECHO.
ECHO 1/%TotalSteps% 正在将 MP10Setup.exe 提取到 %P% 中...
ECHO.
ECHO.
START /WAIT MP10Setup.exe /C /Q /T:%P%
ECHO.
ECHO 完成!
ECHO.
PAUSE

CLS
TITLE 2/%TotalSteps% 正在将文件移动到 %OUT% 中并将其快速压缩...
ECHO.
ECHO.
ECHO.
ECHO 2/%TotalSteps% 正在将文件移动到 %OUT% 中并将其快速压缩...
ECHO.
ECHO.
ECHO 正在开始... 将要压缩 61 个文件...
ECHO.
ECHO.
%C%wmplayer.adm
%C%asferror.dll
%C%blackbox.dll
%C%CEWMDM.dll
%C%custsat.dll
%C%DRMClien.dll
%C%DrmStor.dll
%C%drmv2clt.dll
%C%LAPRXY.DLL
%C%mpvis.DLL
%C%msnetobj.dll
CLS
ECHO.
ECHO 还剩下 50 个要压缩的文件...
ECHO.
ECHO.
ECHO.
%C%MsPMSNSv.dll
%C%MsPMSP.dll
%C%msscp.dll
%C%MSWMDM.dll
%C%qasf.dll
%C%WMADMOD.DLL
%C%WMADMOE.DLL
%C%WMASF.DLL
%C%WMDMLOG.dll
%C%WMDMPS.dll
CLS
ECHO.
ECHO 还剩下 40 个要压缩的文件...
ECHO.
ECHO.
ECHO.
%C%wmerror.dll
%C%wmidx.dll
%C%WMNetMgr.dll
%C%wmp.dll
%C%wmpasf.dll
%C%wmpband.dll
%C%wmpcd.dll
%C%wmpcore.dll
%C%wmpdxm.dll
%C%wmploc.DLL
CLS
ECHO.
ECHO 还剩下 30 个要压缩的文件...
ECHO.
ECHO.
ECHO.
%C%wmpshell.dll
%C%wmpui.dll
%C%WMSDMOD.DLL
%C%WMSDMOE2.DLL
%C%WMSPDMOD.DLL
%C%WMSPDMOE.DLL
%C%WMVCORE.DLL
%C%WMVDMOD.DLL
%C%WMVDMOE2.DLL
%C%logagent.exe
CLS
ECHO.
ECHO 还剩下 20 个要压缩的文件...
ECHO.
ECHO.
ECHO.
%C%migrate.exe
%C%setup_wm.exe
%C%unregmp2.exe
%C%wmplayer.exe
%C%wmp.ocx
%C%Plylst1.wpl
%C%Plylst10.wpl
%C%Plylst11.wpl
%C%Plylst12.wpl
%C%Plylst13.wpl
CLS
ECHO.
ECHO 还剩下 10 个要压缩的文件...
ECHO.
ECHO.
ECHO.
%C%Plylst14.wpl
%C%Plylst15.wpl
%C%Plylst2.wpl
%C%Plylst3.wpl
%C%Plylst4.wpl
%C%Plylst5.wpl
%C%Plylst6.wpl
%C%Plylst7.wpl
%C%Plylst8.wpl
%C%Plylst9.wpl
IF EXIST %P% RD /S /Q %P%
ECHO.
ECHO.
ECHO.
ECHO 完成!
ECHO.
PAUSE

CLS
TITLE 3/%TotalSteps% 现在轮到你了...
ECHO.
ECHO.
ECHO.
ECHO 3/%TotalSteps% 现在轮到你来操作了...
ECHO.
ECHO.
ECHO A)    首先, 要将文件夹 %OUT% 中的文件复制到你的安装文件所在的目录 i386 中. 当问你是否要覆盖文件时, 请点击 '是'.
ECHO.
ECHO.
ECHO B)    现在你就要编辑 I386\HIVEDEF.INF 文件了:
ECHO.
ECHO    在节 [AddReg] 下添加以下行:
ECHO.
ECHO                HKCU,"SOFTWARE\Microsoft\MediaPlayer\Preferences","AcceptedPrivacyStatement",0x00010003,1
ECHO.
ECHO.
ECHO.
ECHO 完成! Windows Media Player 10 现在已被完全整合了!
ECHO.
PAUSE
CLS

EXIT

:ERR
CLS
TITLE ERROR: 无法找到 MP10SETUP.EXE!
ECHO.
ECHO.
ECHO.
ECHO 无法找到 MP10Setup.exe! 请把这个批处理文件放到有 MP10Setup.exe 的文件夹中!
ECHO.
PAUSE
EXIT

原贴地址为http://blogxp.org/ArticleShow/51215

		自动登录	找回密码
密码			注册

[原创]我研究的XP SP2及之后的补丁集成法（后续更新请见老毛桃的帖子）

评分