NSIS 语法随机变量diskpart判别U盘号，请教各位？

chen463 · 发表于 2024-5-13 16:16:19

本帖最后由 chen463 于 2024-5-28 11:57 编辑

NSIS 语法随机变量diskpart判别U盘号，请教各位？给建议或提供相关程序代码

我是个初学者，只是好学习，望各位指导感谢‧
网络上搜索很多，太高阶的看不懂使用，太浅的达不到所需求‧

现在构想有两种方式：
A. 把U.txt字符READ 3 WRITE写入\DISK.txt字符 5替换5-3执行。
B. 在程序中把变量$R8=3 去修改WRITE写入\DISK.txt内容：5-3

自己想把现有固定条件，变成随机变量的方式
1.随机获取U.txt内容：3
2.自动执行DISK.txt内容：
List disk
Sel disk 5
…

U盘号已经设定为$R8=3已经确认，现在只需要把U.txt字符READ 3 WRITE写入\DISK.txt里面字符5替换成3，获取随机变量0.1.2.3.4.5…，就能自动执行 diskpart 脚本diskpart /s scriptname.txt，首要先确立select disk [0.1.2.3.4.5]为先。必须把获取的3写入5位置替换，获取随机变量。
范例；DISK.txt[脚本现在设定为select disk 5而获取随机变量U盘实际为3]

select disk 5
clean
convert gpt
create partition primary size=300
format quick fs=ntfs label="Windows RE tools"
assign letter="T"
create partition efi size=100
rem == Note: for Advanced Format Generation One drives, change to size=260.

format quick fs=fat32 label="System"
assign letter="S"
create partition msr size=128
create partition primary
format quick fs=ntfs label="Windows"
assign letter="W"

WUMEIHAI · 发表于 2024-5-13 16:53:26

看不懂帮顶

maisifu · 发表于 2024-5-14 08:40:33

帮顶，等大神解惑。。。

nttwqz · 发表于 2024-5-14 08:54:34

语文学的不好，看不明白

Tatsumki · 发表于 2024-5-14 13:02:13

看不懂插个眼等大神解答

shy20070509 · 发表于 2024-5-15 09:16:22

不是很懂

4424442 · 发表于 2024-5-16 22:03:02

顶一下，让大佬看见

nttwqz · 发表于 2024-5-17 11:11:50

换个思路，直接重新生成整个diskpart脚本不就好了。

千千静静听 · 发表于 2024-5-18 13:41:31

支持一个。

hilsonma · 发表于 2024-5-18 20:35:43

本帖最后由 hilsonma 于 2024-5-18 20:53 编辑

不知楼主是如何获取u盘号，所以这一步就略过。如果u.txt的内容就是正确的u盘号的话，批可以如下：

@echo off
setlocal EnableDelayedExpansion
for /f %%a in (u.txt) do set d=%%a
(
echo select disk !d!
echo clean
echo convert gpt
echo sel par 1
echo del par override
echo create partition efi size=260
echo format fs=fat32 label=System quick
echo assign letter=S
echo create partition msr size=16
echo create partition primary
echo shr minimum=300
echo format fs=ntfs label=Windows quick
echo assign letter=W
echo create partition primary
echo format fs=ntfs label="Windows RE tools" quick
echo assign letter=T
echo set id=de94bba4-06d1-4d40-a16a-bfd50179d6ac
echo gpt attributes=0x8000000000000001
echo lis par
)|diskpart.exe

复制代码

脚本会清空U盘的！！！应该在脚本执行前有提示
以上脚本已按ms示例将工具分区调整到最后并赋与专门属性，esp直接使用260MB，如需更大请修改。
转换gpt时会自动产生msr分区，以上脚本已添加清除此分区。

dos时代菜鸟 · 发表于 2024-5-18 23:48:18

本帖最后由 dos时代菜鸟于 2024-5-19 00:27 编辑

如果有多个u盘，就麻烦了。
另外 diskpart 本身也能找到u盘

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set "diskpart_cmd=echo list disk"
set disks=
for /f "tokens=2" %%c in ('^(!diskpart_cmd!^)^|diskpart') do (
if defined disks set "disks=!disks!,%%c"
if "%%c"=="-------------" set "disks=,"
)
set diskpart_cmd=echo rem
for %%c in (!disks!) do (
set "diskpart_cmd=!diskpart_cmd! ^& echo select disk %%c ^& echo detail disk"
)
set usb_s=
for /f "tokens=1,2,3 delims=: " %%c in ('^(!diskpart_cmd!^)^|diskpart') do (
if "%%c%%e"=="磁盘现在是所选磁盘。" set "diskx=%%d"
if "%%c"=="类型" (
if /I "%%d"=="USB" ( SET usb_s=!usb_s!,!diskx!)
set diskx=
)
)
echo.
if not defined usb_s ( echo 没有U盘...) else (
for %%c in (!usb_s!) do (
echo 找到U盘编号：%%c
)
)
echo.
echo.
pause

