请教 从PE下BAT安装PE

1198398

从PE下BAT安装PE到硬盘，部分命令不能运行，在XP下安装成功，不知道是PE缺少了哪些文件？

@shift
@Echo Off
color 2e
Set Prog=WinPE硬盘专用安装工具
Set L1=　　　　　　　　　　　╭─────────────╮
Set L2=　　　　　　╭────┤   WinPE硬盘专用安装工具  ├────╮
Set L3=　　　　　　│　　　　╰─────────────╯　      │
Set L4=　　　　　　│============================================  │
Set L5=　　　　　　│             BY:蓝色网络 QQ:1198398           │
Set L6=　　　　　　╰───────────────────────╯
Title %Prog%
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
If "%RP%"=="" Goto NoSys
If Exist %RP%\PELDR Goto :EXISTPE
FIND /I "C:\PELDR" %RP%\BOOT.INI >NUL
If %Errorlevel%==0 Goto :EXISTPE
Goto Start
:EXISTPE
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo 　　　　　　│ 检测到您机器中已经安装了 WinPE，您要卸载吗？ │
Echo 　　　　　　│　[1] 卸载原有的 WinPE，并重新安装 WinPE　　　│
Echo 　　　　　　│　[2] 卸载原有的 WinPE，并删除原有的 WinPE　　│
Echo 　　　　　　│　[Q] 退出安装　　　　　　　　　　　　　　　　│
Echo %L4%
Echo %L5%
Echo %L6%
Echo.
Set Choice=
Set /P Choice=　　　　　　　请选择要进行的操作 (1/2/Q) ，然后按回车：
If %Choice%Choice==Choice Goto :EXISTPE
If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' SET Choi=1&&GOTO :UnInstall
If /I '%Choice%'=='2' GOTO :UnInstall
If /I '%Choice%'=='Q' EXIT
Goto :EXISTPE
:UnInstall
If Exist %RP%\PELDR ATTRIB -S -H -R %RP%\PELDR && Del /Q /F %RP%\PELDR >NUL
If Exist %RP%\WXPE RD %RP%\WXPE /S /Q>NUL
If Exist %RP%\PETOOLS RD %RP%\PETOOLS /S /Q>NUL
Attrib %RP%\BOOT.INI -S -H -R
If Exist %RP%\BOOT.BAK (
Attrib %RP%\BOOT.BAK -S -H -R
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\PELDR">%RP%\BOOT.INI
) Else (
Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\PELDR">%RP%\BOOT.INI
)
Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL
If Exist %RP%\BOOT.BAK ATTRIB -S -H -R %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL
Attrib %RP%\BOOT.INI +S +H +R
Title %Prog%——卸载完成
If %Choi%Choi==1Choi (Echo.&&Echo　　　　　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL&&Goto Start)
Echo.&&Echo　　　　　　　　卸载完成，请按任意键退出 。。。
PAUSE>NUL
Exit
:Start
CLS
Title %Prog%——安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo 　　　　　　│　[1] 安装WinPE到硬盘，并添加至启动菜单       │
Echo 　　　　　　│　[Q] 退出安装　　　　　　　　　　　　　　　　│
Echo %L4%
Echo %L5%
Echo %L6%
Set Choice=
Set /P Choice=　　　　　　　请选择要进行的操作 (1/Q) ，然后按回车：
If %Choice%Choice==Choice Goto Start
If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' GOTO Install
If /I '%Choice%'=='q' EXIT
Goto Start
:Install
Title %Prog%——安装 WinPE
set boot=%RP%\BOOT.INI
Echo.
Echo                请输入启动菜单等待时间，并回车。
Echo　               0－30，0表示不显示菜单（单位：秒）
Echo.
set/p times= 　            等待时间设置为：
Echo.
Echo　　　　　　　　正在复制文件，请稍候 。。。
CD.. >NUL
Copy PESETUP\PELDR %RP%\ /Y >NUL
If Exist PETOOLS  XCOPY PETOOLS /E %RP%\PETOOLS\ /Y >NUL
If Exist WXPE  XCOPY WXPE /E %RP%\WXPE\ /Y >NUL
ATTRIB -S -H -R %RP%\BOOT.INI
If Exist %RP%\BOOT.BAK ATTRIB -S -H -R %RP%\BOOT.BAK
Copy %RP%\BOOT.INI %RP%\BOOT.BAK >NUL
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\PELDR">%RP%\BOOT.INI
Echo C:\WXPE\PELOAD="WinPE 维护系统">>%RP%\BOOT.INI
TYPE %RP%\BOOT.INI>%RP%\bot.bak
TYPE %RP%\bot.bak|find "boot loader" /i>%RP%\BOOT.INI
Echo timeout=%times% >>%RP%\BOOT.INI
TYPE %RP%\bot.bak|find "boot loader" /i /v|find "timeout" /i /v>>%RP%\BOOT.INI
ATTRIB +S +H +R %RP%\BOOT.INI
@del %RP%\bot.bak >>nul
@del %RP%\WXPE\NTDETECT.COM >>nul
Copy PESETUP\PELOAD %RP%\WXPE\ /Y >NUL
ren %RP%\WXPE\SETUPLDR.BIN LDRXPE
ATTRIB +S +H +R %RP%\BOOT.INI
ATTRIB +S +H +R %RP%\BOOT.BAK
ATTRIB +S +H +R %RP%\PELDR
ATTRIB +S +H +R %RP%\WXPE\BFONT.B
ATTRIB +S +H +R %RP%\WXPE\NTDET.C
ATTRIB +S +H +R %RP%\WXPE\PE.X
ATTRIB +S +H +R %RP%\WXPE\PELOAD
ATTRIB +S +H +R %RP%\WXPE\WINPE.IM_
ATTRIB +S +H +R %RP%\WXPE\LDRXPE
ATTRIB +S +H +R %RP%\WXPE
ATTRIB +S +H +R %RP%\PETOOLS
Goto :SUCCESS
:NoSys
Echo 　　　　　　　好像您的机器中没有安装操作系统哦
Echo 　　　　　　　请确认后再执行本安装程序。
Echo.
Echo 请按任意键退出 。。。
PAUSE >NUL
Exit
:SUCCESS
Title %Prog%——安装完成
Echo.
Echo 　　　　　　　恭喜！！
Echo.
Echo 　　　　　　　已经成功将镜像 WINPE 安装到您的 %RP% 盘。
Echo.
Echo 　　　　　　　系统分区中的 BOOT.INI 备份为 BOOT.BAK。
Echo.
Echo               如果您需要将WinPE卸载,请重新运行本安装程序。
Echo.
Echo 　　　　　　　请按任意键退出 。。。
PAUSE >NUL
Exit

1198398

如果命令参数有误，还请高人指教，修正

1198398

一个下午 终于搞定