复制代码

nttwqz · 发表于 2024-5-19 00:47:50

楼主作为一名论坛前辈，发帖这么多天，高手解答的寥寥无几，难道是论坛缺少高手？非也！发求助帖应使用言简意赅、清晰易懂的语言表达，你的贴子显然不符合这种条件。

发帖示例
如何使用NSIS获取diskpart的优盘编号并修改diskpart脚本？

1. 如何用NSIS获取diskpart的优盘编号？用于操作优盘。
2. 获取编号后如何替换现有diskpart脚本的内容，比如下面的select disk 3中的3替换成5。

select disk 3
clean
convert gpt
……

nttwqz · 发表于 2024-5-19 00:49:40

; 仅适用于select disk位于第一行的情况
StrCpy $R1 "select disk "
StrLen $R2 "$R1"
SetOutPath "$EXEDIR"
FileOpen $R0 'sample.txt' a
FileRead $R0 $0
DetailPrint '更改前：$0'
FileSeek $R0 $R2
FileWrite $R0 "5 "
FileSeek $R0 0
FileRead $R0 $0
DetailPrint '更改后：$0'
FileClose $R0

复制代码

!include "TextFunc.nsh"
Section
; 适用于select disk不在第一行，和多行的情况，会更改每一行select disk
${LineFind} "sample.txt" "" "" "func_edit"
SectionEnd
Function func_edit
${TrimNewLines} "$R9" $9
StrCpy $9 "$9" 12
${If} $9 == 'select disk '
StrCpy $R9 "select disk 5$\r$\n"
${EndIf}
Push $1
FunctionEnd

复制代码

chen463 · 发表于 2024-5-19 10:07:53

感谢几位前辈大大指导，后学慢慢研究一下学习运用，感谢。

因为diskpart脚本执行是一串几行的，我没能力从NSIS语法去做变量设定，其实要修改的有很多处.
磁盘选择setect disk 1.2.3.4.5……
分区大小size=100.200.300…..
分区选择setect part 1.2.3.4.5……
能力不足，只能先求U盘确认无误，其他固定脚本。

chen463 · 发表于 2024-5-19 10:08:40

本帖最后由 chen463 于 2024-5-19 10:28 编辑

dos时代菜鸟发表于 2024-5-18 23:48
如果有多个u盘，就麻烦了。
另外 diskpart 本身也能找到u盘

感谢大大，拜读您几个范例，才启发这次'尝试，diskpart可有搜寻detail DISK等讯息输出\TXT功能代码，

chen463 · 发表于 2024-5-19 10:13:47

nttwqz 发表于 2024-5-19 00:49

大大，这几个例应可以运用上，试试，程度差，语法得研究一下

chen463 · 发表于 2024-5-19 10:26:29

hilsonma 发表于 2024-5-18 20:35
不知楼主是如何获取u盘号，所以这一步就略过。如果u.txt的内容就是正确的u盘号的话，批可以如下：

这批处理是想让我执行CMD吗？不知diskpart可行否？
如果可行，可透过批处理来输出\TXT让diskpart完成脚本执行。

U盘,外可从FBINST，BOOTICE来获取，也可从程序代码选取U盘来确认

dos时代菜鸟 · 发表于 2024-5-19 12:12:04

本帖最后由 dos时代菜鸟于 2024-5-19 12:13 编辑

chen463 发表于 2024-5-19 10:08
感谢大大，拜读您几个范例，才启发这次'尝试，diskpart可有搜寻detail DISK等讯息输出\TXT功能代码，

可以的
直接
> x.txt
不就行了？

其实不用生成文件，直接cmd 调用变量就行。
关键是你能确定就 1个 u盘么？

chen463 · 发表于 2024-5-19 17:06:28

dos时代菜鸟发表于 2024-5-19 12:12
可以的
直接
> x.txt

哈哈，多个U盘的确有这现象，其实已经被clear了一个外挂硬盘，才发现diskpart不能乱使，左右都插入U盘在测试着，看着list DISK没问题，结果不小心频繁变换配备插拔，干掉一个位在不是SEL DISK显示的外挂硬盘上，可能是给的条件不充足，就失败执行。还好自己找回分区表恢复数据。
两个纯U盘操作OK，其实排序会随插入时间、配备不同而上下2-3变化，但是如果是外挂USB硬盘，系统会排除而显示在硬盘，但是意外总会发生，外挂USB硬盘会误判辨别为U盘的，所以才想变量所选项的U盘号，以保万无一失。

批次可能无法预知所选的U盘号[没操作过]，但是程式可以立判所选的U盘号

dos时代菜鸟 · 发表于 2024-5-19 20:38:44

chen463 发表于 2024-5-19 17:06
哈哈，多个U盘的确有这现象，其实已经被clear了一个外挂硬盘，才发现diskpart不能乱使，左右都插入U盘在 ...

我 12楼代码能找到多个u盘 ,但仅限简体中文。

nttwqz · 发表于 2024-5-19 23:18:43

本帖最后由 nttwqz 于 2024-5-19 23:31 编辑

@echo off
setlocal enabledelayedexpansion
set title=优盘分区工具
title %title%
::自动请求以管理员权限运行
if /i "%systemdrive%"=="C:" reg query HKU\S-1-5-20>nul 2>nul || echo;CreateObject^("Shell.Application"^).ShellExecute "%~f0", "%*", "", "runas", 1 > "%temp%\getadmin.vbs" && cscript //b "%temp%\getadmin.vbs" 2>nul && exit /b & del "%temp%\getadmin.vbs" /f /q>nul
pushd %~dp0
call dpinfo.bat
:: 如果要合并成一个脚本，请将下面内容复制到dpinfo文件 :: 开始脚本定制的后面
set title=优盘分区工具
for %%a in (!dkl!) do if /i "!dk_%%a_type!"=="USB" if defined usbdkl (set usbdkl=!usbdkl! %%a) else set usbdkl=%%a
if not defined usbdkl (
color 4f
echo;错误，没有找到USB磁盘！
pause
exit
)
title %title% - 选择优盘
echo;
echo; # 大小名称
echo; - -------- -------------------------------------------
for %%a in (!usbdkl!) do (
echo; %%a !dk_%%a_size_echo! !dk_%%a_name!
)
echo;
set /p udisk=请选择优盘：
echo;
title %title% - 选择分区
if defined udisk (
echo; 分区 VOL LTR !dk_type_title_echo! 隐藏 ACT ESP 大小可用偏移量 !dk_label_title_echo! FS/ID
echo; ---- --- --- !dk_type_fgx! ---- --- --- -------- -------- -------- !dk_label_fgx! ------------------
for %%a in (!udisk!) do (
for %%b in (!dk_%%a_dpl!) do (
echo; %%b !dk_%%a_%%b_vol_echo! !dk_%%a_%%b_ltr_echo! !dk_%%a_%%b_type_echo! !dk_%%a_%%b_hidden_echo! !dk_%%a_%%b_act_echo! !dk_%%a_%%b_size_echo! !dk_%%a_%%b_free_echo! !dk_%%a_%%b_offset_echo! !dk_%%a_%%b_label_echo! !dk_%%a_%%b_fs!
)
)
)
echo;
set /p upart=请选择分区：
echo;
echo;
title %title%
pause
exit

复制代码

dpinfo.bat需要放到同目录下，其它路径自己修改call

其实，傲梅分区助手命令行版更合适做为优盘分区工具，支持无损调整分区等diskpart无法实现的操作。

dos时代菜鸟 · 发表于 2024-5-19 23:52:09

本帖最后由 dos时代菜鸟于 2024-5-20 19:02 编辑

唉，给你个现成的算了。找出 usb 盘让你自己选择，然后直接分区。

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
echo 正在获取 usb_disk 信息 ......
set "diskpart_cmd=echo rescan ^& echo list disk"
set disks=
for /f "delims=" %%x in ('^(!diskpart_cmd!^)^|diskpart') do (
for /f "tokens=2" %%c in ("%%x") do (
if defined disks (
set disk%%c=%%x
set "disks=!disks!,%%c"
)
if "%%c"=="-------------" set "disks=,"
)
)
set diskpart_cmd=echo rem
for %%c in (!disks!) do (
set "diskpart_cmd=!diskpart_cmd! ^& echo select disk %%c ^& echo detail disk"
)
set usb_s=
set usb_n=0
for /f "tokens=1,2,3 delims=: " %%c in ('^(!diskpart_cmd!^)^|diskpart') do (
if "%%c%%e"=="磁盘现在是所选磁盘。" set "diskx=%%d"
if "%%c"=="类型" (
if /I "%%d"=="USB" (
set /a usb_n+=1
SET "usb_s=!usb_s! !diskx!"
)
set diskx=
)
)
if !usb_n! equ 0 (
echo 没有U盘...
goto :end1
)
:select1
cls
echo.
echo 部署 usb_disk ...
echo.
echo USB盘列表：
echo ---------------------------------------------------------------------
for %%c in (!usb_s!) do (echo !disk%%c!)
echo ---------------------------------------------------------------------
if !usb_n! geq 2 (
set /p disk_U=请选择一个U盘（!usb_s! , X退出）:
if /i "!disk_U!"=="X" goto :end1
set find1=0
for %%c in (!usb_s!) do (
if !disk_U! equ %%c set find1=1
)
if !find1! equ 0 (
echo 选择错误，请按任意键重新来过....
pause>nul
goto :select1
)
)else (
set /a disk_u=!usb_s!
SET /P X=按任意键开始对唯一的 U 盘进行部署（X退出）....
if /i "!x!"=="x" goto :end1
)
echo.
echo.
echo 对 USB_disk #!disk_U! 进行分区部署：
call :fdisk1 !disk_U!
:end1
pause
goto :eof
:fdisk1
echo 请稍等......
(
echo select disk %1
echo clean
echo convert gpt
echo create partition efi size=100
echo format quick fs=fat32 label="System"
echo create partition msr size=128
echo create partition primary size=300
echo format quick fs=ntfs label="Windows RE tools"
echo assign letter="T"
echo create partition primary
echo format quick fs=ntfs label="Windows"
echo assign letter="W"
)|diskpart >nul 2>nul
echo 完毕...
exit /b

复制代码

chen463 · 发表于 2024-5-21 09:48:19

感谢几位前辈大大，无私地教学示范范例，diskpart脚本已经初步成形，变量U盘号已由程序代码设定，经各位的传球助攻已经进球得分，最后完成当初规画的B.方案，由程序代码变量符号$R8设定修改脚本文本，非常感谢！感恩！

傲梅分区助手命令行，改天再来学习之。先前没使用过。初步变量U盘号制作已达成。

脚本要制作U盘UD三分区或U盘UD四分区或纯UEFI单、双、三、四分区，就由脚本变量去决定，批次后学不懂，后学四十几岁才刚接触计算器，开始学习，而且怀疑开始患了老年痴呆症状，几年没看的程序代码，自己亲自编程的竟然看不懂，热忱已退，记忆已失，哈哈…最后再一次感谢各位感恩大家。

chen463 · 发表于 2024-6-11 19:48:42

nttwqz 发表于 2024-5-19 23:18
dpinfo.bat需要放到同目录下，其它路径自己修改call

其实，傲梅分区助手命令行版更合适做为优盘分区 ...

接受您的建议，diskpart已经玩过完成，现在尝试分区助手，竟然您建议，表示您熟悉这软件，所以请教您，为何CMD运行PartAssist.exe出现找不到ScanPartition.dll而失败，我已经放入同目录中。

chen463 · 发表于 2024-6-11 21:21:52

nttwqz 发表于 2024-5-19 23:18
dpinfo.bat需要放到同目录下，其它路径自己修改call

其实，傲梅分区助手命令行版更合适做为优盘分区 ...

去官方下载了分区助手9.13命令行U盘专用版可以用了，感谢！有问题再来请教

chen463 · 发表于 2024-6-12 08:43:31

nttwqz 发表于 2024-5-19 23:18
dpinfo.bat需要放到同目录下，其它路径自己修改call

其实，傲梅分区助手命令行版更合适做为优盘分区 ...

感谢您建议分区助手，昨晚研究了一下命令行用法，作者很有心，里面提供很多范例，也手动测试UD多分区试用，觉得非常满意，建立分区速度快准确度高，不比diskpart脚本差，甚至更亲切人性操作，了解使用逻辑后更顺手操作它，因为是系统外部软件，在PE下操作应该更能磨合建立分区成功，感谢您。

nttwqz · 发表于 2024-6-12 10:01:44

chen463 发表于 2024-6-12 08:43
感谢您建议分区助手，昨晚研究了一下命令行用法，作者很有心，里面提供很多范例，也手动测试UD多分区试用 ...

因为分区助手命令行版本身就是为此而生，好像也是本坛提出的建议，作者采纳增加了该功能，作者在本坛也有账号。本坛有不少使用分区助手的工具，我倒是没用过其开发过什么工具

财源茂盛 · 发表于 2024-6-14 08:23:49

提示: 作者被禁止或删除内容自动屏蔽

mednova · 发表于 2024-6-14 11:08:07

怎么样？

		自动登录	找回密码
密码			注册

财源茂盛财源茂盛当前离线积分 3274 IP卡狗仔卡	28^# 发表于 2024-6-14 08:23:49 \| 只看该作者提示: 作者被禁止或删除内容自动屏蔽
财源茂盛财源茂盛当前离线积分 3274 IP卡狗仔卡
	回复使用道具举报显身卡

[已解决] NSIS 语法随机变量diskpart判别U盘号，请教各位？

点评

评分

点评

点评

点评

点评

点评

点评

点评

点评